dev-python/construct: update to 2.9.46

Drop python2_7, add python3_7, enable tests

Closes: https://bugs.gentoo.org/679424
Signed-off-by: Azamat H. Hackimov <azamat.hackimov@gmail.com>
Package-Manager: Portage-2.3.76, Repoman-2.3.16
Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/construct/construct-2.9.46.ebuild

@@ -0,0 +1,34 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="A powerful declarative parser for binary data"
+HOMEPAGE="https://construct.readthedocs.io/en/latest/ https://pypi.org/project/construct/"
+SRC_URI="https://github.com/construct/construct/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+distutils_enable_tests pytest
+BDEPEND+="
+	test? (
+		dev-python/arrow[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.15.4[${PYTHON_USEDEP}]
+	)"
+
+src_prepare() {
+	default
+	rm tests/test_benchmarks.py || die
+}
+
+pkg_postinst() {
+	ewarn "Version 2.9.x has significant API and implementation changes from"
+	ewarn "previous 2.8.x releases. Please read the documentation at"
+	ewarn "https://construct.readthedocs.io/en/latest/transition29.html"
+	ewarn "for more info."
+}