gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-07-29 22:28:08 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/llvmlite: Bump to 0.27.1

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2019-02-02 08:19:44 +01:00
parent dabeae7b0f
commit 8ada36c4dd
2 changed files with 64 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/llvmlite/Manifest
View File

@@ -2,3 +2,4 @@ DIST llvmlite-0.20.0.tar.gz 96753 BLAKE2B ec9cfa554f44162c0d6e755628603c9afd8564
DIST llvmlite-0.22.0.gh.tar.gz 156077 BLAKE2B 1b95a0636807fcf38955b32bd5c7c19784df2cc6708f23624c047f0e9caf4eb2fc26c7a1cb778d7cc7e42b8aeaee1ed43c92bcdaf7eb2e798c25f692b96b786a SHA512 633ec4d294dc246ebff5c7931e9bea86efa28323242411f3f54bc34c99085ebaef477b5bfd8224080790a12b188308ff9662c284b360e1a2939f4fe9b84a9458
DIST llvmlite-0.26.0.gh.tar.gz 175536 BLAKE2B 6736e94c13974bb79bcda08ef58dd6d1e67d07a0173b5f2ab1b2fcf9a6e72b2a0b8737da5598023fa0c6db85cfd84f2d429f6077e1342a15b500376addd03c69 SHA512 e6bf76b209f44624fe21551971d422bbee6a6dcdfbd2c42607904be32db1b94cfcb185e70198fced5deadd938208d66d94eed4cea31726ae7f4779d58b57eb48
DIST llvmlite-0.27.0.gh.tar.gz 186891 BLAKE2B c7175beeb5c45b6fda62b78b23352d1c22111a37e7fdb89897409c6ab245dab23aa4f799fd5add1bf2199e8f6783d6094101aa29c4afefa2a3dbd48d735b418a SHA512 6c3230f23fec53ddff077c885bc0da4a773049d0226817142e2b7ded9fe6a665dd5cf8c6468101b342ef8e3b394bf2078cf93fc513e46fe451cd75755111448b
DIST llvmlite-0.27.1.gh.tar.gz 186904 BLAKE2B ee3af4b3ec03799ea6e643e0ee0a793537c46427d239fb3a26abf4a719b68432f403367321345c30a95758ce1bce411495bc48273dbf2452a872a1edd67dc9a4 SHA512 365ffd95050a39269d9f806d3969657437111b8e999db6cf03d0d99fc5bcc024dbc08f1d379745572317f8d4384d7f86095216674695c34f463a0b9bf48a8be7

63
dev-python/llvmlite/llvmlite-0.27.1.ebuild Normal file
View File

@@ -0,0 +1,63 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
inherit distutils-r1 llvm
DESCRIPTION="Python wrapper around the llvm C++ library"
HOMEPAGE="http://llvmlite.pydata.org/"
SRC_URI="https://github.com/numba/llvmlite/archive/v${PV/_/}.tar.gz -> ${P/_/}.gh.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="examples"
LLVM_MAX_SLOT=7
RDEPEND="
dev-python/six[${PYTHON_USEDEP}]
sys-devel/llvm:${LLVM_MAX_SLOT}
sys-libs/zlib:0=
virtual/python-enum34[${PYTHON_USEDEP}]
"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]
"
S=${WORKDIR}/${P/_/}
PATCHES=(
"${FILESDIR}"/llvmlite-0.15.0-use-system-six.patch
)
python_configure_all() {
# upstream's build system is just horrible, and they ignored the PR
# fixing it, so let's build the shared lib properly using implicit
# make rules
export LDLIBS=$(llvm-config --libs all)
export CXXFLAGS="$(llvm-config --cxxflags) -fPIC ${CXXFLAGS}"
export LDFLAGS="$(llvm-config --ldflags) ${LDFLAGS}"
local files=( ffi/*.cpp )
emake -f - <<EOF
ffi/libllvmlite.so: ${files[*]/.cpp/.o}
\$(CXX) -shared \$(CXXFLAGS) \$(LDFLAGS) -o \$@ \$^ \$(LDLIBS)
EOF
}
python_test() {
"${EPYTHON}" runtests.py -v || die "Tests failed under ${EPYTHON}"
}
python_install_all() {
distutils-r1_python_install_all
if use examples; then
dodoc -r examples
docompress -x /usr/share/doc/${PF}/examples
fi
}