diff --git a/dev-libs/sord/Manifest b/dev-libs/sord/Manifest
index 06caaaff6513c..53dee563d6050 100644
--- a/dev-libs/sord/Manifest
+++ b/dev-libs/sord/Manifest
@@ -1 +1,2 @@
 DIST sord-0.16.16.tar.xz 107148 BLAKE2B e657f6e4d38df1c254ce6282ae54a6795e29fd60546373a2b4e1560b269658fa69dd93af4d6f75eaa73f9f777a2d82f99f80d34fd65e1001b8231b63af71029f SHA512 8728fa01466e8f64c1a70a6d4ce727cdac3aaba78db0163ad511d7e959a260c95ab47405cce24ca0e076fb1f0da761687d788cddef87a96aa813757d10f0bfe0
+DIST sord-0.16.18.tar.xz 102300 BLAKE2B 8dfffa4632ddf3efe0c4a421d43001d1186f6336004847eaf12f91ca408486eca222ab1b68e9dc31d2e41f0e65fe1cd167a4b5cc5fabd516f032416b4c0dbae3 SHA512 e271d97c77187d7ed0a9c8fe0a65fcf50e269ba79dba4e8d55781ffe3715888c5388d90812d76a48e89ecc9c5e047e0d53ff40333fde7dbbf12dffc496d05e31
diff --git a/dev-libs/sord/sord-0.16.18.ebuild b/dev-libs/sord/sord-0.16.18.ebuild
new file mode 100644
index 0000000000000..a7a99fdff71fc
--- /dev/null
+++ b/dev-libs/sord/sord-0.16.18.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson-multilib
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/drobilla/sord.git"
+else
+	SRC_URI="https://download.drobilla.net/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+DESCRIPTION="Library for storing RDF data in memory"
+HOMEPAGE="https://drobilla.net/software/sord.html"
+
+LICENSE="ISC"
+SLOT="0"
+IUSE="doc test tools"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+		dev-python/sphinx
+		dev-python/sphinx-lv2-theme
+		dev-python/sphinxygen
+	)
+"
+# Take care on bumps to check minimum versions!
+RDEPEND="
+	>=dev-libs/serd-0.30.10[${MULTILIB_USEDEP}]
+	>=dev-libs/zix-0.4.0[${MULTILIB_USEDEP}]
+	tools? ( dev-libs/libpcre2[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# fix doc installation path
+	sed -i "s/versioned_name/'${PF}'/g" doc/meson.build || die
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_native_use_feature doc docs)
+		$(meson_feature test tests)
+		$(meson_feature tools)
+	)
+
+	meson_src_configure
+}
+
+multilib_src_install_all() {
+	local DOCS=( AUTHORS NEWS README.md )
+	einstalldocs
+}