diff --git a/app-emulation/fuse-utils/Manifest b/app-emulation/fuse-utils/Manifest
index c4b333ee2e702..64d5ba42c07d4 100644
--- a/app-emulation/fuse-utils/Manifest
+++ b/app-emulation/fuse-utils/Manifest
@@ -1 +1,2 @@
 DIST fuse-utils-1.4.3.tar.gz 501006 BLAKE2B 0637fe05b71416e89eb61e3618ff45bd71250201924fb3741a4c5b9898d09b30acecba9957baeaa864c2c9cfe1bcb9cb38a2af83368bc5729221cec36a1eda47 SHA512 13404d1be81a2de9262cd79cce9dd8dc3f17238fdbb75da8a724b76b0976c03f34da9978af36b808103fedcf3f5d5da4bb10f251c5510127d59ca8de5607b99e
+DIST fuse-utils-1.4.4.tar.gz 551378 BLAKE2B e692d635524ac5d2a780cb81fd63d17198398adb7e2277218c4651f6323dba6b9eeab79707924ee1ef412920a83352ebe07181efe2ee40fd6d83034a2215ade6 SHA512 390877e6f940d499ae28a2ce7b74864489b79f535d963b69aa3169c7af84638f37c9ed3a91faa82185ee876b9bb1a619cfbd738e328a12dd17d8c385c0715815
diff --git a/app-emulation/fuse-utils/fuse-utils-1.4.3-r2.ebuild b/app-emulation/fuse-utils/fuse-utils-1.4.3-r3.ebuild
similarity index 84%
rename from app-emulation/fuse-utils/fuse-utils-1.4.3-r2.ebuild
rename to app-emulation/fuse-utils/fuse-utils-1.4.3-r3.ebuild
index 30000d877b620..e2dc6e59556dc 100644
--- a/app-emulation/fuse-utils/fuse-utils-1.4.3-r2.ebuild
+++ b/app-emulation/fuse-utils/fuse-utils-1.4.3-r3.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -6,7 +6,7 @@ EAPI=8
 inherit autotools
 
 DESCRIPTION="Utils for the Free Unix Spectrum Emulator by Philip Kendall"
-HOMEPAGE="http://fuse-emulator.sourceforge.net"
+HOMEPAGE="https://fuse-emulator.sourceforge.net"
 SRC_URI="https://downloads.sourceforge.net/fuse-emulator/${P}.tar.gz"
 
 LICENSE="GPL-2"
@@ -14,7 +14,7 @@ SLOT="0"
 KEYWORDS="~amd64 ~riscv ~x86"
 IUSE="audiofile gcrypt jpeg png zlib"
 
-RDEPEND=">=app-emulation/libspectrum-1.4.4[audiofile?,gcrypt?,zlib?]
+RDEPEND=">=app-emulation/libspectrum-1.4.4:=[audiofile?,gcrypt?,zlib?]
 	audiofile? ( >=media-libs/audiofile-0.3.6 )
 	gcrypt? ( dev-libs/libgcrypt )
 	jpeg? ( media-libs/libjpeg-turbo:= )
diff --git a/app-emulation/fuse-utils/fuse-utils-1.4.4.ebuild b/app-emulation/fuse-utils/fuse-utils-1.4.4.ebuild
new file mode 100644
index 0000000000000..0cc415f56c662
--- /dev/null
+++ b/app-emulation/fuse-utils/fuse-utils-1.4.4.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Utils for the Free Unix Spectrum Emulator by Philip Kendall"
+HOMEPAGE="https://fuse-emulator.sourceforge.net"
+SRC_URI="https://downloads.sourceforge.net/fuse-emulator/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="audiofile gcrypt jpeg png zlib"
+
+RDEPEND="
+	>=app-emulation/libspectrum-1.6.0:=[audiofile?,gcrypt?,zlib?]
+	dev-libs/glib:2
+	audiofile? ( >=media-libs/audiofile-0.3.6 )
+	gcrypt? ( dev-libs/libgcrypt )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	png? ( media-libs/libpng:0= )
+	zlib? ( virtual/zlib:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/remove-local-prefix.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		$(use_with audiofile)
+		$(use_with gcrypt libgcrypt)
+		$(use_with jpeg libjpeg)
+		$(use_with png libpng)
+		$(use_with zlib)
+	)
+	econf "${myconf[@]}"
+}
diff --git a/app-emulation/fuse/Manifest b/app-emulation/fuse/Manifest
index 127daceb5a379..af4129ce3b6bf 100644
--- a/app-emulation/fuse/Manifest
+++ b/app-emulation/fuse/Manifest
@@ -1 +1,2 @@
 DIST fuse-1.6.0.tar.gz 1686171 BLAKE2B d1e6b166f2f649f408349b16a5eb40dd414750ed7a805eb6505b6c81be6ed7bcaa4e6f0b14057645172add1b1a77881f90b64767390fe1a64a486168f452d29d SHA512 5096b24b5b3d812942a7ad401b886b6a99f5493686912cb4aff18ede65404ae97a9bcafa6337aaed4378382f2a170918797d7d4570bb809476be5aa9fc625b8b
+DIST fuse-1.7.0.tar.gz 1742469 BLAKE2B 55b652a15079539694e2e40cc002aec6d8566e1ff3ccb8c400b09a3db1246aacc3a1214afe970de769ccf609ffd7526fee224724319efa0e8adb9a5244557453 SHA512 9903773fd9ced1e36f4b0720201f721f9a3b7876a4d11ada95ffa328ec5bd166dc37c09818e7d96de3c45e5f26d074f4b072a1db6dd0786470dc9fbbb3483084
diff --git a/app-emulation/fuse/fuse-1.6.0-r4.ebuild b/app-emulation/fuse/fuse-1.6.0-r5.ebuild
similarity index 97%
rename from app-emulation/fuse/fuse-1.6.0-r4.ebuild
rename to app-emulation/fuse/fuse-1.6.0-r5.ebuild
index 2dd9ce002040e..fdcce36829fe0 100644
--- a/app-emulation/fuse/fuse-1.6.0-r4.ebuild
+++ b/app-emulation/fuse/fuse-1.6.0-r5.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -25,7 +25,7 @@ REQUIRED_USE="?? ( alsa ao backend-sdl pulseaudio )
 	png? ( zlib )"
 
 RDEPEND="
-	>=app-emulation/libspectrum-1.5.0[zlib?]
+	>=app-emulation/libspectrum-1.5.0:=[zlib?]
 	dev-libs/glib:2
 	alsa? ( media-libs/alsa-lib )
 	ao? ( media-libs/libao )
diff --git a/app-emulation/fuse/fuse-1.7.0.ebuild b/app-emulation/fuse/fuse-1.7.0.ebuild
new file mode 100644
index 0000000000000..bb3d80be7c491
--- /dev/null
+++ b/app-emulation/fuse/fuse-1.7.0.ebuild
@@ -0,0 +1,128 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic xdg
+
+DESCRIPTION="Free Unix Spectrum Emulator by Philip Kendall"
+HOMEPAGE="https://fuse-emulator.sourceforge.net"
+SRC_URI="https://downloads.sourceforge.net/fuse-emulator/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~riscv ~x86"
+IUSE="alsa ao backend-X backend-fbcon +backend-gtk3 backend-sdl gpm joystick memlimit png pulseaudio +xml +zlib"
+
+# TODO:
+# - allow using sdl audio driver without using for the UI
+# - allow using sdl joystick support with gtk3 or X UI in place of libjsw
+# - when using sdl for one of the above but not the UI, allow using sdl2 instead
+
+# At most one audio driver and at most one UI back-end can be enabled at a time
+REQUIRED_USE="?? ( alsa ao backend-sdl pulseaudio )
+	?? ( backend-X backend-fbcon backend-gtk3 backend-sdl )
+	png? ( zlib )"
+
+RDEPEND="
+	>=app-emulation/libspectrum-1.6.0:=[zlib?]
+	dev-libs/glib:2
+	alsa? ( media-libs/alsa-lib )
+	ao? ( media-libs/libao )
+	backend-X? (
+		x11-libs/libX11
+		x11-libs/libXext
+	)
+	backend-gtk3? (
+		x11-libs/cairo
+		x11-libs/gdk-pixbuf:2
+		x11-libs/gtk+:3
+		x11-libs/libX11
+		x11-libs/pango
+	)
+	backend-sdl? ( media-libs/libsdl[joystick,sound] )
+	gpm? ( backend-fbcon? ( sys-libs/gpm ) )
+	joystick? ( !backend-sdl? ( media-libs/libjsw ) )
+	png? ( media-libs/libpng:0= )
+	pulseaudio? ( media-libs/libpulse )
+	xml? ( dev-libs/libxml2:2= )
+	zlib? ( virtual/zlib:= )"
+DEPEND="${RDEPEND}
+	backend-fbcon? ( virtual/linux-sources )"
+BDEPEND="dev-lang/perl
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog README THANKS )
+
+PATCHES=(
+	"${FILESDIR}"/remove-local-prefix.patch
+)
+
+_fuse_audio_driver() {
+	if use alsa; then
+		echo "alsa"
+	elif use ao; then
+		echo "libao"
+	elif use backend-sdl; then
+		echo "sdl"
+	elif use pulseaudio; then
+		echo "pulseaudio"
+	else
+		echo "null"
+	fi
+}
+
+src_prepare() {
+	default
+	xdg_environment_reset
+	eautoreconf
+
+	# Bug #854522
+	filter-lto
+}
+
+src_configure() {
+	local myconf=(
+		--enable-desktop-integration
+		--without-win32
+		--with-audio-driver="$(_fuse_audio_driver)"
+		$(use_with gpm)
+		$(use_with joystick)
+		$(use_enable memlimit smallmem)
+		$(use_with png)
+		$(use_with xml libxml2)
+		$(use_with zlib)
+	)
+
+	# The pure-X UI hasn't got its own configure argument, instead it is
+	# what is used under Linux if all other back-ends have been disabled
+	# - and all except the Gtk+ one are off by default.
+	if use backend-X; then
+		myconf+=("--without-gtk")
+	elif use backend-fbcon; then
+		myconf+=("--with-fb")
+	elif use backend-gtk3; then
+		myconf+=("--with-gtk")
+	elif use backend-sdl; then
+		myconf+=("--with-sdl")
+	else
+		myconf+=("--with-null-ui")
+	fi
+
+	if use joystick; then
+		myconf+=( $(use_enable backend-sdl ui-joystick) )
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	emake test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	if use pulseaudio; then
+		ewarn "The PulseAudio driver in ${PN} is experimental"
+	fi
+}
diff --git a/app-emulation/libspectrum/Manifest b/app-emulation/libspectrum/Manifest
index 9ac9f648158c2..71e8872db3a84 100644
--- a/app-emulation/libspectrum/Manifest
+++ b/app-emulation/libspectrum/Manifest
@@ -1 +1,2 @@
 DIST libspectrum-1.5.0.tar.gz 602354 BLAKE2B fc62437ececfe2c86b475efa512bf7aa7c5af182e16a00f75f77f78656fca01d46a71ac90b38008ff46e5fd0710b1c671b283d65544b5556d98e8c5b66525c35 SHA512 55f4cf623bc6c469a0fd80751ada694259d834c19d98400ba244aabf2ac21fed7cdd6de069d9ed7326e099bd3bd62c42cfb8a669b64ae002f90a52563fa2dcd1
+DIST libspectrum-1.6.0.tar.gz 630698 BLAKE2B 6b210a1a71b4b3a65e3c4575061eeff1d891d9c8b2e53a5ef4d41e40b514dc6631671589dea232afc288b1476ecda7786b36fcc8486030d0fdfc93f5322833bd SHA512 f3bd1e35ba26c0230ba326a5765927ef237e1eee2ac77e656c18d1a285745e7f9720825a849ef763cfb27448e8cb1e8e95769ab5a194bf3c9d49a0e13e253d31
diff --git a/app-emulation/libspectrum/libspectrum-1.5.0.ebuild b/app-emulation/libspectrum/libspectrum-1.5.0-r1.ebuild
similarity index 89%
rename from app-emulation/libspectrum/libspectrum-1.5.0.ebuild
rename to app-emulation/libspectrum/libspectrum-1.5.0-r1.ebuild
index bd6837beee504..8f5f1e655d414 100644
--- a/app-emulation/libspectrum/libspectrum-1.5.0.ebuild
+++ b/app-emulation/libspectrum/libspectrum-1.5.0-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2025 Gentoo Authors
+# Copyright 1999-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -6,11 +6,11 @@ EAPI=8
 inherit autotools
 
 DESCRIPTION="Spectrum emulation library"
-HOMEPAGE="http://fuse-emulator.sourceforge.net/libspectrum.php"
+HOMEPAGE="https://fuse-emulator.sourceforge.net/libspectrum.php"
 SRC_URI="https://downloads.sourceforge.net/fuse-emulator/${P}.tar.gz"
 
 LICENSE="GPL-2"
-SLOT="0"
+SLOT="0/9"
 KEYWORDS="~amd64 ~ppc ~riscv ~x86"
 IUSE="audiofile bzip2 gcrypt zlib"
 
diff --git a/app-emulation/libspectrum/libspectrum-1.6.0.ebuild b/app-emulation/libspectrum/libspectrum-1.6.0.ebuild
new file mode 100644
index 0000000000000..23345b7dd66c0
--- /dev/null
+++ b/app-emulation/libspectrum/libspectrum-1.6.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Spectrum emulation library"
+HOMEPAGE="https://fuse-emulator.sourceforge.net/libspectrum.php"
+SRC_URI="https://downloads.sourceforge.net/fuse-emulator/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/18"
+KEYWORDS="~amd64 ~ppc ~riscv ~x86"
+IUSE="audiofile bzip2 gcrypt zlib"
+
+RDEPEND="dev-libs/glib:2
+	audiofile? ( >=media-libs/audiofile-0.3.6 )
+	bzip2? ( >=app-arch/bzip2-1.0 )
+	gcrypt? ( dev-libs/libgcrypt:0 )
+	zlib? ( virtual/zlib:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/remove-local-prefix.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		$(use_with audiofile libaudiofile)
+		$(use_with bzip2)
+		$(use_with gcrypt libgcrypt)
+		$(use_with zlib)
+	)
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	# check only builds test executable but doesn't run it
+	emake check
+	./test/test || die
+}
+
+src_install() {
+	default
+	dodoc doc/*.txt *.txt
+	find "${ED}" -type f -name "*.la" -delete || die
+}
diff --git a/app-emulation/virtualbox-additions/virtualbox-additions-7.1.16.ebuild b/app-emulation/virtualbox-additions/virtualbox-additions-7.1.16.ebuild
index f07acacae5069..fdec5d1d5717d 100644
--- a/app-emulation/virtualbox-additions/virtualbox-additions-7.1.16.ebuild
+++ b/app-emulation/virtualbox-additions/virtualbox-additions-7.1.16.ebuild
@@ -14,7 +14,7 @@ S="${WORKDIR}"
 
 LICENSE="GPL-3 || ( GPL-3 CDDL )"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64"
+KEYWORDS="amd64"
 
 src_unpack() {
 	return 0
diff --git a/app-emulation/virtualbox-additions/virtualbox-additions-7.2.6.ebuild b/app-emulation/virtualbox-additions/virtualbox-additions-7.2.6.ebuild
index f07acacae5069..fdec5d1d5717d 100644
--- a/app-emulation/virtualbox-additions/virtualbox-additions-7.2.6.ebuild
+++ b/app-emulation/virtualbox-additions/virtualbox-additions-7.2.6.ebuild
@@ -14,7 +14,7 @@ S="${WORKDIR}"
 
 LICENSE="GPL-3 || ( GPL-3 CDDL )"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64"
+KEYWORDS="amd64"
 
 src_unpack() {
 	return 0
diff --git a/app-emulation/virtualbox-extpack-oracle/virtualbox-extpack-oracle-7.1.16.ebuild b/app-emulation/virtualbox-extpack-oracle/virtualbox-extpack-oracle-7.1.16.ebuild
index fdd30bb6b345f..61f505038ea87 100644
--- a/app-emulation/virtualbox-extpack-oracle/virtualbox-extpack-oracle-7.1.16.ebuild
+++ b/app-emulation/virtualbox-extpack-oracle/virtualbox-extpack-oracle-7.1.16.ebuild
@@ -14,7 +14,7 @@ S="${WORKDIR}"
 
 LICENSE="PUEL-12"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64"
+KEYWORDS="amd64"
 RESTRICT="bindist mirror strip"
 
 RDEPEND="
diff --git a/app-emulation/virtualbox-extpack-oracle/virtualbox-extpack-oracle-7.2.6.ebuild b/app-emulation/virtualbox-extpack-oracle/virtualbox-extpack-oracle-7.2.6.ebuild
index fdd30bb6b345f..61f505038ea87 100644
--- a/app-emulation/virtualbox-extpack-oracle/virtualbox-extpack-oracle-7.2.6.ebuild
+++ b/app-emulation/virtualbox-extpack-oracle/virtualbox-extpack-oracle-7.2.6.ebuild
@@ -14,7 +14,7 @@ S="${WORKDIR}"
 
 LICENSE="PUEL-12"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64"
+KEYWORDS="amd64"
 RESTRICT="bindist mirror strip"
 
 RDEPEND="
diff --git a/app-emulation/virtualbox-guest-additions/virtualbox-guest-additions-7.1.16.ebuild b/app-emulation/virtualbox-guest-additions/virtualbox-guest-additions-7.1.16.ebuild
index e93f23fac8f98..b0ac3c2ced2c4 100644
--- a/app-emulation/virtualbox-guest-additions/virtualbox-guest-additions-7.1.16.ebuild
+++ b/app-emulation/virtualbox-guest-additions/virtualbox-guest-additions-7.1.16.ebuild
@@ -18,7 +18,7 @@ S="${WORKDIR}/${MY_PN}-${MY_PV}"
 
 LICENSE="GPL-3 LGPL-2.1+ MIT || ( GPL-3 CDDL )"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64 ~arm64 ~x86"
+KEYWORDS="amd64 ~arm64 x86"
 IUSE="+dbus gui"
 
 RDEPEND="
diff --git a/app-emulation/virtualbox-guest-additions/virtualbox-guest-additions-7.2.6.ebuild b/app-emulation/virtualbox-guest-additions/virtualbox-guest-additions-7.2.6.ebuild
index 3853b939c22cf..c25fe5958d64a 100644
--- a/app-emulation/virtualbox-guest-additions/virtualbox-guest-additions-7.2.6.ebuild
+++ b/app-emulation/virtualbox-guest-additions/virtualbox-guest-additions-7.2.6.ebuild
@@ -18,7 +18,7 @@ S="${WORKDIR}/${MY_PN}-${MY_PV}"
 
 LICENSE="GPL-3 LGPL-2.1+ MIT || ( GPL-3 CDDL )"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64 ~arm64 ~x86"
+KEYWORDS="amd64 ~arm64 x86"
 IUSE="+dbus gui"
 
 RDEPEND="
diff --git a/app-emulation/virtualbox-guest-modules/virtualbox-guest-modules-7.1.16.ebuild b/app-emulation/virtualbox-guest-modules/virtualbox-guest-modules-7.1.16.ebuild
index 06b21997c1b1a..d2f112bfc3f0c 100644
--- a/app-emulation/virtualbox-guest-modules/virtualbox-guest-modules-7.1.16.ebuild
+++ b/app-emulation/virtualbox-guest-modules/virtualbox-guest-modules-7.1.16.ebuild
@@ -17,7 +17,7 @@ S="${WORKDIR}"
 
 LICENSE="GPL-3"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64 ~arm64 ~x86"
+KEYWORDS="amd64 ~arm64 x86"
 
 PATCHES=(
 	"${FILESDIR}"/${PN}-6.1.36-log-use-c99.patch
diff --git a/app-emulation/virtualbox-guest-modules/virtualbox-guest-modules-7.2.6-r1.ebuild b/app-emulation/virtualbox-guest-modules/virtualbox-guest-modules-7.2.6-r1.ebuild
index 659be84b6acc3..daf4fb930facf 100644
--- a/app-emulation/virtualbox-guest-modules/virtualbox-guest-modules-7.2.6-r1.ebuild
+++ b/app-emulation/virtualbox-guest-modules/virtualbox-guest-modules-7.2.6-r1.ebuild
@@ -17,7 +17,7 @@ S="${WORKDIR}"
 
 LICENSE="GPL-3"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64 ~arm64 ~x86"
+KEYWORDS="amd64 ~arm64 x86"
 
 PATCHES=(
 	"${FILESDIR}"/${PN}-7.2.6-log-use-c99.patch
diff --git a/app-emulation/virtualbox-modules/virtualbox-modules-7.1.16.ebuild b/app-emulation/virtualbox-modules/virtualbox-modules-7.1.16.ebuild
index 6d3fc94edaff8..18eb0ace5d441 100644
--- a/app-emulation/virtualbox-modules/virtualbox-modules-7.1.16.ebuild
+++ b/app-emulation/virtualbox-modules/virtualbox-modules-7.1.16.ebuild
@@ -17,7 +17,7 @@ S="${WORKDIR}"
 
 LICENSE="GPL-3"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64"
+KEYWORDS="amd64"
 
 CONFIG_CHECK="~!SPINLOCK JUMP_LABEL ~PREEMPT_NOTIFIERS"
 
diff --git a/app-emulation/virtualbox-modules/virtualbox-modules-7.2.6-r2.ebuild b/app-emulation/virtualbox-modules/virtualbox-modules-7.2.6-r2.ebuild
index 6b6573ff19177..d43c4006ea812 100644
--- a/app-emulation/virtualbox-modules/virtualbox-modules-7.2.6-r2.ebuild
+++ b/app-emulation/virtualbox-modules/virtualbox-modules-7.2.6-r2.ebuild
@@ -17,7 +17,7 @@ S="${WORKDIR}"
 
 LICENSE="GPL-3"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64"
+KEYWORDS="amd64"
 
 PATCHES=(
 	"${FILESDIR}"/${P}-kernel-6.19-{1..3}.patch
diff --git a/app-emulation/virtualbox/virtualbox-7.1.16-r1.ebuild b/app-emulation/virtualbox/virtualbox-7.1.16-r1.ebuild
index fb2f65b06f31f..2b632622a0006 100644
--- a/app-emulation/virtualbox/virtualbox-7.1.16-r1.ebuild
+++ b/app-emulation/virtualbox/virtualbox-7.1.16-r1.ebuild
@@ -36,7 +36,7 @@ S="${WORKDIR}/${MY_PN}-${PV%*a}"
 
 LICENSE="GPL-2+ GPL-3 LGPL-2.1 MIT dtrace? ( CDDL )"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64"
+KEYWORDS="amd64"
 IUSE="alsa dbus debug doc dtrace +gui java lvm nls pam pch pulseaudio +opengl python +sdk +sdl test +udev vboxwebsrv vde +vmmraw vnc"
 RESTRICT="!test? ( test )"
 
diff --git a/app-emulation/virtualbox/virtualbox-7.2.6-r1.ebuild b/app-emulation/virtualbox/virtualbox-7.2.6-r1.ebuild
index ef31694c03a25..f976e4c8913b4 100644
--- a/app-emulation/virtualbox/virtualbox-7.2.6-r1.ebuild
+++ b/app-emulation/virtualbox/virtualbox-7.2.6-r1.ebuild
@@ -36,7 +36,7 @@ S="${WORKDIR}/${MY_PN}-${PV^^}"
 
 LICENSE="GPL-2+ GPL-3 LGPL-2.1 MIT dtrace? ( CDDL )"
 SLOT="0/$(ver_cut 1-2)"
-KEYWORDS="~amd64"
+KEYWORDS="amd64"
 IUSE="alsa dbus debug doc dtrace +gui java lvm nls pam pch pulseaudio +opengl python +sdk +sdl test +udev vboxwebsrv vde vnc"
 RESTRICT="!test? ( test )"
 
diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 299b2ae29edbb..aada333c413ed 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,3 +1,4 @@
 DIST fastfetch-2.56.1.tar.gz 1393184 BLAKE2B abcf98fa1248b08bd79b76367b6075f06d37b33bb6ded17cfb4b98070a3a38b0ee2018b157e16b04c5329d07ccade94058bf1afd58f4231d371d7cf09ba6c916 SHA512 cb6fb47597187565289efed843bf39e866b79d4cfa244614a734ecd1a266352f887a5fd6d02a2339810e79fdec24eeb25742fdfd68b196aabc8a8597e9a93ce5
 DIST fastfetch-2.58.0.tar.gz 1415337 BLAKE2B ad17dbc3d24e8fc70b87b405b4fa4f437cd2b57db9948c1cadfe3a902ea54ef41eafd1f3e7f6981b3b13e127209a4cabe7a1a680988f89cc5b1e14fbb0f60ead SHA512 f69fb50e5860a8cbb400b532658fcfd55d8dcde86e9ada00ccfaa93f902ee626c00f82e40fdc0c84bb3a13b7fd1c28220f674a04e7f00008faab8b33767eddc7
 DIST fastfetch-2.60.0.tar.gz 1428945 BLAKE2B fa1bb47489d2f5906f863da8de72f0971ecb9b2700832c2f317b6f3777b72a5fde4c1374dd46a97d229f9f1dd18a7db5273a54f1bed9b8c9207233b356b50e4f SHA512 b4984dd0b5ffbd002deea1b3c4d35d0e18857b6517fb493495fc4661448ea14861267671eefb8cd26909d6f2c0aa00989dfd18f9b34d1c1f5af8026e9457645a
+DIST fastfetch-2.61.0.tar.gz 1452448 BLAKE2B 1fabd1830fea19d764727e678340456c519bd8e5cd1098a4dd1f4a1495dedd372154c507c88056450ed4e4bfbed00ef7ed6018986355aab596ca678cba76eaaa SHA512 45bd9a0bd6b6911bf4eea419ee9f0e990b63a567c662cf1b567d7dd9f964443a55e4f061aea54a3c945d50238469d046bf45beb3c52a18bbc2921fbc25c221a8
diff --git a/app-misc/fastfetch/fastfetch-2.61.0.ebuild b/app-misc/fastfetch/fastfetch-2.61.0.ebuild
new file mode 100644
index 0000000000000..a9c8a037c914d
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.61.0.ebuild
@@ -0,0 +1,120 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm elf gnome imagemagick opencl opengl pulseaudio sqlite test vulkan wayland xcb xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.12.0
+	sys-apps/hwdata
+	virtual/zlib:=
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	elf? ( virtual/libelf:= )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? (
+		media-libs/libglvnd[X?]
+		X? ( x11-libs/libX11 )
+	)
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	opengl? ( X? ( x11-base/xorg-proto ) )
+	xcb? ( x11-base/xorg-proto )
+	xrandr? ( x11-base/xorg-proto )
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local glx=no
+	if use X; then
+		if use opengl; then
+			glx=yes
+		else
+			ewarn 'USE="X" adds GLX support for USE="opengl"'
+			ewarn 'This build with USE="X -opengl" will not include any extra X support.'
+		fi
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+		-DINSTALL_LICENSE=no
+		-DBUILD_FLASHFETCH=no
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_ELF=$(usex elf)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=${glx}
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}
diff --git a/net-im/mattermost-desktop-bin/Manifest b/net-im/mattermost-desktop-bin/Manifest
index 957cfc099d20e..a78d5d2334c85 100644
--- a/net-im/mattermost-desktop-bin/Manifest
+++ b/net-im/mattermost-desktop-bin/Manifest
@@ -2,3 +2,5 @@ DIST mattermost-desktop-5.13.5-linux-arm64.tar.gz 114225035 BLAKE2B 18d861762bd9
 DIST mattermost-desktop-5.13.5-linux-x64.tar.gz 114233206 BLAKE2B 30e56c7639b81b60a9415bb252093dafc580c5df3a2ea163ebc4e7cc4d87d63ce6c399f7b426d8b352f4900b182339383b8ddae9641f9fb7c323da2a1d5d2220 SHA512 c08bef2f0c6d9853fec7bf09928665d640034ae4b7dd1f38b75c6d0f3a77741c31cf93d1c6d1c233db50ac1231f16af31e16a33efb70c749eb07a82eb16856c0
 DIST mattermost-desktop-6.1.0-linux-arm64.tar.gz 116060984 BLAKE2B 699c4d4719a3634aee01bdf8ad39ccc61ea7b27f41780e45bfa0d99d09dd46093937d5b9946e5f0f5a66cc5ef8b39575992583521eb1d69c777de030b44c24a9 SHA512 af60367eae56729e6d500e8d23e7b871a07fa5254907b24b76089c17071866f307d41d6eb6ca6967dd69b6b8cf783ec9e544578128b2eaf1fc89d3d2cdd30655
 DIST mattermost-desktop-6.1.0-linux-x64.tar.gz 115642921 BLAKE2B c9a42577541d9199b7e6942478f68db7e5a60496f86eed2130c35414a52f49fcd8445e5933a9b75edd12784151d03dfb9396a14ebda34b86fda6d1ded24209e2 SHA512 f13c5cb372ce2fdb5a7f4dff0be22a38629a9df21c910f805e2b8ed168c74aaf1181a16cbab0fcffcbd765fbe427b901cae3757b7bf64859051f0d28db49aa17
+DIST mattermost-desktop-6.1.1-rc.1-linux-arm64.tar.gz 116165215 BLAKE2B 9b2a4cbcc57fe632dfc3f7b11997a48097f5c78fe27d27be52c71d5125955b0836ff55e5c93225fe79fb32cc94ddc5843d49f0b117ce2c47310071a0d6f0ca9d SHA512 5759a9cbd0f2715f391c525b7796c83f90f1156560c441b8df205e8dd2ac3e49862b46b42a160da37fd10b27b1c5571faa879050b3dd3636257297e5c846be45
+DIST mattermost-desktop-6.1.1-rc.1-linux-x64.tar.gz 115764980 BLAKE2B ce5ee69bb9c49c58419d4e244217573b71dd9c124dc7af679214903998bb0524937e6ed0c4e0045478d499cd3b84caba8ebdfb6d24ea178fc6e5777effa7ad0d SHA512 de5942528c58e4f7ed3733be1cf49d1f2040987c44c78b6c8dbe903b848f2d10740e51b0f393cc176e659f5b669a3bc8bf82b9362e9e2032f5bfd1d96253e069
diff --git a/net-im/mattermost-desktop-bin/mattermost-desktop-bin-6.1.1_rc1.ebuild b/net-im/mattermost-desktop-bin/mattermost-desktop-bin-6.1.1_rc1.ebuild
new file mode 100644
index 0000000000000..b0eeeb5bd45e4
--- /dev/null
+++ b/net-im/mattermost-desktop-bin/mattermost-desktop-bin-6.1.1_rc1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN%-*}"
+MY_PV="${PV/_rc/-rc.}"
+
+inherit desktop toolchain-funcs xdg
+
+DESCRIPTION="Mattermost Desktop application"
+HOMEPAGE="https://mattermost.com/"
+
+SRC_URI="
+	amd64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-x64.tar.gz )
+	arm64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-arm64.tar.gz )
+"
+S="${WORKDIR}"
+
+LICENSE="Apache-2.0 GPL-2+ LGPL-2.1+ MIT"
+SLOT="0"
+if [[ ${PV} != *rc* ]]; then
+	KEYWORDS="~amd64 ~arm64"
+fi
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2[X]
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	virtual/libudev
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3[X]
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango
+"
+
+BDEPEND="
+	dev-util/debugedit
+"
+
+QA_PREBUILT="
+	opt/mattermost-desktop/mattermost-desktop
+	opt/mattermost-desktop/libnode.so
+	opt/mattermost-desktop/libffmpeg.so
+	opt/mattermost-desktop/libGLESv2.so
+	opt/mattermost-desktop/libEGL.so
+	opt/mattermost-desktop/libvk_swiftshader.so
+	opt/mattermost-desktop/libvulkan.so.1
+	opt/mattermost-desktop/resources/*
+"
+
+DOCS=(
+	NOTICE.txt
+)
+
+src_prepare() {
+	default
+
+	# file collision with FEATURES=splitdebug, see bug #961437
+	tc-export OBJCOPY
+	find . -type f ! -name '*$(*)*' -print0 | while IFS= read -r -d '' file; do
+		if file "${file}" | grep -qE "ELF (32|64)-bit"; then
+			${OBJCOPY} --remove-section .note.gnu.build-id "${file}" || die
+			debugedit -b "${EPREFIX}/opt/${MY_PN}" -d "/usr/lib/debug" -i "${file}" || die
+		fi
+	done
+}
+
+src_install() {
+	if use amd64; then
+		cd mattermost-desktop-${MY_PV}-linux-x64 || die
+	elif use arm64; then
+		cd mattermost-desktop-${MY_PV}-linux-arm64 || die
+	fi
+	newicon app_icon.png ${MY_PN}.png
+
+	insinto "/opt/${MY_PN}/locales"
+	doins locales/*.pak
+
+	insinto "/opt/${MY_PN}/resources"
+	doins -r resources/*.asar*
+
+	insinto "/opt/${MY_PN}"
+	doins *.pak *.bin *.dat
+	exeinto "/opt/${MY_PN}"
+	doexe *.so *.so.* "${MY_PN}"
+
+	dosym -r "/opt/${MY_PN}/${MY_PN}" "/usr/bin/${MY_PN}"
+
+	make_desktop_entry \
+		"${MY_PN} --enable-features=WaylandWindowDecorations --ozone-platform-hint=auto %U" \
+		Mattermost "${MY_PN}" "Network;InstantMessaging;" \
+		"MimeType=x-scheme-handler/mattermost;\nStartupWMClass=Mattermost"
+
+	einstalldocs
+}