From 95d61df0c1ea80a49243a1ed8071cfcb095ca48b Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 19 Oct 2024 10:30:24 +0200
Subject: [PATCH] dev-python/httpcore: Remove old
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/httpcore/Manifest              |  1 -
 dev-python/httpcore/httpcore-1.0.5.ebuild | 69 -----------------------
 2 files changed, 70 deletions(-)
 delete mode 100644 dev-python/httpcore/httpcore-1.0.5.ebuild

diff --git a/dev-python/httpcore/Manifest b/dev-python/httpcore/Manifest
index 03a7245cbd719..951672d1d0c2f 100644
--- a/dev-python/httpcore/Manifest
+++ b/dev-python/httpcore/Manifest
@@ -1,2 +1 @@
-DIST httpcore-1.0.5.gh.tar.gz 97696 BLAKE2B 2e05f790e0e67c36f86ac1ee47eea716f820d68678eff63e73bce0f652448d782c66764e7f1ab3f8e891ebf2243b96ba79ca211ea769bbf5df117342e2942cbb SHA512 4b37f3874e65908598b906167d5b0840f66ffef95b65110d318d9e64df5fd23770a08ea44ea2f3cf6f9db50f20bb9fec99b40323b959675b37168414cf397bf8
 DIST httpcore-1.0.6.gh.tar.gz 99863 BLAKE2B 0da9b958674d92ed787c0310ad6819cd9359b6e608bfff1b366233ba10085905ec5aeb1b1f0b99ea3fef84aaed31f3aa832ced3fa22cb659e3016c0626dac997 SHA512 f83fb851267bb2007a1735d387acba4d99a957db7f85decd5dc6d7d7235a41fe50081b33267e61dc5c52627f07429ba99839868e95997cff1f6c8b2c046a0596
diff --git a/dev-python/httpcore/httpcore-1.0.5.ebuild b/dev-python/httpcore/httpcore-1.0.5.ebuild
deleted file mode 100644
index 04de9d7b576a2..0000000000000
--- a/dev-python/httpcore/httpcore-1.0.5.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( pypy3 python3_{10..13} )
-
-inherit distutils-r1 optfeature
-
-DESCRIPTION="A minimal low-level HTTP client"
-HOMEPAGE="
-	https://www.encode.io/httpcore/
-	https://github.com/encode/httpcore/
-	https://pypi.org/project/httpcore/
-"
-SRC_URI="
-	https://github.com/encode/httpcore/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
-
-RDEPEND="
-	<dev-python/anyio-5[${PYTHON_USEDEP}]
-	dev-python/certifi[${PYTHON_USEDEP}]
-	<dev-python/h11-0.15[${PYTHON_USEDEP}]
-	<dev-python/h2-5[${PYTHON_USEDEP}]
-	=dev-python/sniffio-1*[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
-	test? (
-		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
-		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
-		dev-python/socksio[${PYTHON_USEDEP}]
-		dev-python/trustme[${PYTHON_USEDEP}]
-		$(python_gen_cond_dep '
-			dev-python/pytest-trio[${PYTHON_USEDEP}]
-			dev-python/trio[${PYTHON_USEDEP}]
-		' 3.{10..13})
-	)
-"
-
-distutils_enable_tests pytest
-
-python_test() {
-	local opts=()
-	local EPYTEST_IGNORE=()
-
-	if ! has_version "dev-python/trio[${PYTHON_USEDEP}]"; then
-		opts+=( -k "not trio" )
-		EPYTEST_IGNORE+=(
-			tests/_async/test_connection_pool.py
-		)
-	fi
-
-	if ! has_version "dev-python/pytest-trio[${PYTHON_USEDEP}]"; then
-		opts+=( -m "not trio" -o addopts= )
-	fi
-
-	epytest "${opts[@]}"
-}
-
-pkg_postinst() {
-	optfeature "SOCKS support" dev-python/socksio
-}