diff --git a/dev-lua/lua-term/lua-term-0.7-r100.ebuild b/dev-lua/lua-term/lua-term-0.7-r100.ebuild
new file mode 100644
index 0000000000000..5ced1bbb4f1a5
--- /dev/null
+++ b/dev-lua/lua-term/lua-term-0.7-r100.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+MY_PV="0.07"
+MY_PV_SO="1.0.1"
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Terminal operations for Lua"
+HOMEPAGE="https://github.com/hoelzro/lua-term"
+SRC_URI="https://github.com/hoelzro/lua-term/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="${LUA_DEPS}"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+ default
+
+ # Respect users CFLAGS
+ sed -e 's/-O3//g' -i Makefile
+}
+
+lua_src_compile() {
+ # Clean project to compile it for every lua slot
+ emake clean
+
+ local myemakeargs=(
+ "CC=$(tc-getCC)"
+ "CFLAGS=${CFLAGS} ${LDFLAGS} $(lua_get_CFLAGS)"
+ )
+
+ emake "${myemakeargs[@]}" all
+
+ # Copy module to match the choosen LUA implementation
+ cp "core.so.${MY_PV_SO}" "core-${ELUA}.so.${MY_PV_SO}" || die
+}
+
+src_compile() {
+ lua_foreach_impl lua_src_compile
+}
+
+lua_src_install() {
+ # Use correct module for the choosen LUA implementation
+ cp "core-${ELUA}.so.${MY_PV_SO}" "core.so.${MY_PV_SO}" || die
+
+ local myemakeargs=(
+ LUA_LIBDIR="${ED}/$(lua_get_cmod_dir)/term"
+ LUA_SHARE="${ED}/$(lua_get_lmod_dir)/term"
+ )
+
+ emake "${myemakeargs[@]}" install
+}
+
+src_install() {
+ lua_foreach_impl lua_src_install
+}
diff --git a/dev-lua/lua-term/metadata.xml b/dev-lua/lua-term/metadata.xml
index cd082b51556ce..a0fd1bd9d692b 100644
--- a/dev-lua/lua-term/metadata.xml
+++ b/dev-lua/lua-term/metadata.xml
@@ -5,6 +5,10 @@
williamh@gentoo.org
William Hubbs
+
+ conikost@gentoo.org
+ Conrad Kostecki
+
hoelzro/lua-term
diff --git a/profiles/package.mask b/profiles/package.mask
index 5a1c0da8b6d55..3c83c65166949 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -508,6 +508,7 @@ dev-lua/luacrypto
=dev-lua/luaexpat-1.3.0-r100
=dev-lua/luaexpat-1.3.3-r100
>=dev-lua/lua_cliargs-3.0_p2-r100
+>=dev-lua/lua-term-0.7-r100
>=dev-lua/luafilesystem-1.8.0-r100
>=dev-lua/luasec-0.9-r100
>=dev-lua/luasocket-3.0_rc1_p20200328-r100