dev-python/scikit-build: Bump to 0.18.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/scikit-build/Manifest

@@ -1 +1,2 @@
 DIST scikit_build-0.17.6.tar.gz 272208 BLAKE2B 9e3f908041eca89182f798c54a1a248934dc026816f7cd041a8debc97be27096942dda42a0ae63e87b9337304a478d6f520edcd5ea7a45aae6a195d1f769eed2 SHA512 92b97146f40d8222bd8415ef8439497d5075b72e5bafc40aba0a3e2911d269a118f2f7d41f468f7add8949f550b1fd7d5a9113d249e42dfac431108182ca9198
+DIST scikit_build-0.18.0.tar.gz 273824 BLAKE2B 2eac991ea22948e900c4485783f5bcbb8b87bd5858bbe7ade99b2a67c16a9a035e04c53b2d9b94422a5eff36f33c11cf297198bce520ba818b7355386977a8a1 SHA512 a374f86c69a288ddcfe8e8d95b594b2bf94365b4d6d4d25a7912cf871f12dfb1866b1d74694c919ef8e4fef3d166b7afe9de3b32b56add33173840a9bb917c71

dev-python/scikit-build/scikit-build-0.18.0.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Improved build system generator for Python C/C++/Fortran/Cython extensions"
+HOMEPAGE="
+	https://github.com/scikit-build/scikit-build/
+	https://pypi.org/project/scikit-build/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-42.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.10)
+	>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/build-0.7[${PYTHON_USEDEP}]
+		>=dev-python/cython-0.25.1[${PYTHON_USEDEP}]
+		dev-python/pip[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-1.10.4[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme \
+	dev-python/sphinx-issues
+# note: tests are unstable with xdist
+distutils_enable_tests pytest
+
+src_prepare() {
+	# not packaged
+	sed -i -e '/cmakedomain/d' docs/conf.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=()
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# no "library" in (our install of) pypy3
+				tests/test_cmaker.py::test_get_python_library
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_mock \
+		-m "not isolated and not nosetuptoolsscm" \
+		-o tmp_path_retention_count=1
+	rm -r "${BUILD_DIR}/install$(python_get_sitedir)"/{easy-install.pth,*.egg,*.egg-link} || die
+}