From 8e52680d31369d7449eb341ff262c30a80ce44e0 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Fri, 11 Jul 2025 20:43:37 +0200
Subject: [PATCH] kde-frameworks/breeze-icons: 6.16.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-frameworks/breeze-icons/Manifest          |  1 +
 .../breeze-icons/breeze-icons-6.16.0.ebuild   | 48 +++++++++++++++++++
 2 files changed, 49 insertions(+)
 create mode 100644 kde-frameworks/breeze-icons/breeze-icons-6.16.0.ebuild

diff --git a/kde-frameworks/breeze-icons/Manifest b/kde-frameworks/breeze-icons/Manifest
index f983504731440..aae288cbe4967 100644
--- a/kde-frameworks/breeze-icons/Manifest
+++ b/kde-frameworks/breeze-icons/Manifest
@@ -1,2 +1,3 @@
 DIST breeze-icons-6.13.0.tar.xz 2255616 BLAKE2B e81489fdc704b0a5d15f4af693214c4b07846d43b0e99c0a029828c8e729c3c05475d96b9556b13d825e00797d8a1a03c843f6d85c4b69ac5a03b9da4c51ef1f SHA512 03734a0838b2545d4320d9a0b75625558cb83247cd1c455c909cca917a8c7e4b46df3ff4ea9d0935237a57d6bf1387e290b1005e3eb01c46d506339d5ca68687
 DIST breeze-icons-6.15.0.tar.xz 2255160 BLAKE2B e9eaad39160b347a02b12476b88ccae86c9c338e803293c177954ffa08dedd4a72cf1e9217dd1497f0d6bebba8c53d7ad15449f6b46592258342409c292dc3e6 SHA512 433ef5ffb48f485a64eee2fa7d30aa76dadc167495901234ebf80bb395c6307df2ef798484db9d7886ecad2797a930ab405f8eb5e285ab0a62cdbf9b3cda2eee
+DIST breeze-icons-6.16.0.tar.xz 2256520 BLAKE2B 356e1e93c094503aa472606be5e3d5dbf34e95b43440e0315972ae710b18c7ea0cf9f8951115aa8ea1eef3c2c424615053e7aeab4a52b8dbe8c9570cadde7fc4 SHA512 589e7bf8885dbc19e309613b00620714f1e6b9b85093b864c64fde5be0f14f3e11671c76e4ec5d25b6729a75fc815b1e78d21f5091fcbdcb7d5f5442576963af
diff --git a/kde-frameworks/breeze-icons/breeze-icons-6.16.0.ebuild b/kde-frameworks/breeze-icons/breeze-icons-6.16.0.ebuild
new file mode 100644
index 0000000000000..e02d7a9a24dab
--- /dev/null
+++ b/kde-frameworks/breeze-icons/breeze-icons-6.16.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit cmake frameworks.kde.org python-any-r1 xdg
+
+DESCRIPTION="Breeze SVG icon theme"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!kde-frameworks/${PN}:5
+	!kde-frameworks/${PN}-rcc:5
+	!kde-frameworks/${PN}-rcc:6
+"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtbase:6[gui]
+	>=kde-frameworks/extra-cmake-modules-${KDE_CATV}:*
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	python_has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=ON # TODO: remove when kexi was ported away
+		-DSKIP_INSTALL_ICONS=OFF
+		-DBUILD_TESTING="$(usex test)"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# bug 770988
+	find "${ED}"/usr/share/icons/ -type d -empty -delete || die
+	find "${ED}"/usr/share/icons/ -xtype l -delete || die
+}