dev-python/sqlalchemy-rqlite: new package

Package-Manager: portage-2.2.28

dev-python/sqlalchemy-rqlite/sqlalchemy-rqlite-9999.ebuild

@@ -0,0 +1,40 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_{4,5}} )
+
+inherit distutils-r1
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+fi
+
+DESCRIPTION="A SQLAlchemy dialect for rqlite"
+EGIT_REPO_URI="https://github.com/rqlite/sqlalchemy-rqlite.git"
+HOMEPAGE="${EGIT_REPO_URI%.git}/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/pyrqlite[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		dev-python/pylint[${PYTHON_USEDEP}]
+	)"
+
+src_prepare() {
+	sed -e "s:^__version__ = .*:__version__ = '${PV}':" -i src/sqlalchemy_rqlite/constants.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	esetup.py test || die "tests failed"
+	esetup.py lint -f text -E || die "pylint failed"
+}