dev-libs/metee: add 6.1.0

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

dev-libs/metee/Manifest

@@ -1 +1,2 @@
 DIST metee-6.0.2.tar.gz 119084 BLAKE2B 31ced32744d5c2fe38bc409bb90682d8c66051704c1c3fc5f4abe2947e2272f5d3c1b921a04dbd14935c3260d88154d5e3cd3509e62006b3196d133601152d36 SHA512 a1f8e77c201a4864bd04d9ff4aac5beca451ab77cc57b6ba8164cfdf005c693371c0558dac123b832a62a30929260b9777405dd6732651f0e9361834ac74eca2
+DIST metee-6.1.0.tar.gz 120485 BLAKE2B 73b233b9a9478d3830749146515cc1a50f25aa133639662b21a4f01dc17ddb2c0ade4fe3b8137e03b2112c44a391d5d3d067a144a6662a1206c21e5681cae0aa SHA512 9f1f869c64e3d889c0ab5e0b1a7f2772ba196a6580d280d06051f2020ff2228470aeb3da34964f5b2d6c401cf03d61aaeee98b8581e1c1ee17e7e6632d02c83d

dev-libs/metee/metee-6.1.0.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake edo
+
+DESCRIPTION="Cross-platform access library for Intel CSME HECI interface"
+HOMEPAGE="https://github.com/intel/metee"
+SRC_URI="https://github.com/intel/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	doc? ( app-text/doxygen )
+	test? ( dev-cpp/gtest )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.0.0-system-gtest.patch
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Respect users CFLAGS
+	sed -e 's/-D_FORTIFY_SOURCE=2 -O2//' -e 's/-Werror//' -i linux.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DOCS="$(usex doc)"
+		-DBUILD_SAMPLES="NO"
+		-DBUILD_SHARED_LIBS="YES"
+		-DBUILD_TEST="$(usex test)"
+		-DCONSOLE_OUTPUT="NO"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local skip_tests=(
+		MeTeeTESTInstance/MeTeeTEST.PROD_N_TestGetMeiKind/PCH
+		MeTeePPTESTInstance/MeTeePPTEST.PROD_MKHI_MoveSemantics/PCH
+	)
+
+	# The format for disabling test1, test2, and test3 looks like:
+	# -test1:test2:test3
+	edo "${BUILD_DIR}"/tests/metee_test \
+		--gtest_filter=-$(echo $(IFS=:; echo "${skip_tests[*]}"))
+}
+
+src_install() {
+	cmake_src_install
+
+	# Don't install test binary
+	if use test ; then
+		rm "${ED}"/usr/bin/metee_test || die
+	fi
+}