From 8b9e03cf7f5fdc62eab6290ccada6bbfb62294b6 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sun, 8 Jan 2023 06:15:27 +0100
Subject: [PATCH] dev-python/google-auth: Remove Python < 3.10 in -r1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 .../google-auth/google-auth-2.15.0-r1.ebuild  | 58 +++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-python/google-auth/google-auth-2.15.0-r1.ebuild

diff --git a/dev-python/google-auth/google-auth-2.15.0-r1.ebuild b/dev-python/google-auth/google-auth-2.15.0-r1.ebuild
new file mode 100644
index 0000000000000..2dc5b30afbe82
--- /dev/null
+++ b/dev-python/google-auth/google-auth-2.15.0-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Google Authentication Library"
+HOMEPAGE="
+	https://github.com/googleapis/google-auth-library-python/
+	https://pypi.org/project/google-auth/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 x86"
+
+RDEPEND="
+	<dev-python/cachetools-6.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.2.1[${PYTHON_USEDEP}]
+	>=dev-python/rsa-3.1.4[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	!dev-python/namespace-google
+"
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/grpcio[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/pyu2f[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/urllib3[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# these are compatibility tests with oauth2client
+	# disable them to unblock removal of that package
+	tests/test__oauth2client.py
+)
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}