dev-python/jaraco-text: bump to 1.7, EAPI=6, add doc

Package-Manager: portage-2.3.0_rc1
Closes: https://github.com/gentoo/gentoo/pull/1621

Signed-off-by: Patrice Clement <monsieurp@gentoo.org>

dev-python/jaraco-text/Manifest

@@ -1 +1,2 @@
 DIST jaraco.text-1.6.3.tar.gz 5971 SHA256 47f4e0cb30a34c50e16d369bf80a5a5119dd0692d5379d5091edced46956e501 SHA512 3eb15f6142c5afbea5deabca08cc7b1fa53afa84a8cdc0b9d488c58901dac32c4a5f9e79e7d6606aaed3658fc3266f9db486c68f5353eb524dc604f2e4b2dc35 WHIRLPOOL 313d2ecad01aa516886116e61ae2c118f0b5b135feb21938166a8c9166763686510f7d7c4900e6acef7bfab33e0db264562d664f790df3b5ec633114c20fdd13
+DIST jaraco.text-1.7.tar.gz 7020 SHA256 10ae286a70f391ab7b787863a8b3f538a0e2901d3c6eeffc0c4b23c13e608c1d SHA512 b1418dc19b52e353da3b2a332ffbc9a4201c6696ecc962722e25fd6549c8748a9dbea2cf76f658111aa4e3fd411ee999b526fa4d8148259866dbe95ebc4cfa95 WHIRLPOOL 5f08fd96576dbda3aaca3aca047bafe72939f66f61882a513cbe7dec07c3a8a187aa7eae9f5aedfe9ee9f4d497aae3dd0c62039f3ae7321687b11ed34f975e43

dev-python/jaraco-text/jaraco-text-1.7.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+DESCRIPTION="Text utilities used by other projects by developer jaraco"
+HOMEPAGE="https://github.com/jaraco/jaraco.text"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+PDEPEND="dev-python/jaraco-collections[${PYTHON_USEDEP}]"
+RDEPEND="dev-python/jaraco-functools[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.9[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/rst-linker[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	PYTHONPATH=. py.test || die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	distutils-r1_python_install_all
+}

dev-python/jaraco-text/metadata.xml

@@ -4,7 +4,6 @@
 	<maintainer type="person">
 		<email>sautier.louis@gmail.com</email>
 		<name>Louis Sautier</name>
-		<description>Proxied maintainer; set to assignee in all bugs</description>
 	</maintainer>
 	<maintainer type="project">
 		<email>proxy-maint@gentoo.org</email>
@@ -13,5 +12,6 @@
 	<upstream>
 		<remote-id type="pypi">jaraco.text</remote-id>
 		<remote-id type="github">jaraco/jaraco.text</remote-id>
+		<bugs-to>https://github.com/jaraco/jaraco.text/issues</bugs-to>
 	</upstream>
 </pkgmetadata>