From 96f863f93079082f0c0936f7031555dd11f98ddf Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Tue, 1 Jul 2025 03:31:50 +0100
Subject: [PATCH] dev-util/peg: add 0.1.20

Drop using the 'check' target, just use the 'test' one (we were calling
both before) as the former seems to require some test data to be updated.

Closes: https://bugs.gentoo.org/959339
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-util/peg/Manifest          |  1 +
 dev-util/peg/peg-0.1.20.ebuild | 52 ++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)
 create mode 100644 dev-util/peg/peg-0.1.20.ebuild

diff --git a/dev-util/peg/Manifest b/dev-util/peg/Manifest
index 292d9bac79cf..309dd7ccc08e 100644
--- a/dev-util/peg/Manifest
+++ b/dev-util/peg/Manifest
@@ -1 +1,2 @@
 DIST peg-0.1.19.tar.gz 136241 BLAKE2B 78487434f49c64bbe4454e603d5bef8f264fd095339a389c16eb50765e641b2a337426d7bd5fef5d3ad205d9e502850b3f813a7a67b399a936c402f25a74b0c6 SHA512 fc6a1dfab73bde6992b5385ac1c190fa957e9838d5ec6ddb2bbe6f773766c793d745e892bc952dc65969a6ff942424b7208a9d9d27f177a451da5c22b05d5575
+DIST peg-0.1.20.tar.gz 137305 BLAKE2B de98ca0650868e7be355e81a794d801ed19557305c557e53b885c82cccae141a2ba3e25317606563539687470c43ac2365e8a17609844f756526557fb85d1df3 SHA512 e95d62752f7668e3f6e3c78e87fc0c7e1ebe3098a474ac4ed2dd363f203c1b91371cefbf0318ba6cef5bd5ea982e72f7b59fe2a0cf2e0f6ef624f02a7a6cb3cb
diff --git a/dev-util/peg/peg-0.1.20.ebuild b/dev-util/peg/peg-0.1.20.ebuild
new file mode 100644
index 000000000000..ab627031b268
--- /dev/null
+++ b/dev-util/peg/peg-0.1.20.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Recursive-descent parser generators for C"
+HOMEPAGE="https://piumarta.com/software/peg/"
+SRC_URI="https://piumarta.com/software/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DOCS=( ChangeLog README.txt )
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/strip/d' \
+		-e '/^CFLAGS/d' \
+		-e 's/$(CC) $(CFLAGS) -o/$(CC) $(CFLAGS) $(LDFLAGS) -o/g' \
+			Makefile || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_test() {
+	# There's also a 'check' target but it seems to rely on some
+	# data being regenerated (bug #959339).
+	emake test \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	dodir /usr/share/man/man1
+
+	emake \
+		ROOT="${D}" \
+		PREFIX="${EPREFIX}/usr" \
+		MANDIR="${D}/${EPREFIX}/usr/share/man/man1" \
+		install
+}