From 74084de2dc5d4e9dbd0bb08b4dd26b3727422d47 Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Tue, 22 Sep 2026 09:57:44 -0400
Subject: [PATCH] dev-util/mesa_clc: Version bump to 26.2.3

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 dev-util/mesa_clc/Manifest               |   1 +
 dev-util/mesa_clc/mesa_clc-26.2.3.ebuild | 124 +++++++++++++++++++++++
 2 files changed, 125 insertions(+)
 create mode 100644 dev-util/mesa_clc/mesa_clc-26.2.3.ebuild

diff --git a/dev-util/mesa_clc/Manifest b/dev-util/mesa_clc/Manifest
index 137460ba91455..14ef008ebf74a 100644
--- a/dev-util/mesa_clc/Manifest
+++ b/dev-util/mesa_clc/Manifest
@@ -1,2 +1,3 @@
 DIST mesa-26.1.8.tar.xz 77827888 BLAKE2B 173997a90bbb27d8f6b1e4c349430d063a9264efddf03c9449f93b9e0438fa38948dfbfecddb798cd57818070953b8c525cb3796807101632b1b642c4d6b0361 SHA512 eb3d46ae9aaba70fdd908486cef24041fec9264ddf586eaebbba65ce55e716d306ef9e91be83e742dfaec4dfc94105a5cd3a36b29bf56614febcbcf6c1f8b516
 DIST mesa-26.2.2.tar.xz 68533264 BLAKE2B a9924a7cbac5dbdb4d93ba8499c49a6be51edd8ec5b258f2986a5690b04f6898012389dcc7e07097bad0defed52e9255d3a2c82bb6101a531b17fde82ef69afc SHA512 55b1234c8653dad9b85ba3de7b777a0d957909baf4628f0c00e21d4ba89c004cb687a1dcf8da46ed0a092231dd4f859027509f83ad8c558750845ba470902615
+DIST mesa-26.2.3.tar.xz 68561540 BLAKE2B 53e451060bdc0df6ea8f7b5d3a23563c4bf56613c0871a91c5f0570649fcfe35e0dc1c0fc7834642621fc0772d0614b6a60acf196e82d4b77132629307c4a82e SHA512 ec621735ae4679762ea27b979a5314c7aecfdd4165afea19c8c55f933d79b40f01fa041a95874fc4347e732ac565786d9b616a9aa8856a422204d9ecc9a12ec4
diff --git a/dev-util/mesa_clc/mesa_clc-26.2.3.ebuild b/dev-util/mesa_clc/mesa_clc-26.2.3.ebuild
new file mode 100644
index 0000000000000..ad1dae69348ce
--- /dev/null
+++ b/dev-util/mesa_clc/mesa_clc-26.2.3.ebuild
@@ -0,0 +1,124 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( {18..22} )
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit llvm-r2 meson python-any-r1
+
+MY_PV="${PV/_/-}"
+
+DESCRIPTION="mesa_clc tool used for building OpenCL C to SPIR-V"
+HOMEPAGE="https://mesa3d.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	S="${WORKDIR}/mesa_clc-${MY_PV}"
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git"
+	inherit git-r3
+else
+	S="${WORKDIR}/mesa-${MY_PV}"
+	SRC_URI="https://archive.mesa3d.org/mesa-${MY_PV}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+VIDEO_CARDS="asahi panfrost"
+for card in ${VIDEO_CARDS}; do
+	IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+IUSE="${IUSE_VIDEO_CARDS} debug"
+
+RDEPEND="
+	dev-util/spirv-tools
+	$(llvm_gen_dep '
+		dev-util/spirv-llvm-translator:${LLVM_SLOT}
+		llvm-core/clang:${LLVM_SLOT}=
+		llvm-core/llvm:${LLVM_SLOT}=
+		=llvm-runtimes/libclc-${LLVM_SLOT}*
+	')
+"
+DEPEND="${RDEPEND}
+	dev-libs/expat
+	>=virtual/zlib-1.2.8:=
+	x11-libs/libdrm
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_any_dep "
+		>=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]
+		dev-python/packaging[\${PYTHON_USEDEP}]
+		dev-python/pyyaml[\${PYTHON_USEDEP}]
+	")
+	virtual/pkgconfig
+"
+
+python_check_deps() {
+	python_has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]" &&
+	python_has_version -b "dev-python/packaging[${PYTHON_USEDEP}]" &&
+	python_has_version -b "dev-python/pyyaml[${PYTHON_USEDEP}]" || return 1
+}
+
+pkg_setup() {
+	llvm-r2_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	tools_enable video_cards_asahi asahi
+	tools_enable video_cards_panfrost panfrost
+
+	tools_list() {
+		local tools="$(sort -u <<< "${1// /$'\n'}")"
+		echo "${tools//$'\n'/,}"
+	}
+
+	PKG_CONFIG_PATH="$(get_llvm_prefix)/$(get_libdir)/pkgconfig"
+
+	use debug && EMESON_BUILDTYPE=debug
+
+	local emesonargs=(
+		-Dallow-broken-lto=true
+		-Dllvm=enabled
+		-Dshared-llvm=enabled
+		-Dmesa-clc=enabled
+		-Dinstall-mesa-clc=true
+		-Dprecomp-compiler=enabled
+		-Dinstall-precomp-compiler=true
+		-Dtools=$(tools_list "${TOOLS[*]}")
+
+		-Dgallium-drivers=''
+		-Dvulkan-drivers=''
+
+		# Set platforms empty to avoid the default "auto" setting. If
+		# platforms is empty meson.build will add surfaceless.
+		-Dplatforms=''
+
+		-Dglx=disabled
+		-Dlibunwind=disabled
+		-Dzstd=disabled
+
+		-Db_ndebug=$(usex debug false true)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}"/src/compiler/clc/mesa_clc
+	dobin "${BUILD_DIR}"/src/compiler/spirv/vtn_bindgen2
+	use video_cards_asahi && dobin "${BUILD_DIR}"/src/asahi/clc/asahi_clc
+	use video_cards_panfrost && dobin "${BUILD_DIR}"/src/panfrost/clc/panfrost_compile
+}
+
+# $1 - VIDEO_CARDS flag (check skipped for "--")
+# other args - names of tools to enable
+tools_enable() {
+	if [[ $1 == -- ]] || use $1; then
+		shift
+		TOOLS+=("$@")
+	fi
+}