From 7191b605492740217ea3639d3a87d50c644871a5 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sun, 26 Oct 2025 17:09:18 +0100
Subject: [PATCH] dev-python/iminuit: Bump to 2.31.3
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/iminuit/Manifest              |  2 +
 dev-python/iminuit/iminuit-2.31.3.ebuild | 62 ++++++++++++++++++++++++
 2 files changed, 64 insertions(+)
 create mode 100644 dev-python/iminuit/iminuit-2.31.3.ebuild

diff --git a/dev-python/iminuit/Manifest b/dev-python/iminuit/Manifest
index 01206f91ae24..3229200dc2d5 100644
--- a/dev-python/iminuit/Manifest
+++ b/dev-python/iminuit/Manifest
@@ -1 +1,3 @@
 DIST iminuit-2.31.1.tar.gz 1840604 BLAKE2B c363b87dd58433528a9b8d87ef3d7f67b2d1442810aa60d60704b000c432f100ba4ada33786a936f7cb80cb49b4cebb00e7db19f415bc339286691e5e1e3a1ec SHA512 c4e54ddbc7b39e0b151eb3ea8d20d215fb56cb2dd08c907e5242968ee6f45fe0495274adea70d90a22718c402def1dea50275fc0ec62f8cc82781f97d9264f38
+DIST iminuit-2.31.3.tar.gz 1841427 BLAKE2B 8b2005967478cf575c8a7f6a59c888d40e1389da466e90e3b414eff82c5f62423b996b62272f895f116377d69b71d00d4e4d89178b9c254556ef7e5929512644 SHA512 2918077f691dcbb9fb9bb510fbcebb98402b5508f73693a6b767471cdf3ee98fd5e097f79b76a53adf0e4e853c8fe066efa22ac3a705e41cf0f2b7270595fed2
+DIST iminuit-2.31.3.tar.gz.provenance 9490 BLAKE2B d84d56b359dd20d0671283331bf04977320efa025c859c914f43f4f0057841e814d3b684d13a7960a17278855f1eb00a2e1cad386f4781f54882be2c2921b892 SHA512 f14a4f0afb00f5b927ff1d6d58868bb04ef93b27df5fe5ac11a30ab1d9b992b61913541bb20b6e35c542358a537cca8e6c9138144bfcdfff33473df052687093
diff --git a/dev-python/iminuit/iminuit-2.31.3.ebuild b/dev-python/iminuit/iminuit-2.31.3.ebuild
new file mode 100644
index 000000000000..f2746d9470a8
--- /dev/null
+++ b/dev-python/iminuit/iminuit-2.31.3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=scikit-build-core
+PYPI_VERIFY_REPO=https://github.com/scikit-hep/iminuit
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit cmake distutils-r1 virtualx pypi
+
+DESCRIPTION="Minuit numerical function minimization in Python"
+HOMEPAGE="
+	https://github.com/scikit-hep/iminuit/
+	https://pypi.org/project/iminuit/
+"
+
+LICENSE="MIT LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+DEPEND="
+	>=dev-python/pybind11-3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${DEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/annotated-types[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# precision error
+	tests/test_cost.py::test_Template_with_model_2D
+
+	# TODO
+	tests/test_describe.py::test_with_pydantic_types
+)
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# do not force LTO
+	sed -i -e '/INTERPROCEDURAL_OPTIMIZATION/d' CMakeLists.txt || die
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}