dev-libs/wayland: bump to 1.13.0

Gentoo-bug: 611062

dev-libs/wayland/Manifest

@@ -1 +1,2 @@
 DIST wayland-1.12.0.tar.xz 379520 SHA256 d6b4135cba0188abcb7275513c72dede751d6194f6edc5b82183a3ba8b821ab1 SHA512 cde05344e6c9ee40c80651f5b6d6b4a14787a9cf2c8e3099d69b8f78672610e3ccbe4a87446f9ae93ca402cfbb916ef7444294efa7a0fc88ef1a984f94dabd20 WHIRLPOOL 8dc03639759908921c7d5d5df4dc02c6f7e96d9c9a7e8728bd64310a10c54fe50c4042ced3db4954ff4512f073c1bd8993df207b45182d862f6ffeeb0b1283e4
+DIST wayland-1.13.0.tar.xz 414508 SHA256 69b052c031a61e89af7cc8780893d0da1e301492352aa449dee9345043e6fe51 SHA512 163bae2c2c2e79e03dda9a57b1e3a1060eff9e0b053b70ad00a6949a1d40f4c40d0244340c2603109fcbfe919533c2ce196338b27587fd3bda996e615d51e543 WHIRLPOOL a581769134155f1063e464083b93c2159417f8f481d4e86dc4ca88dd792ff01edfbc3fef4ed5bf74212554a622d81eeec091547628b9a488038073f4927ac5b9

dev-libs/wayland/wayland-1.13.0.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/git/wayland/${PN}"
+
+if [[ ${PV} = 9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+inherit autotools libtool ltprune multilib-minimal toolchain-funcs $GIT_ECLASS
+
+DESCRIPTION="Wayland protocol libraries"
+HOMEPAGE="https://wayland.freedesktop.org/"
+
+if [[ $PV = 9999* ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://wayland.freedesktop.org/releases/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc static-libs"
+
+RDEPEND=">=dev-libs/expat-2.1.0-r3:=[${MULTILIB_USEDEP}]
+	>=virtual/libffi-3.0.13-r1:=[${MULTILIB_USEDEP}]
+	dev-libs/libxml2:="
+DEPEND="${RDEPEND}
+	doc? (
+		>=app-doc/doxygen-1.6[dot]
+		app-text/xmlto
+		>=media-gfx/graphviz-2.26.0
+		sys-apps/grep[pcre]
+	)
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+	[[ $PV = 9999* ]] && eautoreconf || elibtoolize
+}
+
+multilib_src_configure() {
+	local myconf
+	if tc-is-cross-compiler ; then
+		myconf+=' --with-host-scanner '
+	fi
+
+	ECONF_SOURCE="${S}" econf \
+		--disable-static \
+		$(multilib_native_use_enable doc documentation) \
+		$(multilib_native_enable dtd-validation) \
+		${myconf}
+}
+
+multilib_src_install_all() {
+	prune_libtool_files
+	einstalldocs
+}
+
+src_test() {
+	# We set it on purpose to only a short subdir name, as socket paths are
+	# created in there, which are 108 byte limited. With this it hopefully
+	# barely fits to the limit with /var/tmp/portage/$CAT/$PF/temp/xdr
+	export XDG_RUNTIME_DIR="${T}"/xdr
+	mkdir "${XDG_RUNTIME_DIR}" || die
+	chmod 0700 "${XDG_RUNTIME_DIR}" || die
+
+	multilib-minimal_src_test
+}