dev-python/nagiosplugin: support Python 3.8, use distutils_* helpers

Package-Manager: Portage-2.3.96, Repoman-2.3.22
Signed-off-by: Louis Sautier <sbraz@gentoo.org>

dev-python/nagiosplugin/nagiosplugin-1.3.2-r1.ebuild

@@ -0,0 +1,19 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy3 python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="A class library for writing nagios-compatible plugins"
+HOMEPAGE="https://github.com/mpounsett/nagiosplugin https://nagiosplugin.readthedocs.io"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="ZPL"
+SLOT="0"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc dev-python/sphinx_rtd_theme

dev-python/nagiosplugin/nagiosplugin-1.3.2.ebuild

@@ -1,38 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( pypy3 python3_{6,7} )
-
-inherit distutils-r1
-
-DESCRIPTION="A class library for writing nagios-compatible plugins"
-HOMEPAGE="https://github.com/mpounsett/nagiosplugin https://nagiosplugin.readthedocs.io"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc test"
-RESTRICT="!test? ( test )"
-
-LICENSE="ZPL"
-SLOT="0"
-
-BDEPEND="
-	dev-python/setuptools[${PYTHON_USEDEP}]
-	doc? (
-		dev-python/sphinx[${PYTHON_USEDEP}]
-		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
-	)
-	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
-"
-
-python_compile_all() {
-	if use doc; then
-		sphinx-build doc doc/_build/html || die
-		HTML_DOCS=( doc/_build/html/. )
-	fi
-}
-
-python_test() {
-	pytest -vv tests || die "tests failed with ${EPYTHON}"
-}