games-emulation/mednafen-jg: add 1.32.1.1

Signed-off-by: orbea <orbea@riseup.net>
Signed-off-by: Sam James <sam@gentoo.org>

games-emulation/mednafen-jg/Manifest

@@ -1 +1,2 @@
+DIST mednafen-1.32.1.1.tar.bz2 4430513 BLAKE2B 6cfecf12b962e46696b352c37fb1c3476e4a9a175ee65cf3f332f1f983bbec3ae0096fbbb27c3cf222a50bdb1e595f62debaf0117b10ac10c9d8b06613e55d47 SHA512 81b42120319c452347f03928aa5c7957d0906de5e413149c9f7403a6776f537ed2eadd0b41cdc45a608c246d9ceade5090755f790255017bd2223115655b20a9
 DIST mednafen-1.32.1.tar.bz2 4428510 BLAKE2B b85ef506e9d0f76b08469f12dc1f57e0cdb789c9b36b50ad03ed1dbbc9640e2109a37f639acb5d9f7f8d17f97f9aca97700c75ffcfcd53c3a8098fb7f0d3d128 SHA512 1cbf88a3f95ead46cd4e106a701e7adefd54cd1869394e6e907f89370ba434b3999d8a5372e5f2ded43135716aed739fb5313f680687de20f1c4b8e74af54b60

games-emulation/mednafen-jg/mednafen-jg-1.32.1.1.ebuild

@@ -0,0 +1,69 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+MY_PN=${PN%-*}
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="Jolly Good Port of Mednafen"
+HOMEPAGE="https://gitlab.com/jgemu/mednafen"
+if [[ "${PV}" == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/jgemu/${MY_PN}.git"
+else
+	SRC_URI="https://gitlab.com/jgemu/${MY_PN}/-/archive/${PV}/${MY_P}.tar.bz2"
+	S="${WORKDIR}/${MY_P}"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="BSD GPL-2 GPL-2+ LGPL-2.1+ ZLIB"
+SLOT="1"
+IUSE="cpu_flags_x86_avx"
+
+DEPEND="
+	app-arch/zstd
+	dev-libs/lzo:2
+	>=dev-libs/trio-1.17
+	media-libs/flac
+	media-libs/jg:1=
+	sys-libs/zlib:=[minizip]
+	virtual/libiconv
+"
+RDEPEND="
+	${DEPEND}
+	games-emulation/jgrf
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	cd jollygood/conf || die
+	eautoreconf
+}
+
+src_configure() {
+	cd jollygood/conf || die
+	econf $(use_enable cpu_flags_x86_avx avx)
+}
+
+src_compile() {
+	emake -C jollygood \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		PKG_CONFIG="$(tc-getPKG_CONFIG)" \
+		USE_EXTERNAL_TRIO=1
+}
+
+src_install() {
+	emake -C jollygood install \
+		DESTDIR="${D}" \
+		PREFIX="${EPREFIX}"/usr \
+		DOCDIR="${EPREFIX}"/usr/share/doc/${PF} \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
+		USE_EXTERNAL_TRIO=1
+}