diff --git a/dev-scheme/guile-ssh/guile-ssh-0.16.4-r100.ebuild b/dev-scheme/guile-ssh/guile-ssh-0.16.4-r100.ebuild
new file mode 100644
index 0000000000000..2de52a2e3291c
--- /dev/null
+++ b/dev-scheme/guile-ssh/guile-ssh-0.16.4-r100.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GUILE_COMPAT=( 2-2 3-0 )
+inherit autotools guile
+
+DESCRIPTION="Library providing access to the SSH protocol for GNU Guile"
+HOMEPAGE="https://memory-heap.org/~avp/projects/guile-ssh/
+	https://github.com/artyom-poptsov/guile-ssh/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/artyom-poptsov/${PN}.git"
+else
+	SRC_URI="https://github.com/artyom-poptsov/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+REQUIRED_USE="${GUILE_REQUIRED_USE}"
+
+RDEPEND="
+	${GUILE_DEPS}
+	dev-libs/boehm-gc
+	dev-libs/libatomic_ops
+	net-libs/libssh:0=[server,sftp]
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.16.2-tests.patch"
+)
+
+src_prepare() {
+	guile_src_prepare
+	eautoreconf
+}
+
+src_configure() {
+	my_configure() {
+		econf guile_snarf=${GUILESNARF}
+	}
+	guile_foreach_impl my_configure
+}
+
+src_install() {
+	guile_src_install
+
+	find "${ED}" -name "*.la" -delete || die
+}
diff --git a/profiles/package.mask b/profiles/package.mask
index 200ed91c0dfe6..5e583ba0630a8 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -380,6 +380,7 @@ dev-scheme/guile:3.0
 >=dev-scheme/guile-ncurses-3.1-r100
 >=dev-scheme/guile-nyacc-1.06.7-r100
 >=dev-scheme/guile-sqlite3-0.1.3-r100
+>=dev-scheme/guile-ssh-0.16.4-r100
 
 # Eli Schwartz <eschwartz@gentoo.org> (2024-08-15)
 # Abandoned upstream since 2011, unmaintained in gentoo since 2017. Tons of