kde-apps/kalarm: 25.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/kalarm/Manifest

@@ -1,2 +1,3 @@
 DIST kalarm-24.12.3.tar.xz 2648416 BLAKE2B 16cbc23c6752d6fdf7befb458580387c8d02f48c538d8c719370d88ffd2b0837ee189e731cb99cda3c9a71bbe4599a7543f0e02804883a54b8ac842cdb986f3b SHA512 47945cfa9e2f1af590f7fcde523da04043331545eced9f7ba934f54609195013f4461e292901042e3ec28d60b337adae1da6e947afe0d9e2222fa1337e32c3ce
 DIST kalarm-25.04.2.tar.xz 2687416 BLAKE2B 5054525cb7d98cc696ba126bc77a4cfdd8e2ca9e6c092a5d59e50778f981da3927f25680b0a612154101f2cbb28ca44da19f5a3bfe7afde3807980b1783f03cb SHA512 1281ac30cdfee58aac64879aec983b151690a7e406045a56c2b3e9c2092d15b2b2b7fd5d6a7b76492b7d28931d767ff1d9f9c3fe92da6795b98d79b22d51a048
+DIST kalarm-25.04.3.tar.xz 2687380 BLAKE2B 4c531aa185148a5372363bc1300f00513fb7f61f95a868c9229c521b5c60838d203182b3f3ff6b8ecd32c5a5974959b5b27ce070b310e2ff1fac97e2ba8ce4d3 SHA512 37dc3defd446a9b54a2045f634446f56b6fa463088e22c77e3f8355a9079af52c56e1bc440b1b0a49dafd7db8ce525369ef140eb29a7c6559d728392af1bd21d

kde-apps/kalarm/kalarm-25.04.3.ebuild

@@ -0,0 +1,89 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.13.0
+QTMIN=6.7.2
+inherit ecm gear.kde.org xdg
+
+DESCRIPTION="Application to manage alarms and other timer based alerts for the desktop"
+HOMEPAGE="https://apps.kde.org/kalarm/ https://userbase.kde.org/KAlarm"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64"
+IUSE="mpv +pim speech X"
+
+COMMON_DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
+	>=kde-apps/kcalutils-${PVCUT}:6=
+	>=kde-apps/kidentitymanagement-${PVCUT}:6=
+	>=kde-apps/kmime-${PVCUT}:6=
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcalendarcore-${KFMIN}:6
+	>=kde-frameworks/kcodecs-${KFMIN}:6
+	>=kde-frameworks/kcolorscheme-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcontacts-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6
+	>=kde-frameworks/kholidays-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/knotifyconfig-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6[X?]
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	mpv? ( >=media-video/mpv-0.37.0:=[libmpv] )
+	!mpv? ( media-video/vlc:= )
+	pim? (
+		>=kde-apps/akonadi-${PVCUT}:6=
+		>=kde-apps/akonadi-contacts-${PVCUT}:6=
+		>=kde-apps/akonadi-mime-${PVCUT}:6=
+		>=kde-apps/kmailtransport-${PVCUT}:6=
+	)
+	speech? ( >=dev-libs/ktextaddons-1.5.4:6[speech] )
+	X? ( x11-libs/libX11 )
+"
+RDEPEND="${COMMON_DEPEND}
+	pim? ( =kde-apps/kdepim-runtime-${PVCUT}*:6 )
+"
+# kde-apps/kidentitymanagement through its cmake module forces
+# kpimtextedit[speech=] in order not to break w/ kalarm[-speech]
+DEPEND="${COMMON_DEPEND}
+	>=kde-apps/kpimtextedit-${PVCUT}:6[speech=]
+	X? ( x11-base/xorg-proto )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_LIBMPV=$(usex mpv)
+		-DENABLE_LIBVLC=$(usex !mpv)
+		-DENABLE_AKONADI_PLUGIN=$(usex pim)
+		$(cmake_use_find_package speech KF6TextEditTextToSpeech)
+		-DWITHOUT_X11=$(usex !X)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# LC_TIME bug 665626, 857012
+	# TZ bug https://bugs.kde.org/show_bug.cgi?id=445734
+	LC_TIME="C" TZ=UTC ecm_src_test
+}