From 861c7cfb378586bbc29af6ae02fcc0df5522736b Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Mon, 21 Apr 2025 13:09:03 +0200
Subject: [PATCH] app-i18n/fcitx-unikey: Drop IUSE qt5, qt6; fix IUSE gui no-op

- app-i18n/fcitx-qt[qt6(+)] USEdep default analogous to fcitx-configtool
- USE=-gui was doing nothing since ENABLE_QT is default enabled
- USE=qt5 was doing nothing since it did not tick any cmake arg
- nor was it exclusive-or enforced by REQUIRED_USE constraints
  but their cmake build system does not allow both to be enabled
- wire up IUSE test with cmake arg

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 .../fcitx-unikey/fcitx-unikey-5.1.6-r1.ebuild | 38 +++++++++++++++++++
 .../fcitx-unikey/fcitx-unikey-5.1.6.ebuild    |  2 +-
 2 files changed, 39 insertions(+), 1 deletion(-)
 create mode 100644 app-i18n/fcitx-unikey/fcitx-unikey-5.1.6-r1.ebuild

diff --git a/app-i18n/fcitx-unikey/fcitx-unikey-5.1.6-r1.ebuild b/app-i18n/fcitx-unikey/fcitx-unikey-5.1.6-r1.ebuild
new file mode 100644
index 0000000000000..2c287b009738e
--- /dev/null
+++ b/app-i18n/fcitx-unikey/fcitx-unikey-5.1.6-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="fcitx5-unikey"
+inherit cmake unpacker xdg
+
+DESCRIPTION="Unikey (Vietnamese Input Method) engine support for Fcitx"
+HOMEPAGE="https://fcitx-im.org/ https://github.com/fcitx/fcitx5-unikey"
+SRC_URI="https://download.fcitx-im.org/fcitx5/${MY_PN}/${MY_PN}-${PV}.tar.zst"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gui test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=app-i18n/fcitx-5.1.12:5
+	>=app-i18n/fcitx-qt-5.1.4:5[qt6(+),-onlyplugin]
+	gui? ( dev-qt/qtbase:6[dbus,gui,widgets] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	kde-frameworks/extra-cmake-modules:0
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_QT=$(usex gui)
+		-DENABLE_TEST=$(usex test)
+		-DUSE_QT6=ON
+	)
+	cmake_src_configure
+}
diff --git a/app-i18n/fcitx-unikey/fcitx-unikey-5.1.6.ebuild b/app-i18n/fcitx-unikey/fcitx-unikey-5.1.6.ebuild
index 6536fa939b239..69102a4d17e29 100644
--- a/app-i18n/fcitx-unikey/fcitx-unikey-5.1.6.ebuild
+++ b/app-i18n/fcitx-unikey/fcitx-unikey-5.1.6.ebuild
@@ -15,7 +15,7 @@ S="${WORKDIR}/${MY_PN}-${PV}"
 LICENSE="LGPL-2+ GPL-2+"
 SLOT="5"
 KEYWORDS="~amd64 ~x86"
-IUSE="+gui +qt5 qt6 test"
+IUSE="+gui qt5 +qt6 test"
 RESTRICT="!test? ( test )"
 
 RDEPEND="