dev-python/uvloop: Version bump to 0.5.3

Gentoo-Bug: https://bugs.gentoo.org/593082

Package-Manager: portage-2.2.28
Closes: https://github.com/gentoo/gentoo/pull/2273

Signed-off-by: David Seifert <soap@gentoo.org>

dev-python/uvloop/Manifest

@@ -1 +1,2 @@
 DIST uvloop-0.4.20.tar.gz 1781445 SHA256 b39afbc242eafff7471337468b28c4164f55d130f8194e0fb4a8b2eb71cb1298 SHA512 c7f540da9d29340fb0cc0e589143fabc12d4c185d4e7eff889e3434478f445e98c703fd9024af66b6b121bce3c860be2b4da497a6492a43df5891e86b6007d7e WHIRLPOOL 1d50e45cf92fca4b983222038e6524359e7160d0ac87b89265dd298d0fa9f33527c5a839752e6cc0a2d34c6eb27f0919474085616885c779b876a8638a0c5ba1
+DIST uvloop-0.5.3.tar.gz 1913999 SHA256 ee402d2df4bf092f6f036637db41bb2896f7c6832adf91dbb6dfec0e6dfa6aee SHA512 7902557e865f6b346edcf7c71ea06e6970b7844d47c0d46aee23bb6ec8cae292a0d77960fc5fcaf0c4b47220c1f5f76b92546ccf94694f07adfd04474355a638 WHIRLPOOL 05c509e832a6866016c7187ac2ec71b9f1c2493a2d57594be341144a2ccfa9c478c2525bb0d348cc2e960350eab2969a46dd6fb3c57cc88e0fa489459590869e

dev-python/uvloop/uvloop-0.5.3.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_5 )
+inherit distutils-r1
+
+DESCRIPTION="Ultra-fast implementation of asyncio event loop on top of libuv."
+HOMEPAGE="https://github.com/magicstack/uvloop"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-libs/libuv-1.9.0:="
+DEPEND="
+	${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/alabaster-0.6.2[${PYTHON_USEDEP}]
+		>=dev-python/cython-0.24.1[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-python/cython-0.24.1[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	cat <<EOF >> setup.cfg
+[build_ext]
+use-system-libuv=1
+EOF
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake docs
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}