dev-python/flask: version bump to 0.11

Package-Manager: portage-2.3.0_rc1

dev-python/flask/Manifest

@@ -1 +1,2 @@
 DIST Flask-0.10.1.tar.gz 544247 SHA256 4c83829ff83d408b5e1d4995472265411d2c414112298f2eb4b359d9e4563373 SHA512 0008d62d03a46b071c7d0510513d011a9bfd2b77df7f677371a446ca9805d16b1ee5e17dd8dd7cde6443a629370234e44735e20381de20a7da385969797f053f WHIRLPOOL f30a306ed00fe6d4c8e47b781c556c576b99b3545f833ae06f6b778d91c3127dc0adcc34d48221a0f1db1bb1633f2329d6085b7a4550afc672530525fdff474f
+DIST Flask-0.11.tar.gz 563928 SHA256 29a7405a7f0de178232fe48cd9b2a2403083bf03bd34eabe12168863d4cdb493 SHA512 77ee9998c96ba5e4eb007b81e04a051a6f8fc3ac837496a8c9e6637fdbff3e6fbba4912919b1cb2c5ed72951cc9fb8eb28d699e3f15de14ecbb51c362111eafc WHIRLPOOL ee65af738a841a05c7d2ad2e9b021e3b0a0e046db706c747802d675d76246701b62d1911fae321aa460f7aafd17274b21177fd2cc5c647383ac6b6eba37cd36d

dev-python/flask/flask-0.11.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy{,3} )
+
+inherit distutils-r1
+
+MY_PN="Flask"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+HOMEPAGE="https://github.com/pallets/flask/"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-python/blinker-1[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-0.7[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.4[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-0.21[${PYTHON_USEDEP}]
+	>=dev-python/click-2[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	 # Prevent un-needed d'loading
+	sed -e "s/ 'sphinx.ext.intersphinx',//" -i docs/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test -v || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	use doc && HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}