diff --git a/x11-misc/j4-dmenu-desktop/Manifest b/x11-misc/j4-dmenu-desktop/Manifest
index 06331467739f7..80b9c168215fb 100644
--- a/x11-misc/j4-dmenu-desktop/Manifest
+++ b/x11-misc/j4-dmenu-desktop/Manifest
@@ -1 +1,2 @@
 DIST j4-dmenu-desktop-3.1.tar.gz 108974 BLAKE2B fd0527ee27855ef453b76e52cd15402bb86b9812255edacfacd5b5486162b052eb74d41f072fcf151837698d352dfa743a6bd30cd28156f62ddafc39d2402edb SHA512 6baa4bdf0564683e09bf3dd34f619ec9dcfc840be68ec0f68b4cd643bee5acbc09ebfffaf82daced991899fb467c84ed441257915a9c6b411f317e9947471fca
+DIST j4-dmenu-desktop-3.2.tar.gz 125056 BLAKE2B 7fd26fd749961feb2a0de73b888e085fc4275743335923ab4c8674e79aa85bb2fca4787069fc2cf40ddc0f1748df0ec7f77164ff1cca80cc3c648fff016584c7 SHA512 d6bffa372a461feb1b09293bf51eb8dc081cf1d7aef21f059c51b296dc52804c3cefd9ab6d64d9025bbdee325cb7d24f78719a8f9504f55b868f10ca9715ae5a
diff --git a/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-3.2.ebuild b/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-3.2.ebuild
new file mode 100644
index 0000000000000..e56bc1b3ab29a
--- /dev/null
+++ b/x11-misc/j4-dmenu-desktop/j4-dmenu-desktop-3.2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_PV="r${PV}"
+
+DESCRIPTION="A fast desktop replacement for i3-dmenu-desktop"
+HOMEPAGE="https://github.com/enkore/j4-dmenu-desktop"
+SRC_URI="https://github.com/enkore/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+dmenu test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="test? ( dev-cpp/catch:0 )"
+DEPEND="
+	dev-libs/libfmt:=
+	dev-libs/spdlog:=
+"
+RDEPEND="
+	${DEPEND}
+	dmenu? ( x11-misc/dmenu )
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Respect users CFLAGS
+	sed -i -e "s/-pedantic -O2//" CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DNO_DOWNLOAD="ON"
+		-DWITH_GIT_CATCH="no"
+		-DWITH_TESTS="$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	doman j4-dmenu-desktop.1
+}
+
+pkg_postinst() {
+	if ! use dmenu; then
+		elog "As you have disabled the 'dmenu' use flag,"
+		elog "x11-misc/dmenu won't be installed by default."
+		elog ""
+		elog "Since x11-misc/j4-dmenu-desktop uses x11-misc/dmenu as default,"
+		elog "you must configure your own replacement with --dmenu=<command>,"
+		elog "as otherwise it won't work."
+	fi
+}