From 6faa56e4bc50bdbe5bd1bf7917b5217d91cf465a Mon Sep 17 00:00:00 2001
From: Sebastian Parborg <darkdefende@gmail.com>
Date: Mon, 1 May 2023 16:56:29 +0200
Subject: [PATCH] media-libs/osl: Bump to 1.12.7.0

Signed-off-by: Sebastian Parborg <darkdefende@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/30823
Signed-off-by: Sam James <sam@gentoo.org>
---
 media-libs/osl/Manifest             |   1 +
 media-libs/osl/osl-1.12.11.0.ebuild | 106 ++++++++++++++++++++++++++++
 2 files changed, 107 insertions(+)
 create mode 100644 media-libs/osl/osl-1.12.11.0.ebuild

diff --git a/media-libs/osl/Manifest b/media-libs/osl/Manifest
index 11f422a9e40f6..75ed128ae73ed 100644
--- a/media-libs/osl/Manifest
+++ b/media-libs/osl/Manifest
@@ -1 +1,2 @@
+DIST osl-1.12.11.0.tar.gz 20287156 BLAKE2B 178db816980929cc61a0deea63f715a9f10adc41c6dd264bca8df451ef9531c4ee9477f6374f160b2a7d6fb72289a3edcbe5a3e8050ff2fdcc6bfe57fda58626 SHA512 9cf7b08f43e66d280cb90bf8c579f3a7d949934ac8e7a9289113a4a34158a43e32c9b73863f2a94a628ebc1a988923c3a7d32f0944745ae7c74dc164fdd5125e
 DIST osl-1.12.7.0.tar.gz 20250356 BLAKE2B a9398243546b1bfc1e3f9602f6112a72a8e7cb6ace54e93d0e5f30d943474e82c3317596597d6a09e0f2cf04b1b21f05c31a2357e3d667d710cd2aa340f5fd63 SHA512 ec0391dfc95140fee4fa8332991cdcb0978dafc436f3e07d0293e2baa2014b8765e6b60631ae5a8bbd6e16dbcf37f04c076d7d6b2d8bfa58b78471f0d92c433f
diff --git a/media-libs/osl/osl-1.12.11.0.ebuild b/media-libs/osl/osl-1.12.11.0.ebuild
new file mode 100644
index 0000000000000..d9c353880f224
--- /dev/null
+++ b/media-libs/osl/osl-1.12.11.0.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+# Check this on updates
+LLVM_MAX_SLOT=15
+
+inherit cmake llvm toolchain-funcs python-single-r1
+
+DESCRIPTION="Advanced shading language for production GI renderers"
+HOMEPAGE="http://opensource.imageworks.com/?p=osl"
+# If a development release, please don't keyword!
+SRC_URI="https://github.com/imageworks/OpenShadingLanguage/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/OpenShadingLanguage-${PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+X86_CPU_FEATURES=(
+	sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4.1 sse4_2:sse4.2
+	avx:avx avx2:avx2 avx512f:avx512f f16c:f16c
+)
+CPU_FEATURES=( ${X86_CPU_FEATURES[@]/#/cpu_flags_x86_} )
+
+IUSE="doc partio qt5 test ${CPU_FEATURES[@]%:*} python"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-libs/pugixml
+	>=media-libs/openexr-3:0=
+	>=media-libs/openimageio-2.3.12.0:=
+	<sys-devel/clang-$((${LLVM_MAX_SLOT} + 1)):=
+	sys-libs/zlib:=
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/pybind11[${PYTHON_USEDEP}]
+		')
+	)
+	partio? ( media-libs/partio )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+"
+
+llvm_check_deps() {
+	has_version -r "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+	llvm_pkg_setup
+
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local cpufeature
+	local mysimd=()
+	for cpufeature in "${CPU_FEATURES[@]}"; do
+		use "${cpufeature%:*}" && mysimd+=("${cpufeature#*:}")
+	done
+
+	# If no CPU SIMDs were used, completely disable them
+	[[ -z ${mysimd} ]] && mysimd=("0")
+
+	local gcc="$(tc-getCC)"
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+		-DINSTALL_DOCS=$(usex doc)
+		-DUSE_CCACHE=OFF
+		-DLLVM_STATIC=OFF
+		-DOSL_BUILD_TESTS=$(usex test)
+		-DSTOP_ON_WARNING=OFF
+		-DUSE_PARTIO=$(usex partio)
+		-DUSE_QT=$(usex qt5)
+		-DUSE_PYTHON=$(usex python)
+		-DPYTHON_VERSION="${EPYTHON/python}"
+		-DUSE_SIMD="$(IFS=","; echo "${mysimd[*]}")"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# TODO: investigate failures
+	local myctestargs=(
+		-E "(osl-imageio|osl-imageio.opt|render-background|render-bumptest|render-mx-furnace-burley-diffuse|render-mx-furnace-sheen|render-mx-burley-diffuse|render-mx-conductor|render-mx-generalized-schlick|render-mx-generalized-schlick-glass|render-microfacet|render-oren-nayar|render-uv|render-veachmis|render-ward|render-raytypes.opt|color|color.opt|example-deformer)"
+	)
+
+	cmake_src_test
+}