gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-21 21:17:37 -08:00
Code Issues Projects Releases Wiki Activity

dev-python/blockbuster: Bump to 1.5.26

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny 2025-12-08 04:13:41 +01:00
parent 02540e7b9d
commit 79493a9d2b
No known key found for this signature in database
GPG Key ID: 8E32347AF4055AE8
2 changed files with 61 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/blockbuster/Manifest
View File

@ -1 +1,2 @@
DIST blockbuster-1.5.25.tar.gz 36058 BLAKE2B 75accc4bcba23664206adcd1a5adbfe5b4f4fdae634370e89b72a3122d3908dbba96ea2387766bced0814c47dac9b2b1c1b57647977b90bbd729561d6a2fb205 SHA512 a5201166425fa4449d319ed7265e9ab51c8bff05e1ec84c79d2b5cc54effc70f047154583b2362d6a6b6d0a986cd4f4082e96079a013778507fc5906bf6b7cff
DIST blockbuster-1.5.26.tar.gz 36085 BLAKE2B 856a57dae55251771cd3340b1b6cad84fa168d7ca63630401fbbd8acf27b99d77759e3161b77f94abf7085035ef9303bf7b693561fad4cf8796009a2297bee5d SHA512 d12263e81c2acc97a537b3067632a6fc41af214125bd4c4c16f12079531fe4d6addc48091942fa5311dec6024113492ee585a185127c0cf69abfde4e3c1a8ce0

60
dev-python/blockbuster/blockbuster-1.5.26.ebuild Normal file
View File

@ -0,0 +1,60 @@
# Copyright 2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
inherit distutils-r1 pypi
DESCRIPTION="Utility to detect blocking calls in the async event loop"
HOMEPAGE="
https://github.com/cbornet/blockbuster/
https://pypi.org/project/blockbuster/
"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
$(python_gen_cond_dep '
>=dev-python/forbiddenfruit-0.1.4[${PYTHON_USEDEP}]
' 'python*')
"
BDEPEND="
test? (
dev-python/aiofiles[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
)
"
EPYTEST_PLUGINS=( pytest-asyncio )
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=(
# Internet
tests/test_blockbuster.py::test_ssl_socket
)
case ${EPYTHON} in
pypy3.11)
EPYTEST_DESELECT+=(
# upstream doesn't care, however that doesn't stop
# people from depending on it...
# https://github.com/cbornet/blockbuster/issues/47
tests/test_blockbuster.py::test_file_random
tests/test_blockbuster.py::test_file_read_bytes
tests/test_blockbuster.py::test_file_text
tests/test_blockbuster.py::test_file_write_bytes
tests/test_blockbuster.py::test_lock
tests/test_blockbuster.py::test_os_scandir
tests/test_blockbuster.py::test_scanned_modules
)
;;
esac
epytest
}