dev-python/flask-mongoengine: Support python 3.6

Package-Manager: Portage-2.3.40, Repoman-2.3.9

dev-python/flask-mongoengine/flask-mongoengine-0.9.3-r1.ebuild

@@ -0,0 +1,44 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+RESTRICT="test" # requires running MongoDB server
+
+DESCRIPTION="Flask support for MongoDB and with WTF model forms"
+HOMEPAGE="https://pypi.org/project/flask-mongoengine/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/flask-0.8[${PYTHON_USEDEP}]
+	>=dev-python/mongoengine-0.7.10[${PYTHON_USEDEP}]
+	dev-python/flask-wtf[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	# fix distutils sandbox violation due to missing test-deps in normal build
+	sed -i '/test_requirements/d' setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}