mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-21 21:17:37 -08:00
kde-plasma/plasma-workspace: drop 6.5.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
parent
fe89fe676a
commit
70c4cb2c3c
@ -1,4 +1,3 @@
|
||||
DIST plasma-workspace-6.4.5-patchset.tar.xz 6984 BLAKE2B 3433d586cad29b4bd956ac30e2fed5e8f659edd518af1a4fdd9801f886d74f64e40c7aa8413775514b22e63e1f0d5c21f29254fba6b509e526be1ebe25288c54 SHA512 b7c1a0a161ed1b169319a77c7ec663b1864919e9fc6fe57c9bfad32af6945d579f27ae2cdc0840f0e325e1c907c4e2d3a289c7f016c9c33d66d479df9f53b999
|
||||
DIST plasma-workspace-6.4.5.tar.xz 20834364 BLAKE2B f99248273faa60f0e4b42bf3aa81d7e10c8f932a919581fa3cb9bb83d1e8fc1ad344c9c8b6ac11f9c0958c373f27582d31453d78c6f6e4170bcbdd172b5a77fd SHA512 5d267605783b28e7ab46c02f78c7584a516c311ad16203db56bd77fb752d767462d8a78d65955082086af8ae0dcbd35a5678c0cd94d55e2d67a08d57ac187534
|
||||
DIST plasma-workspace-6.5.3.tar.xz 20268060 BLAKE2B 802416239af44b35a287559584b0bdc698f6783db9dfeca06714b0e1c4ff65326c065ab5cca00965513fa8eb82ea78d23a68deab12d526c10000d5b9b8a09cd7 SHA512 7b504d23756b5ad8bfe5cab09a040aca2790312bd01397cf5cd9f2fffc563c9810cdbbb51467d57953f8b770b7988464ff7e1fd9b10f819050a9144bb72cebf1
|
||||
DIST plasma-workspace-6.5.4.tar.xz 20270036 BLAKE2B 553accab907049863484335fa94efb5ab60fe408f64a50c343f62e2c76da44add0789a17a3f21b36fbf55e4d4923e0cb8321948f33e076e22bf43956e0cfaadb SHA512 080402878a4163e349e6709e627bf5b0a3798e97dbd55b967c1bc68d4e677986987748e54b5bbf4b76590abde6440ec13a6d9cfcfda8ff6dc7027e3778a5a031
|
||||
|
||||
@ -1,228 +0,0 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
ECM_HANDBOOK="optional"
|
||||
ECM_TEST="forceoptional"
|
||||
KFMIN=6.18.0
|
||||
QTMIN=6.9.1
|
||||
inherit ecm plasma.kde.org xdg
|
||||
|
||||
DESCRIPTION="KDE Plasma workspace"
|
||||
|
||||
LICENSE="GPL-2" # TODO: CHECK
|
||||
SLOT="6"
|
||||
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
|
||||
IUSE="appstream +fontconfig +ksysguard networkmanager phonon +policykit
|
||||
screencast +semantic-desktop systemd telemetry +wallpaper-metadata +X"
|
||||
|
||||
REQUIRED_USE="fontconfig? ( X )"
|
||||
RESTRICT="test"
|
||||
|
||||
# kde-frameworks/kwindowsystem[X]: Uses KX11Extras
|
||||
# slot op: Uses Qt::GuiPrivate for qtx11extras_p.h
|
||||
# slot op: various private QtWaylandClient headers
|
||||
COMMON_DEPEND="
|
||||
dev-libs/icu:=
|
||||
>=dev-libs/wayland-1.15
|
||||
>=dev-qt/qt5compat-${QTMIN}:6[qml]
|
||||
>=dev-qt/qtbase-${QTMIN}:6=[dbus,gui,libinput,network,opengl,sql,sqlite,wayland,widgets,xml]
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
|
||||
>=dev-qt/qtlocation-${QTMIN}:6
|
||||
>=dev-qt/qtpositioning-${QTMIN}:6
|
||||
>=dev-qt/qtshadertools-${QTMIN}:6
|
||||
>=dev-qt/qtsvg-${QTMIN}:6
|
||||
>=kde-frameworks/karchive-${KFMIN}:6
|
||||
>=kde-frameworks/kauth-${KFMIN}:6
|
||||
>=kde-frameworks/kbookmarks-${KFMIN}:6
|
||||
>=kde-frameworks/kcmutils-${KFMIN}:6
|
||||
>=kde-frameworks/kcolorscheme-${KFMIN}:6
|
||||
>=kde-frameworks/kcompletion-${KFMIN}:6
|
||||
>=kde-frameworks/kconfig-${KFMIN}:6
|
||||
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kcrash-${KFMIN}:6
|
||||
>=kde-frameworks/kdbusaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kdeclarative-${KFMIN}:6
|
||||
>=kde-frameworks/kded-${KFMIN}:6
|
||||
>=kde-frameworks/kglobalaccel-${KFMIN}:6
|
||||
>=kde-frameworks/kguiaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kholidays-${KFMIN}:6
|
||||
>=kde-frameworks/ki18n-${KFMIN}:6
|
||||
>=kde-frameworks/kiconthemes-${KFMIN}:6
|
||||
>=kde-frameworks/kidletime-${KFMIN}:6
|
||||
>=kde-frameworks/kio-${KFMIN}:6
|
||||
>=kde-frameworks/kitemmodels-${KFMIN}:6
|
||||
>=kde-frameworks/kitemviews-${KFMIN}:6
|
||||
>=kde-frameworks/kjobwidgets-${KFMIN}:6
|
||||
>=kde-frameworks/knewstuff-${KFMIN}:6
|
||||
>=kde-frameworks/knotifications-${KFMIN}:6
|
||||
>=kde-frameworks/knotifyconfig-${KFMIN}:6
|
||||
>=kde-frameworks/kpackage-${KFMIN}:6
|
||||
>=kde-frameworks/kparts-${KFMIN}:6
|
||||
>=kde-frameworks/krunner-${KFMIN}:6
|
||||
>=kde-frameworks/kservice-${KFMIN}:6
|
||||
>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
|
||||
>=kde-frameworks/ksvg-${KFMIN}:6
|
||||
>=kde-frameworks/ktexteditor-${KFMIN}:6
|
||||
>=kde-frameworks/ktextwidgets-${KFMIN}:6
|
||||
>=kde-frameworks/kwallet-${KFMIN}:6
|
||||
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
|
||||
>=kde-frameworks/kwindowsystem-${KFMIN}:6[X?]
|
||||
>=kde-frameworks/kxmlgui-${KFMIN}:6
|
||||
>=kde-frameworks/prison-${KFMIN}:6[qml]
|
||||
>=kde-frameworks/solid-${KFMIN}:6
|
||||
>=kde-plasma/breeze-${KDE_CATV}:6
|
||||
>=kde-plasma/knighttime-${KDE_CATV}:6
|
||||
>=kde-plasma/kwayland-${KDE_CATV}:6
|
||||
>=kde-plasma/kwin-${KDE_CATV}:6
|
||||
>=kde-plasma/layer-shell-qt-${KDE_CATV}:6
|
||||
>=kde-plasma/libkscreen-${KDE_CATV}:6
|
||||
>=kde-plasma/libplasma-${KDE_CATV}:6
|
||||
>=kde-plasma/plasma-activities-${KDE_CATV}:6=
|
||||
>=kde-plasma/plasma-activities-stats-${KDE_CATV}:6
|
||||
>=kde-plasma/plasma5support-${KDE_CATV}:6
|
||||
media-libs/libcanberra
|
||||
sci-libs/libqalculate:=
|
||||
sys-apps/dbus
|
||||
virtual/zlib:=
|
||||
virtual/libudev:=
|
||||
appstream? ( >=dev-libs/appstream-1[qt6] )
|
||||
ksysguard? ( >=kde-plasma/libksysguard-${KDE_CATV}:6 )
|
||||
phonon? ( >=media-libs/phonon-4.12.0[qt6(+)] )
|
||||
policykit? ( virtual/libcrypt:= )
|
||||
networkmanager? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:6 )
|
||||
semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:6 )
|
||||
systemd? ( sys-apps/systemd:= )
|
||||
telemetry? ( >=kde-frameworks/kuserfeedback-${KFMIN}:6 )
|
||||
wallpaper-metadata? ( kde-apps/libkexiv2:6 )
|
||||
X? (
|
||||
>=dev-qt/qtbase-${QTMIN}:6=[X]
|
||||
>=kde-plasma/kscreenlocker-${KDE_CATV}:6
|
||||
x11-libs/libICE
|
||||
x11-libs/libSM
|
||||
x11-libs/libX11
|
||||
x11-libs/libXau
|
||||
x11-libs/libxcb
|
||||
x11-libs/libXcursor
|
||||
x11-libs/libXfixes
|
||||
x11-libs/libXtst
|
||||
x11-libs/xcb-util
|
||||
fontconfig? (
|
||||
media-libs/fontconfig
|
||||
x11-libs/libXft
|
||||
x11-libs/xcb-util-image
|
||||
)
|
||||
)
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
>=dev-libs/plasma-wayland-protocols-1.19.0
|
||||
dev-libs/qcoro
|
||||
>=dev-qt/qtbase-${QTMIN}:6[concurrent]
|
||||
test? ( screencast? ( >=media-video/pipewire-0.3:* ) )
|
||||
X? (
|
||||
fontconfig? ( x11-libs/libXrender )
|
||||
x11-base/xorg-proto
|
||||
)
|
||||
"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
!kde-plasma/libkworkspace:5
|
||||
!<kde-plasma/plasma-desktop-6.3.80
|
||||
!<kde-plasma/xdg-desktop-portal-kde-6.1.90
|
||||
!kde-plasma/xembed-sni-proxy:*
|
||||
app-text/iso-codes
|
||||
dev-libs/kirigami-addons:6
|
||||
>=dev-qt/qttools-${QTMIN}:*[qdbus]
|
||||
kde-apps/kio-extras:6
|
||||
>=kde-frameworks/kirigami-${KFMIN}:6
|
||||
>=kde-frameworks/kquickcharts-${KFMIN}:6
|
||||
>=kde-plasma/kactivitymanagerd-${KDE_CATV}:6
|
||||
>=kde-plasma/kdesu-gui-${KDE_CATV}:*
|
||||
>=kde-plasma/milou-${KDE_CATV}:6
|
||||
>=kde-plasma/plasma-integration-${KDE_CATV}:6
|
||||
>=kde-plasma/plasma-login-sessions-${KDE_CATV}:6
|
||||
sys-apps/dbus
|
||||
x11-apps/xmessage
|
||||
x11-apps/xprop
|
||||
x11-apps/xrdb
|
||||
policykit? ( sys-apps/accountsservice )
|
||||
screencast? ( >=media-video/pipewire-0.3:* )
|
||||
"
|
||||
RDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
|
||||
BDEPEND="
|
||||
>=dev-qt/qtbase-${QTMIN}:6[wayland]
|
||||
>=dev-util/wayland-scanner-1.19.0
|
||||
>=kde-frameworks/kcmutils-${KFMIN}:6
|
||||
virtual/pkgconfig
|
||||
test? ( >=dev-qt/qtwayland-${QTMIN}:6[compositor(+)] )
|
||||
"
|
||||
BDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-5.22.5-krunner-cwd-at-home.patch" # TODO upstream: KDE-bug 432975, bug 767478
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
ecm_src_prepare
|
||||
|
||||
cmake_comment_add_subdirectory login-sessions
|
||||
|
||||
if ! use phonon; then
|
||||
sed -e "s/^find_package.*Phonon4Qt6/#&/" -i CMakeLists.txt || die
|
||||
cmake_comment_add_subdirectory phonon
|
||||
fi
|
||||
|
||||
if ! use policykit; then
|
||||
cmake_comment_add_subdirectory -f kcms users
|
||||
fi
|
||||
|
||||
if ! use fontconfig; then
|
||||
ecm_punt_bogus_dep XCB IMAGE
|
||||
sed -e "s/check_X11_lib(Xft)/#&/" -i CMakeLists.txt || die
|
||||
fi
|
||||
|
||||
# TODO: try to get a build switch upstreamed
|
||||
if ! use systemd; then
|
||||
sed -e "s/^pkg_check_modules.*SYSTEMD/#&/" -i CMakeLists.txt || die
|
||||
fi
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DWITH_X11=$(usex X) # remember to submit patches with bugs
|
||||
-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt6=ON # not packaged
|
||||
-DGLIBC_LOCALE_GEN=OFF
|
||||
-DGLIBC_LOCALE_PREGENERATED=$(usex elibc_glibc)
|
||||
$(cmake_use_find_package appstream AppStreamQt)
|
||||
$(cmake_use_find_package fontconfig Fontconfig)
|
||||
$(cmake_use_find_package ksysguard KSysGuard)
|
||||
$(cmake_use_find_package networkmanager KF6NetworkManagerQt)
|
||||
-DBUILD_CAMERAINDICATOR=$(usex screencast)
|
||||
$(cmake_use_find_package semantic-desktop KF6Baloo)
|
||||
$(cmake_use_find_package telemetry KF6UserFeedback)
|
||||
$(cmake_use_find_package wallpaper-metadata KExiv2Qt6)
|
||||
)
|
||||
|
||||
ecm_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
ecm_src_install
|
||||
|
||||
# default startup and shutdown scripts
|
||||
insinto /etc/xdg/plasma-workspace/env
|
||||
doins "${FILESDIR}"/10-agent-startup.sh
|
||||
|
||||
insinto /etc/xdg/plasma-workspace/shutdown
|
||||
doins "${FILESDIR}"/10-agent-shutdown.sh
|
||||
fperms +x /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh
|
||||
}
|
||||
|
||||
pkg_postinst () {
|
||||
xdg_pkg_postinst
|
||||
|
||||
elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
|
||||
elog "edit ${EPREFIX}/etc/xdg/plasma-workspace/env/10-agent-startup.sh"
|
||||
elog "and ${EPREFIX}/etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user