From 7f92bfcb14e34cee88c6db89e3ddd8f0638607c9 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Wed, 29 May 2024 06:10:14 +0200
Subject: [PATCH] dev-python/uvicorn: Bump to 0.30.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/uvicorn/Manifest              |  1 +
 dev-python/uvicorn/uvicorn-0.30.0.ebuild | 75 ++++++++++++++++++++++++
 2 files changed, 76 insertions(+)
 create mode 100644 dev-python/uvicorn/uvicorn-0.30.0.ebuild

diff --git a/dev-python/uvicorn/Manifest b/dev-python/uvicorn/Manifest
index 036951a881478..57a48cf100d16 100644
--- a/dev-python/uvicorn/Manifest
+++ b/dev-python/uvicorn/Manifest
@@ -1 +1,2 @@
 DIST uvicorn-0.29.0.gh.tar.gz 719202 BLAKE2B 15a1e9d001e00805d9efe89c1b46416f6556d944ec5a32fb31c8368d4c0e1e32155169e9b5754c7d56a3ee86a1b7edddcf0d9a641abf74fdb89c1332ebd289af SHA512 bb37940acc2eba2a649d07ba44890400332e5ad873ac03c6740c1bc730068ede39c2e6d9aefb0f100ec261d7ed2eef1596c99a060fd8000cff874b25bdbbbdfa
+DIST uvicorn-0.30.0.gh.tar.gz 722322 BLAKE2B 5868f27cf8589b00737c77904dd60a4996641610bd9216744c89fbf39956d4f2764249b45f7736c11141f214544aeaaf196d22421fb52596a9e3517931d500c2 SHA512 1e090fe7b1a5eb00fa11359694e5bc0a577d206e97e65c6dba0b401c2c2d11d621ed69b5f0e883e1757a660a823d0f3ab4fe9a041bb3f738086337ac8dad108b
diff --git a/dev-python/uvicorn/uvicorn-0.30.0.ebuild b/dev-python/uvicorn/uvicorn-0.30.0.ebuild
new file mode 100644
index 0000000000000..9511a7d54223f
--- /dev/null
+++ b/dev-python/uvicorn/uvicorn-0.30.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Lightning-fast ASGI server implementation"
+HOMEPAGE="
+	https://www.uvicorn.org/
+	https://github.com/encode/uvicorn/
+	https://pypi.org/project/uvicorn/
+"
+# as of 0.28.0, no tests in sdist
+SRC_URI="
+	https://github.com/encode/uvicorn/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test-rust"
+
+RDEPEND="
+	>=dev-python/asgiref-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/click-7.0[${PYTHON_USEDEP}]
+	>=dev-python/h11-0.8[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	test? (
+		dev-python/a2wsgi[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/python-dotenv[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		>=dev-python/websockets-10.4[${PYTHON_USEDEP}]
+		dev-python/wsproto[${PYTHON_USEDEP}]
+		test-rust? (
+			dev-python/cryptography[${PYTHON_USEDEP}]
+			dev-python/trustme[${PYTHON_USEDEP}]
+			dev-python/watchfiles[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# too long path for unix socket
+		tests/test_config.py::test_bind_unix_socket_works_with_reload_or_workers
+	)
+	case ${EPYTHON} in
+		pypy3)
+			# TODO
+			EPYTEST_DESELECT+=(
+				tests/middleware/test_logging.py::test_running_log_using_fd
+			)
+			;;
+	esac
+
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "auto reload on file changes" dev-python/watchfiles
+}