From 890e0183ec69e9a96db3ec6cdabd819cc0c0d52f Mon Sep 17 00:00:00 2001
From: Eli Schwartz <eschwartz@gentoo.org>
Date: Fri, 20 Jun 2025 01:51:18 -0400
Subject: [PATCH] dev-debug/d-feet: update EAPI 7 -> 8

Signed-off-by: Eli Schwartz <eschwartz@gentoo.org>
---
 dev-debug/d-feet/d-feet-0.3.16-r1.ebuild | 58 ++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-debug/d-feet/d-feet-0.3.16-r1.ebuild

diff --git a/dev-debug/d-feet/d-feet-0.3.16-r1.ebuild b/dev-debug/d-feet/d-feet-0.3.16-r1.ebuild
new file mode 100644
index 0000000000000..8906868d1ce60
--- /dev/null
+++ b/dev-debug/d-feet/d-feet-0.3.16-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit gnome2 meson python-single-r1 virtualx
+
+DESCRIPTION="D-Feet is a powerful D-Bus debugger"
+HOMEPAGE="https://wiki.gnome.org/Apps/DFeet"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+IUSE="test +X"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=x11-libs/gtk+-3.9.4:3[introspection]
+	>=dev-libs/gobject-introspection-0.9.6:=
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-libs/glib-2.34:2
+	$(python_gen_cond_dep '
+		>=dev-python/pygobject-3.3.91:3[${PYTHON_USEDEP}]
+	')
+	>=sys-apps/dbus-1
+	X? ( x11-libs/libwnck:3[introspection] )
+"
+BDEPEND="
+	dev-util/itstool
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.3.16-fix-meson-0.61.patch
+	"${FILESDIR}"/0001-Do-not-lint-coding-style-in-distro-testing.patch
+)
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use test tests)
+		-Dpython="${EPYTHON}"
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}