dev-util/bloaty: add compat with >=dev-libs/capstone-6.0

Also remove system absl patch from -9999 as it will automatically
use system libs.

Closes: https://bugs.gentoo.org/964344
Signed-off-by: Holger Hoffstätte <holger@applied-asynchrony.com>
Part-of: https://github.com/gentoo/gentoo/pull/44188
Closes: https://github.com/gentoo/gentoo/pull/44188
Signed-off-by: Sam James <sam@gentoo.org>

dev-util/bloaty/bloaty-1.1-r2.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="A size profiler for binaries"
+HOMEPAGE="https://github.com/google/bloaty"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/google/${PN}"
+	IUSE="test"
+	RESTRICT="!test? ( test )"
+else
+	SRC_URI="https://github.com/google/${PN}/releases/download/v${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm64 ~loong"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-cpp/abseil-cpp:=
+	dev-libs/capstone:=
+	dev-libs/protobuf:=
+	dev-libs/re2:=
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.1-system-abseil.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DBLOATY_ENABLE_CMAKETARGETS=OFF
+		-DBUILD_SHARED_LIBS=OFF
+	)
+
+	if [[ ${PV} == 9999 ]]; then
+		mycmakeargs+=(
+			-DBUILD_TESTING=$(usex test)
+			$(usex test -DINSTALL_GTEST=OFF "")
+		)
+	fi
+
+	# capstone-6 compatibility (#964344)
+	append-flags -DCAPSTONE_AARCH64_COMPAT_HEADER
+
+	cmake_src_configure
+}

dev-util/bloaty/bloaty-9999.ebuild

@@ -3,7 +3,7 @@
 
 EAPI=8
 
-inherit cmake
+inherit cmake flag-o-matic
 
 DESCRIPTION="A size profiler for binaries"
 HOMEPAGE="https://github.com/google/bloaty"
@@ -32,10 +32,6 @@ DEPEND="
 "
 RDEPEND="${DEPEND}"
 
-PATCHES=(
-	"${FILESDIR}"/${PN}-1.1-system-abseil.patch
-)
-
 src_configure() {
 	local mycmakeargs=(
 		-DBLOATY_ENABLE_CMAKETARGETS=OFF
@@ -49,5 +45,8 @@ src_configure() {
 		)
 	fi
 
+	# capstone-6 compatibility (#964344)
+	append-flags -DCAPSTONE_AARCH64_COMPAT_HEADER
+
 	cmake_src_configure
 }