diff --git a/dev-python/tavern/Manifest b/dev-python/tavern/Manifest
index d51cbaa9c3621..d65d253ac477f 100644
--- a/dev-python/tavern/Manifest
+++ b/dev-python/tavern/Manifest
@@ -1 +1,2 @@
 DIST tavern-2.16.0.gh.tar.gz 241605 BLAKE2B 1c813c80de9680f700668200961a0cbe3a16c0fc9e169fa32724c35ff518e9b337639f493c586bd23f42aa1cff1fcbca64fac8807a1cdb0925c61a738450f736 SHA512 9bf582e2f118630bd036dcf726fafe4a79092981e77631e82e9be3f1504d73f68bf650be2fb815412e2dc1fc4ab63587801bff646dcc4dd503415c139f47f3d7
+DIST tavern-2.17.0.gh.tar.gz 243762 BLAKE2B aca42310622fe769ff6a6201c4fd4faa613ff2a73910044d4eed9ab60f3e731e1614e3cea9deee8a47c553f9156462da5312e358fe58b52beb45fe4a60e847e0 SHA512 33f01a13bf87a6015bb0896bb7184ca584da43b1543a620b0577cfe2f7ebc71c550008e0febd0634e9649394322a41ded32e1b482abfd26fe750a2c46a5a0894
diff --git a/dev-python/tavern/tavern-2.17.0.ebuild b/dev-python/tavern/tavern-2.17.0.ebuild
new file mode 100644
index 0000000000000..ce42f586360fa
--- /dev/null
+++ b/dev-python/tavern/tavern-2.17.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="A tool, library, and Pytest plugin for testing RESTful APIs"
+HOMEPAGE="
+	https://github.com/taverntesting/tavern/
+	https://pypi.org/project/tavern/
+"
+SRC_URI="
+	https://github.com/taverntesting/tavern/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/jmespath-1[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4[${PYTHON_USEDEP}]
+	>=dev-python/paho-mqtt-1.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/pykwalify-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/pytest-7[${PYTHON_USEDEP}]
+	>=dev-python/python-box-6[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.22.0[${PYTHON_USEDEP}]
+	>=dev-python/simpleeval-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/colorlog[${PYTHON_USEDEP}]
+		dev-python/faker[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( "${PN}" )
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires grpc
+	tests/unit/test_extensions.py::TestGrpcCodes
+	# broken with paho-mqtt-2
+	tests/unit/test_mqtt.py::TestClient::test_context_connection_success
+)
+EPYTEST_IGNORE=(
+	# require grpc*
+	tavern/_plugins/grpc
+	tests/unit/tavern_grpc
+)
+
+src_prepare() {
+	# strip unnecessary pins, upstream doesn't update them a lot
+	sed -i -E -e 's:,?<=?[0-9.]+::' pyproject.toml || die
+	distutils-r1_src_prepare
+}