diff --git a/dev-python/pdm/Manifest b/dev-python/pdm/Manifest
index 128de70cbb3a7..a9450e56c7dd0 100644
--- a/dev-python/pdm/Manifest
+++ b/dev-python/pdm/Manifest
@@ -1 +1,2 @@
 DIST pdm-2.25.9.tar.gz 2664950 BLAKE2B e5ed047e0198b464ca4b201388cfe8d8afc0be577791e8730fac111c9cd457990f8dc834d19219b1c855124bbde69ff3d1eda94f2d39d02248fc49816951aa52 SHA512 401506dba65c33ac4790fffaf5c91b334b0b3e58fc5a769ad0599784121cbd16ff8e0dbf934aebc85cb8b81c1fc86e377f494ec6acb91a86e94725a08cd216b9
+DIST pdm-2.26.0.tar.gz 2671157 BLAKE2B b215960d0f8b3fe1f327fb3a8a048270da7879765d106cdbe46b3fc95e87424aa3c1e036401c30b6cd85f555d5c9a445f1a1fb1507fe0c82e817453b835baf7b SHA512 dcab85915a8bf9f33b55728bf989633d3c36c327c58891824c5d38be4b51bc2531f891072b0518e5296072b1f4746c4ca4b0e70f8c3ef306b0f93f66d128c6dd
diff --git a/dev-python/pdm/pdm-2.26.0.ebuild b/dev-python/pdm/pdm-2.26.0.ebuild
new file mode 100644
index 0000000000000..1d86f5a7e4da0
--- /dev/null
+++ b/dev-python/pdm/pdm-2.26.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
+HOMEPAGE="
+	https://pdm-project.org/
+	https://github.com/pdm-project/pdm/
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/dep-logic-0.5[${PYTHON_USEDEP}]
+	<dev-python/findpython-1[${PYTHON_USEDEP}]
+	>=dev-python/findpython-0.7.0[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	>=dev-python/hishel-0.0.32[${PYTHON_USEDEP}]
+	>=dev-python/httpcore-1.0.6[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	>=dev-python/id-1.5.0[${PYTHON_USEDEP}]
+	dev-python/installer[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22.1[${PYTHON_USEDEP}]
+	>=dev-python/pbs-installer-2025.10.07[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.2.0[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	>=dev-python/truststore-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/unearth-0.17.5[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/uv
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{httpserver,httpx,mock,rerunfailures} )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps
+	sed -i -e 's:,<[0-9.a]*::' pyproject.toml || die
+	# remove pkgutil namespace magic, as it doesn't work and makes
+	# dev-python/pdm-backend tests test the wrong package
+	rm src/pdm/__init__.py || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @ file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
+		# unhappy about extra packages being installed?
+		# (also fails randomly in venv)
+		tests/cli/test_build.py::test_build_with_no_isolation
+		# TODO: random regression?
+		tests/cli/test_python.py::test_find_python
+		# TODO
+		tests/test_formats.py::test_export_from_pylock_not_empty
+	)
+
+	epytest -m "not network and not integration and not path"
+}