From 74ebb561af2cdd7cde8742ceb185d4f6df6c4c40 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 15 Oct 2024 08:43:39 +0200
Subject: [PATCH] dev-python/flask-caching: New package, v2.3.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Required by dev-python/flask-compress now.

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/flask-caching/Manifest             |  1 +
 .../flask-caching/flask-caching-2.3.0.ebuild  | 45 +++++++++++++++++++
 dev-python/flask-caching/metadata.xml         | 12 +++++
 3 files changed, 58 insertions(+)
 create mode 100644 dev-python/flask-caching/Manifest
 create mode 100644 dev-python/flask-caching/flask-caching-2.3.0.ebuild
 create mode 100644 dev-python/flask-caching/metadata.xml

diff --git a/dev-python/flask-caching/Manifest b/dev-python/flask-caching/Manifest
new file mode 100644
index 0000000000000..ead2150b13644
--- /dev/null
+++ b/dev-python/flask-caching/Manifest
@@ -0,0 +1 @@
+DIST flask_caching-2.3.0.tar.gz 67668 BLAKE2B 13517a0741959ca72072e2baf71f3d87b61a678052f0c3ba657d247fb82ab8457f45d453e9730fdfcac1cb665822d78a9c69aef83c0c62d2b808021f42f9881b SHA512 40ed857cf0822267af7e2c138b3136ff6312b3b2ea627a97738792ea4f7649db20f2df31a7414c42cc245a66d34248b3a54681824cf23d800bdb0d453c02df49
diff --git a/dev-python/flask-caching/flask-caching-2.3.0.ebuild b/dev-python/flask-caching/flask-caching-2.3.0.ebuild
new file mode 100644
index 0000000000000..a0f72b0813ff0
--- /dev/null
+++ b/dev-python/flask-caching/flask-caching-2.3.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=Flask-Caching
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Adds caching support to Flask applications"
+HOMEPAGE="
+	https://github.com/pallets-eco/flask-caching/
+	https://pypi.org/project/Flask-Caching/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/cachelib-0.9.0[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/asgiref[${PYTHON_USEDEP}]
+		dev-python/pylibmc[sasl(-),${PYTHON_USEDEP}]
+		dev-python/redis[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-xprocess[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# fix check for obsolete package name
+	sed -i -e '/pytest_xprocess/d' tests/conftest.py || die
+	# remove pinned deps
+	sed -i -e '/install_requires/d' setup.py || die
+}
diff --git a/dev-python/flask-caching/metadata.xml b/dev-python/flask-caching/metadata.xml
new file mode 100644
index 0000000000000..cf90d31dfacdd
--- /dev/null
+++ b/dev-python/flask-caching/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">pallets-eco/flask-caching</remote-id>
+		<remote-id type="pypi">Flask-Caching</remote-id>
+	</upstream>
+</pkgmetadata>