From 7dd764a89caf7133e51cce664dee7bacd6de55b3 Mon Sep 17 00:00:00 2001
From: Justin Lecher <jlec@gentoo.org>
Date: Tue, 23 Feb 2016 10:22:16 +0100
Subject: [PATCH] dev-python/qtconsole: Version Bump

Package-Manager: portage-2.2.27
Signed-off-by: Justin Lecher <jlec@gentoo.org>
---
 dev-python/qtconsole/Manifest               |  1 +
 dev-python/qtconsole/qtconsole-4.2.0.ebuild | 68 +++++++++++++++++++++
 2 files changed, 69 insertions(+)
 create mode 100644 dev-python/qtconsole/qtconsole-4.2.0.ebuild

diff --git a/dev-python/qtconsole/Manifest b/dev-python/qtconsole/Manifest
index cc3f3c2f67bd2..a8b53e68c20a2 100644
--- a/dev-python/qtconsole/Manifest
+++ b/dev-python/qtconsole/Manifest
@@ -1 +1,2 @@
 DIST qtconsole-4.1.1.tar.gz 406257 SHA256 741906acae9e02c0df9138ac88b621ef22e438565aa96d783a9ef88faec3de46 SHA512 2848eb8d3a8816a47ca422b24837372899864e750336509f3d8444333d0783bae46b9917258cab14d4e09d91d5068a7772fb849a267e1a7d6e282c7c75e9f4e9 WHIRLPOOL 1a3a638be2bdea3f9ab6d625edd110ef698a84cfdf3b1f4101375faf8ed60a0e8e9ab6e297575dab8e2e6389107ba62a6bb338c78934780e19dd4c498aee9eb9
+DIST qtconsole-4.2.0.tar.gz 408331 SHA256 937314f4f35bde9ee28e97b199289f8ac1b1ba14e2a4e22ab8aafa17a1bae5b7 SHA512 bf8ab82b316961ecf14e56dda27bb1253e7e56b10adc7388b1a6a8548526a756da45a16b34e891e966dfa72cdd73a571390b23b9ed1e5d4cb684f2ba14569368 WHIRLPOOL 4ccb073c2d29ee1908696867af41c28c1cc51a2c30a7d2e030de7dacc0e069788d2f08756c6a22044fc58cec9d1df84fe1de10692d8d0eea0ffe31c9a6d64b66
diff --git a/dev-python/qtconsole/qtconsole-4.2.0.ebuild b/dev-python/qtconsole/qtconsole-4.2.0.ebuild
new file mode 100644
index 0000000000000..7ea50addbcec1
--- /dev/null
+++ b/dev-python/qtconsole/qtconsole-4.2.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Qt-based console for Jupyter with support for rich media output"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-4.1.1[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? (
+		>=dev-python/ipython-4.0.0-r2[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.3.1-r1[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-python/nose-0.10.1[${PYTHON_USEDEP}]
+	)
+	|| (
+		dev-python/pyside[${PYTHON_USEDEP},svg]
+		dev-python/PyQt4[${PYTHON_USEDEP},svg]
+		dev-python/PyQt5[${PYTHON_USEDEP},svg]
+	)
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-13[${PYTHON_USEDEP}]
+	"
+PDEPEND="dev-python/ipython[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	# jupyter qtconsole --generate-config ... jupyter-qtconsole: cannot connect to X server
+	# ERROR
+	sed \
+		-e 's:test_generate_config:_&:g' \
+		-i qtconsole/tests/test_app.py || die
+	virtx nosetests --verbosity=2 qtconsole
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}