dev-java/openjdk-jre-bin: add 8.502_p07

Bug: https://bugs.gentoo.org/979647
Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/1585
Merges: https://codeberg.org/gentoo/gentoo/pulls/1585
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-java/openjdk-jre-bin/Manifest

@@ -7,3 +7,4 @@ DIST OpenJDK21U-jre_x64_linux_hotspot_21.0.12_8.tar.gz 52069757 BLAKE2B 07f3fbfb
 DIST OpenJDK25U-jre_x64_linux_hotspot_25.0.3_9.tar.gz 61687836 BLAKE2B ef3616cb4b1febc4f319be9144228f524a4d52074dfef431ec5f631b9c652a7e60cca731681ab615bf42a01daee37f28987283418a7a56acda3f72b02d447c96 SHA512 ea28bce0f082f7943236fc4b9e5bd8c6fd3c0c4b4204d8a8c782680565bbeb348db33cc50a93d4e744b8cc2c0e49016e90776ae735b16b1a1bbbf1571ae5e67c
 DIST OpenJDK25U-jre_x64_linux_hotspot_25.0.4_7.tar.gz 61714730 BLAKE2B fdda4e24bd5ab623699876df6d2a80e3a831488be80c87390f6fa673ab96ae14419f1c96b2acc837c2429bd187ab06f5f0b5c071be0f82641b106c5da3b60bed SHA512 934a482e2979558cffba08629933543123165c19f72d60e3f1f842bafa0340b508ab85169c9902078e3311228998c5e42e914ea1e9fe307b449c7d159e5477ef
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u492b09.tar.gz 41870107 BLAKE2B c58bd972bce6c952fea83b96da352d73bcc5221e61eee02739624a8d850efa0ae73376f2052d796e72694d7f7c960faa9422cf7a57bc301bb7c60a3ccb0cd35f SHA512 0cef2f30b2974924b1001a69e5fd07278f735e932f686f0f2b63cd8eda39ca44454bf0f532b7b0120aedc1d0b6a9e10287cbddd691c4ddb67a3aea6214db98fe
+DIST OpenJDK8U-jre_x64_linux_hotspot_8u502b07.tar.gz 41851657 BLAKE2B 89250fc27c98ac92d7f22f7844f451789cf1e84069e39237857a323bd4c735319d685d7d09e599dc097f495d6b291784f9ca2b8acf79a7135b5b27ce87c6828a SHA512 856e8295ae22d5410d797bf2c82ec56335203d17a30968fa7c46fd5962b6cdb018df0fe31f250fb42033c074d0ad67a140eb3052309d8bd07be736e649c1e921

dev-java/openjdk-jre-bin/openjdk-jre-bin-8.502_p07.ebuild

@@ -0,0 +1,85 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-vm-2
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/adoptium/temurin${SLOT}-binaries/releases/download/jdk${MY_PV}/OpenJDK8U-jre_${1}_linux_hotspot_${MY_PV/-/}.tar.gz
+		)"
+}
+
+MY_PV=$(ver_rs 1 'u' 2 '-' ${PV//p/b})
+SLOT="$(ver_cut 1)"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by Eclipse Temurin"
+HOMEPAGE="https://adoptium.net/"
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+
+IUSE="alsa cups headless-awt selinux"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>net-libs/libnet-1.1
+	>=sys-apps/baselayout-java-0.1.0-r1
+	>=sys-libs/glibc-2.2.5:*
+	virtual/zlib:=
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk${MY_PV}-jre"
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED}/${dest#/}"
+
+	# https://bugs.gentoo.org/922741
+	docompress "${dest}/man"
+
+	rm ASSEMBLY_EXCEPTION LICENSE THIRD_PARTY_README || die
+
+	# this does not exist on arm64 hence -f
+	rm -fv lib/*/libfreetype.so* || die
+
+	if ! use alsa ; then
+		rm -v lib/*/libjsoundalsa.so* || die
+	fi
+
+	if use headless-awt ; then
+		rm -fvr lib/*/lib*{[jx]awt,splashscreen}* \
+			bin/policytool || die
+	fi
+
+	rm -v lib/security/cacerts || die
+	dosym -r /etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	# provide stable symlink
+	dosym "${P}" "/opt/${PN}-${SLOT}"
+
+	java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}