dev-lua/lanes: add 3.16.1

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
This commit is contained in:
Conrad Kostecki
2023-08-27 01:42:01 +02:00
parent e08dce9412
commit 8a9d72fe2f
2 changed files with 94 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST lanes-3.16.0.tar.gz 257945 BLAKE2B aecc0bd551f10b29791acdde8da30fb83591395eac4d152999a0e92fe9738a6171b13363edae2d94b1db47398a01e011833ccee7a7f234033d3230605423c0b6 SHA512 ffd935baae8af752591251bbb1a7f936034ad281870d453e6e1b4291c175c91537ccae23ec25a616b45e8ab601222f323e05e938d7887091ba7e132b0cd5e449
DIST lanes-3.16.1.tar.gz 446136 BLAKE2B e9505db907660378eb2e67f674a9e671c9554d7587ddeedca6ecaf332cdd03985d027ae5dfa7ae510da9c710b2dc70246e4eb42812347068536dd070a396e20b SHA512 bbc4e7d4dccb10a25f7560dbc4980e36b8f6bb0fbce667471d0be0ad028afc7e1dc88810e78be52a3aee9846512ec10a5ddd324dbe53f9a1db9af647f959014e
+93
View File
@@ -0,0 +1,93 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LUA_COMPAT=( lua5-{1..4} luajit )
inherit lua toolchain-funcs
DESCRIPTION="Lightweight, native, lazy evaluating multithreading library"
HOMEPAGE="https://github.com/LuaLanes/lanes"
SRC_URI="https://github.com/LuaLanes/lanes/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="test"
REQUIRED_USE="${LUA_REQUIRED_USE}"
# Tests are currently somehow problematic.
# https://github.com/LuaLanes/lanes/issues/197
# https://github.com/LuaLanes/lanes/issues/198
RESTRICT="test"
RDEPEND="${LUA_DEPS}"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
test? ( ${RDEPEND} )
"
HTML_DOCS=( "docs/." )
PATCHES=( "${FILESDIR}/${PN}-3.13.0-makefile.patch" )
src_prepare() {
default
lua_copy_sources
}
lua_src_compile() {
pushd "${BUILD_DIR}" || die
local myemakeargs=(
"CC=$(tc-getCC)"
"LUA=${ELUA}"
"LUA_FLAGS=$(lua_get_CFLAGS)"
"LUA_LIBS="
"OPT_FLAGS=${CFLAGS}"
)
tc-export PKG_CONFIG
emake "${myemakeargs[@]}"
popd
}
src_compile() {
lua_foreach_impl lua_src_compile
}
lua_src_test() {
pushd "${BUILD_DIR}" || die
emake LUA="${ELUA}" test
popd
}
src_test() {
lua_foreach_impl lua_src_test
}
lua_src_install() {
pushd "${BUILD_DIR}" || die
local myemakeargs=(
"LUA_LIBDIR=${ED}/$(lua_get_cmod_dir)"
"LUA_SHAREDIR=${ED}/$(lua_get_lmod_dir)"
)
emake "${myemakeargs[@]}" install
popd
}
src_install() {
lua_foreach_impl lua_src_install
einstalldocs
}