From 849068830764c9092de79d51a9751009f7abb2b9 Mon Sep 17 00:00:00 2001
From: Benda Xu <heroxbd@gentoo.org>
Date: Sat, 9 Jun 2018 05:56:27 +0900
Subject: [PATCH] dev-python/ipykernel: handle the multiple python3 case.

  Bonus of verion bump.

Credit: Colin MacLean
Closes: https://bugs.gentoo.org/628222
Package-Manager: Portage-2.3.28, Repoman-2.3.9
---
 dev-python/ipykernel/Manifest                 |  1 +
 .../ipykernel/ipykernel-4.6.1-r2.ebuild       |  2 +-
 dev-python/ipykernel/ipykernel-4.8.2.ebuild   | 45 +++++++++++++++++++
 3 files changed, 47 insertions(+), 1 deletion(-)
 create mode 100644 dev-python/ipykernel/ipykernel-4.8.2.ebuild

diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 19978affb1198..5011acb82ed0f 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1 +1,2 @@
 DIST ipykernel-4.6.1.tar.gz 90591 BLAKE2B 9d66e569e416e30fa0af93e9442326a081638e55e004c751d38b3e995e2e1c6baeba5b61e125ae8484a31344ca541070035154e4453f9eda30f7a2ac436e7f1c SHA512 3124534a8a059056211ac573784c491ba18d6e936292523382a9604af10bc2c911b14f49f7625242e29189b46c673da25244f3c9dfa3148d460ba4e466eef001
+DIST ipykernel-4.8.2.tar.gz 94441 BLAKE2B cdcf08c114c6c53ce4ed9829f3c2e0d2184f5b89b54556f92df25ecefadcc38955f992572a6dfb9ee49477e9a2111304c9b4f636edc47c0c0a26209c5f616579 SHA512 6542b086ef14abe70f51393e585c1e02eac0967b863c2e3de2dfdcbcdc2f4c01597bd035990f09f07d76005628a3345be97d1b5e5ce7a772ce7074bb31b4d4df
diff --git a/dev-python/ipykernel/ipykernel-4.6.1-r2.ebuild b/dev-python/ipykernel/ipykernel-4.6.1-r2.ebuild
index 0beee570792b2..0b67f85acfe52 100644
--- a/dev-python/ipykernel/ipykernel-4.6.1-r2.ebuild
+++ b/dev-python/ipykernel/ipykernel-4.6.1-r2.ebuild
@@ -36,7 +36,7 @@ python_install() {
 	distutils-r1_python_install
 
 	# bug 628222, specify python 2 or 3.
-	sed -e "s:python:${EPYTHON}:" \
+	sed -e "s:python:${EPYTHON%.*}:" \
 		-i "${ED}"usr/share/jupyter/kernels/${EPYTHON%.*}/kernel.json || die
 }
 
diff --git a/dev-python/ipykernel/ipykernel-4.8.2.ebuild b/dev-python/ipykernel/ipykernel-4.8.2.ebuild
new file mode 100644
index 0000000000000..98f9a7f4602e4
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-4.8.2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="https://github.com/ipython/ipykernel"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/ipython-4.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '<dev-python/ipython-6[${PYTHON_USEDEP}]' 'python2*')
+	dev-python/jupyter_client[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.1.0[${PYTHON_USEDEP}]
+	>=www-servers/tornado-4.0[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/nose_warnings_filters[${PYTHON_USEDEP}]
+	)
+"
+
+python_install() {
+	distutils-r1_python_install
+
+	# bug 628222, specify python 2 or 3.
+	sed -e "s:python:${EPYTHON%.*}:" \
+		-i "${ED}"usr/share/jupyter/kernels/${EPYTHON%.*}/kernel.json || die
+}
+
+python_test() {
+	nosetests --verbose ipykernel || die
+}