From 90d0e40f508194e279a6584fe2f55ca695ab89b1 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Fri, 14 Nov 2025 14:26:10 +0000
Subject: [PATCH] app-backup/duplicity: add 3.0.6.1

Signed-off-by: Sam James <sam@gentoo.org>
---
 app-backup/duplicity/Manifest                 |  1 +
 app-backup/duplicity/duplicity-3.0.6.1.ebuild | 72 +++++++++++++++++++
 app-backup/duplicity/duplicity-9999.ebuild    |  2 +-
 3 files changed, 74 insertions(+), 1 deletion(-)
 create mode 100644 app-backup/duplicity/duplicity-3.0.6.1.ebuild

diff --git a/app-backup/duplicity/Manifest b/app-backup/duplicity/Manifest
index 52d13046d1d7f..d490ccae05332 100644
--- a/app-backup/duplicity/Manifest
+++ b/app-backup/duplicity/Manifest
@@ -1,3 +1,4 @@
 DIST duplicity-3.0.6-fix-pexpect-sftp-regression.patch.xz 6892 BLAKE2B b872c3bacf80d0224269937a958e508bd03ccffb10ef53730d8300d072c2e4961c5a48e010aff315474e30fbefcc461c2ff75718aecb550b379bbdbf12df9465 SHA512 76238d85c33ad91417046abd02e3e5a20e538f39406f2a5d95402e48cb122680dce94d01704421b2597d0b5fe8783c64e09270f23f456ee55bfc527990698f8a
 DIST duplicity-rel.3.0.5.tar.bz2 952327 BLAKE2B a5befdcfbca07655b690c681a7858e181029f6432583006872d9a1fe446a157717d6bfdc8462b087d719548ad8e761efb35b37ee23441bd7ed7830cbf5ed1612 SHA512 c57cd0192989ea98ef297aa5eb1e80f32f885af8c035521fffed115e2bd77af187b726a500e8d2e3f4100b00490cc62079dcba4568ca0d17239763477d3e7cb5
+DIST duplicity-rel.3.0.6.1.tar.bz2 958273 BLAKE2B 5018689e2d3cafde97933f7d194acaaf5d43536e792f6588215a6d6f6751dc23aab628eb3b636bba24f9d74d32bf29debf27619216789fd49277acc76d06ae0a SHA512 8da5018a41253c326ec2602c603abf3876af7ad9f4dc98f77ce2c70e8b69324ccb6fb20e8ca9b7e467c0c4dd29ea5d3ce7e3929a66308c8a25b68cb449b43141
 DIST duplicity-rel.3.0.6.tar.bz2 960619 BLAKE2B 9b83008408a3ef5148614e3db1a87f45347cae11455d0f9295570231b0d85fbd987d3724c5623a0713e412ebb496d6ea81ca611c88b769d210e597aca468f934 SHA512 4c385a53a0e70e1d7b6cde564d8ef458a765273583b73375af113a065006fa75204e0596f7a7e4eb3bcb090889548f4c5878a5c744ce5f34f610c0843dea3ce3
diff --git a/app-backup/duplicity/duplicity-3.0.6.1.ebuild b/app-backup/duplicity/duplicity-3.0.6.1.ebuild
new file mode 100644
index 0000000000000..42cb83263b89e
--- /dev/null
+++ b/app-backup/duplicity/duplicity-3.0.6.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_EXT=1
+
+inherit distutils-r1
+
+DESCRIPTION="Secure backup system using gnupg to encrypt data"
+HOMEPAGE="https://duplicity.gitlab.io/"
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://gitlab.com/duplicity/duplicity.git/"
+	inherit git-r3
+else
+	SRC_URI="https://gitlab.com/duplicity/duplicity/-/archive/rel.${PV}/${PN}-rel.${PV}.tar.bz2"
+	S="${WORKDIR}"/${PN}-rel.${PV}
+
+	KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="s3 test"
+
+COMMON_DEPEND="
+	net-libs/librsync
+	app-crypt/gnupg
+	dev-python/fasteners[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${COMMON_DEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		|| ( app-arch/par2cmdline app-arch/par2cmdline-turbo )
+		dev-python/pexpect[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	dev-python/paramiko[${PYTHON_USEDEP}]
+	s3? ( dev-python/boto3[${PYTHON_USEDEP}] )
+"
+
+EPYTEST_DESELECT=(
+	# Linting tests (black, pylint, etc); not relevant for us
+	testing/test_code.py::CodeTest::test_black
+	testing/test_code.py::CodeTest::test_pep8
+	testing/test_code.py::CodeTest::test_pylint
+	# boto3
+	testing/unit/test_cli_main.py::CommandlineTest::test_intermixed_args
+)
+
+EPYTEST_IGNORE=(
+	testing/test_code.py
+)
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.0.4.0-fix-docs-cmd.patch
+	"${FILESDIR}"/${PN}-3.0.5-dont-repeat-standard-paths.patch
+)
+
+distutils_enable_tests pytest
+
+pkg_postinst() {
+	elog "Duplicity has many optional dependencies to support various backends."
+	elog "Currently it's up to you to install them as necessary."
+}
diff --git a/app-backup/duplicity/duplicity-9999.ebuild b/app-backup/duplicity/duplicity-9999.ebuild
index 6b72e1fb4daab..42cb83263b89e 100644
--- a/app-backup/duplicity/duplicity-9999.ebuild
+++ b/app-backup/duplicity/duplicity-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{11..13} )
+PYTHON_COMPAT=( python3_{11..14} )
 DISTUTILS_USE_PEP517=setuptools
 DISTUTILS_EXT=1