dev-python/blockbuster: New package, v1.5.24

New test dependency for dev-python/aiohttp.

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/blockbuster/Manifest

@@ -0,0 +1 @@
+DIST blockbuster-1.5.24.tar.gz 51245 BLAKE2B 6d1e6a66154603d0a485dd77041b24488a35f9b07ec7b833b3ef2893edaada798e1feca158ceed7ba347cfcc738adc52d846991ec90808aa6a523a03403988cd SHA512 f286c1fad7236783aae81111480a43c946819264c7584fe9cdc466cdfff0c63c5076a9c74397e5f37782f5957c68834a1db7640a5aeae2bc0a2961fc472e7824

dev-python/blockbuster/blockbuster-1.5.24.ebuild

@@ -0,0 +1,61 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Utility to detect blocking calls in the async event loop"
+HOMEPAGE="
+	https://github.com/cbornet/blockbuster/
+	https://pypi.org/project/blockbuster/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/forbiddenfruit-0.1.4[${PYTHON_USEDEP}]
+	' 'python*')
+"
+BDEPEND="
+	test? (
+		dev-python/aiofiles[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/test_blockbuster.py::test_ssl_socket
+	)
+
+	case ${EPYTHON} in
+		pypy3.11)
+			EPYTEST_DESELECT+=(
+				# upstream doesn't care, however that doesn't stop
+				# people from depending on it...
+				# https://github.com/cbornet/blockbuster/issues/47
+				tests/test_blockbuster.py::test_file_random
+				tests/test_blockbuster.py::test_file_read_bytes
+				tests/test_blockbuster.py::test_file_text
+				tests/test_blockbuster.py::test_file_write_bytes
+				tests/test_blockbuster.py::test_lock
+				tests/test_blockbuster.py::test_os_scandir
+				tests/test_blockbuster.py::test_scanned_modules
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p asyncio
+}

dev-python/blockbuster/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">cbornet/blockbuster</remote-id>
+		<remote-id type="pypi">blockbuster</remote-id>
+	</upstream>
+</pkgmetadata>