From f301a9aab4a277e27eb8de31146d2e57d775de6c Mon Sep 17 00:00:00 2001
From: Hans de Graaff <graaff@gentoo.org>
Date: Wed, 27 Nov 2024 07:37:47 +0100
Subject: [PATCH 1/8] dev-ruby/ruby-oembed: add 0.18.1

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
---
 dev-ruby/ruby-oembed/Manifest                 |  1 +
 .../ruby-oembed/ruby-oembed-0.18.1.ebuild     | 41 +++++++++++++++++++
 2 files changed, 42 insertions(+)
 create mode 100644 dev-ruby/ruby-oembed/ruby-oembed-0.18.1.ebuild

diff --git a/dev-ruby/ruby-oembed/Manifest b/dev-ruby/ruby-oembed/Manifest
index 03bfdca981282..bd2602ae8d2ea 100644
--- a/dev-ruby/ruby-oembed/Manifest
+++ b/dev-ruby/ruby-oembed/Manifest
@@ -1,2 +1,3 @@
 DIST ruby-oembed-0.17.0.tar.gz 4548719 BLAKE2B d91c4321b745b5c96f866468f8985ec5a27b8318450b14b92f4c7456cea3dea048fb66d5d1c93a3ebd7b12d52a5ea6b2a543987f9d83d35b64521f46bf204d05 SHA512 ec130cca009dd63d18ff3498be2bd05eacdef28c3e7dbae9a373da7700949a18184714dfb3b942154b5af0e305ccdcaf7d18652f36236599d04f0ba531d8aca4
 DIST ruby-oembed-0.18.0.tar.gz 8018574 BLAKE2B fa78c6d84b5f2d479d094091642aa8bcfcbc3d1687e9f6d498ced3090ad86a64f7c1ff61a6ce53c0e7353680ed307c9bceece8321419a260baa7651efe1794cc SHA512 6ab69c4e3d887a919047026194f470057563238962b8de05d594c2f37898603aa6991b79ce188fbeef13a2e272bd091229d76e0b1adf8774b007ea786f2f8497
+DIST ruby-oembed-0.18.1.tar.gz 8021833 BLAKE2B 7adac44e599710046abd277e8b90f4eb852e14c67c92261fc67ce52defbbd34058577b1326fa3a5b8396c85dfe50c18e890e92603a7ccf01339f13c5788cdb87 SHA512 7e6050d087ba31b27cfbb27239b1dd9438b7dc325c3ce61c2a313101be753f30486b78460663a875da20f0377a00120e2a04aa99523fbf3afd6e361f47262d65
diff --git a/dev-ruby/ruby-oembed/ruby-oembed-0.18.1.ebuild b/dev-ruby/ruby-oembed/ruby-oembed-0.18.1.ebuild
new file mode 100644
index 0000000000000..e37354c36dee5
--- /dev/null
+++ b/dev-ruby/ruby-oembed/ruby-oembed-0.18.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+USE_RUBY="ruby31 ruby32 ruby33"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.rdoc README.md"
+RUBY_FAKEGEM_GEMSPEC="ruby-oembed.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="An oEmbed consumer library written in Ruby"
+HOMEPAGE="https://github.com/ruby-oembed/ruby-oembed"
+SRC_URI="https://github.com/ruby-oembed/ruby-oembed/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="MIT"
+
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+ruby_add_bdepend "test?
+	(
+		dev-ruby/json
+		dev-ruby/vcr:6
+		dev-ruby/xml-simple
+		dev-ruby/nokogiri
+		dev-ruby/webmock:3
+	)"
+
+all_ruby_prepare() {
+	# Remove bundler but keep vcr version requirement
+	rm -f Gemfile || die
+	sed -i -e '1igem "vcr", "~> 6.0"' spec/spec_helper.rb || die
+
+	# Avoid development dependencies
+	sed -i -e '/coverall/I s:^:#:' spec/spec_helper.rb || die
+
+	sed -i -e 's/git ls-files/find * -print/' ${RUBY_FAKEGEM_GEMSPEC} || die
+}

From 2ae901bb9a0f235f8908c75e83b7198d3d7d8b4b Mon Sep 17 00:00:00 2001
From: Hans de Graaff <graaff@gentoo.org>
Date: Wed, 27 Nov 2024 07:39:51 +0100
Subject: [PATCH 2/8] dev-ruby/selenium-webdriver: add 4.27.0

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
---
 dev-ruby/selenium-webdriver/Manifest          |  1 +
 .../selenium-webdriver-4.27.0.ebuild          | 44 +++++++++++++++++++
 2 files changed, 45 insertions(+)
 create mode 100644 dev-ruby/selenium-webdriver/selenium-webdriver-4.27.0.ebuild

diff --git a/dev-ruby/selenium-webdriver/Manifest b/dev-ruby/selenium-webdriver/Manifest
index bd1ceb339c4f0..453f53daf482b 100644
--- a/dev-ruby/selenium-webdriver/Manifest
+++ b/dev-ruby/selenium-webdriver/Manifest
@@ -4,3 +4,4 @@ DIST selenium-webdriver-4.11.0.gem 6300672 BLAKE2B bedbc18c14ab67c1bde05a35b5b66
 DIST selenium-webdriver-4.24.0.gem 8609280 BLAKE2B 629846a239f65a37ff093014e39a7da79832cbd1f1031cdf7a3a4d94eccad9082d70cc3d7cb62c673a6dd60eaeb80160229cdba0699d6124b539925dade1b7f9 SHA512 5d12c65296a80e9a109376025f8a5c404af2b35cef6f232ca18e0c925ca7008b55726cd0fde2fadd5b560d3df1b7417a574aee012da97504b32c1a4f49807a5f
 DIST selenium-webdriver-4.25.0.gem 8715776 BLAKE2B 382a63e42a298ce5dc7b7f37927c01f436baf3e6b45c62acafe445f6858c006b55d4df5f4ce8d6f0418c4f55f3d71ffd055f821e32f2dda52375fbca2e1fa167 SHA512 4464179de283785076603ccab0ea1e448c902d949c20d755c5cf3d80684dd2a8e6b67a94a4a4e351edccdbabd8501eda7dc268e28f013b089d0d24fc24b5f4ea
 DIST selenium-webdriver-4.26.0.gem 8705024 BLAKE2B b66ce6224ca862a457ce13eff289c007b089210215d145472e0ae9bdb65f2c7a1b9de9d301de9e29465c1c9749a376175be65c53614a18ed866b0a6a48972af5 SHA512 789181146ba89f8361b35c101a8a90d38ab8e05e182dae16f53e587a87cc08af6c6c50b8c475fb82662042499589681b75b55cf949d271a233163b64c5d14768
+DIST selenium-webdriver-4.27.0.gem 8709632 BLAKE2B 44fa6622189316c6606f1edbdaed8834a4a0ab0c12da81fca51fcf28d8f07cc7de6233c689cabf0e3fb242b0667687d3d9213887076ef4e24387f3fc5ba59c3a SHA512 0dc8e962d0f4403882a976ee841af074a52da608e33894c7eafcc6528fd268c533eefd95cdbfcd1a3a3cba70a9d453cb1da18f374d098fd05e5a8255c7532e7d
diff --git a/dev-ruby/selenium-webdriver/selenium-webdriver-4.27.0.ebuild b/dev-ruby/selenium-webdriver/selenium-webdriver-4.27.0.ebuild
new file mode 100644
index 0000000000000..c0afd06f0f536
--- /dev/null
+++ b/dev-ruby/selenium-webdriver/selenium-webdriver-4.27.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby31 ruby32 ruby33"
+
+RUBY_FAKEGEM_RECIPE_DOC="none"
+RUBY_FAKEGEM_EXTRADOC="CHANGES README.md"
+
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_GEMSPEC="selenium-webdriver.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="This gem provides Ruby bindings for WebDriver"
+HOMEPAGE="https://github.com/seleniumhq/selenium"
+
+LICENSE="Apache-2.0"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND=" >=dev-util/selenium-manager-$(ver_cut 1-2)"
+
+ruby_add_rdepend "
+	>=dev-ruby/base64-0.2 =dev-ruby/base64-0*
+	>=dev-ruby/logger-1.4:0
+	>=dev-ruby/rexml-3.2.5:3
+	dev-ruby/rubyzip:2
+	dev-ruby/websocket:0
+"
+
+all_ruby_prepare() {
+	# Remove the pre-compiled selenium-manager executables
+	rm -fr bin || die
+}
+
+pkg_postinst() {
+	ewarn "This package now uses the SE_MANAGER_PATH environment "
+	ewarn "variable to locate selenium-manager.  This variable is"
+	ewarn "provided by the selenium-manager package but may not be"
+	ewarn "available yet directly after the update."
+}

From f7e2bbabf7cb6a59629015bbb9329bebab1dd859 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Wed, 27 Nov 2024 06:35:49 +0000
Subject: [PATCH 3/8] net-analyzer/wireshark: add 4.4.2

Signed-off-by: Sam James <sam@gentoo.org>
---
 net-analyzer/wireshark/Manifest               |   2 +
 net-analyzer/wireshark/wireshark-4.4.2.ebuild | 343 ++++++++++++++++++
 2 files changed, 345 insertions(+)
 create mode 100644 net-analyzer/wireshark/wireshark-4.4.2.ebuild

diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index 7aeaf28f9e501..5d82171eec08e 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -14,3 +14,5 @@ DIST wireshark-4.4.0-signatures.txt 2706 BLAKE2B 46337f24dfe32b1ff39f8a0b1f30c29
 DIST wireshark-4.4.0.tar.xz 46786568 BLAKE2B 679b774e780201d1d188f5ce2ec1eb21d98250d2dd45b37b741a3cd5d6dc59d983e473a3f87e3ae1b8eef0b0f9b0c02227eecee644697ec19b6c3b2a21a5ad31 SHA512 a00275ffcc7c5bdf546e3e1c95a2fa77b86232d008f77b1b2f3de8e63f1862321d7a439cba2d136be4407131e07e20071d972a4efb7db2bc55388a347f47ce9e
 DIST wireshark-4.4.1-signatures.txt 2706 BLAKE2B 04458da4aedbefa57f03711781215b999bbf1e8d5f34aefa7d853b18991cb08da29ec9b922fd1b9d8f1092cd9b1a080df8aa41bf0e5981639cc9820c39302b12 SHA512 145c6739d092f0068666c4317b58efdfd34690511ff30797c0fa153abc847f96fb84ea8bde4e09c681ca28b32ddb7dc25683c8e40ccb55b83c23328f2e732f62
 DIST wireshark-4.4.1.tar.xz 46748700 BLAKE2B 747ffe14a7b30c4d7bb435bff1fded11efcf03a8bfcacd48d36141fae7a9cfb7965076b1a807d7f095f66bb99148732c090493d2c3654b4a20355f8dbeac3972 SHA512 66c5e035a5a0d2bbb82fba67b652e0e37c296ab470da59b8ed71ef4e6d6d061d6a2649b5af544b737cdf31d808a7f8f07a64a9e4d805674ce8965eff23081de4
+DIST wireshark-4.4.2-signatures.txt 2706 BLAKE2B 3349a3e88782e1326b6c2e1b56d5eefbaeb2dbd6cf33b055e3a49692023b02e77a7e6d26ade7a9018cda783aa29edade997aaa03222fadb06c5bfa106a492459 SHA512 c809085b69c909702b3390b93891a19b8a8c0812d448ac9399eb59991618737b3bfeb737bd569267dcffc46290d59b34664f967e88c1a38b1678faaecd76d445
+DIST wireshark-4.4.2.tar.xz 46763620 BLAKE2B ea5c48f06c2aeb5b51f6ba62fd57214e9dd79917f978867d3ae31ffec74eb82ba7c8a2e2dcba415e53d051e531f9f9907aac88c6f29b6746222cf812bb43c85b SHA512 df80c98a2d00ba46a853acfe3aec9dfc0d4484f490a276b8b8390b6d108634b7e0fa38e8f02f8d93afe5c2394c463a0d89611027032898d7d0390d2111b70ca6
diff --git a/net-analyzer/wireshark/wireshark-4.4.2.ebuild b/net-analyzer/wireshark/wireshark-4.4.2.ebuild
new file mode 100644
index 0000000000000..5c5d9c7af028f
--- /dev/null
+++ b/net-analyzer/wireshark/wireshark-4.4.2.ebuild
@@ -0,0 +1,343 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{3..4} )
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit fcaps flag-o-matic lua-single python-any-r1 qmake-utils xdg cmake
+
+DESCRIPTION="Network protocol analyzer (sniffer)"
+HOMEPAGE="https://www.wireshark.org/"
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://gitlab.com/wireshark/wireshark"
+	inherit git-r3
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/wireshark.asc
+	inherit verify-sig
+
+	SRC_URI="https://www.wireshark.org/download/src/all-versions/${P/_/}.tar.xz"
+	SRC_URI+=" verify-sig? ( https://www.wireshark.org/download/SIGNATURES-${PV}.txt -> ${P}-signatures.txt )"
+	S="${WORKDIR}/${P/_/}"
+
+	if [[ ${PV} != *_rc* ]] ; then
+		KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc64 ~riscv ~x86"
+	fi
+fi
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+IUSE="androiddump bcg729 brotli +capinfos +captype ciscodump +dftest doc dpauxmon"
+IUSE+=" +dumpcap +editcap +gui http2 http3 ilbc kerberos libxml2 lua lz4 maxminddb"
+IUSE+=" +mergecap +minizip +netlink opus +plugins +pcap +randpkt"
+IUSE+=" +randpktdump +reordercap sbc selinux +sharkd smi snappy spandsp sshdump ssl"
+IUSE+=" sdjournal test +text2pcap tfshark +tshark +udpdump wifi zlib +zstd"
+
+REQUIRED_USE="
+	lua? ( ${LUA_REQUIRED_USE} )
+"
+
+RESTRICT="!test? ( test )"
+
+# bug #753062 for speexdsp
+RDEPEND="
+	acct-group/pcap
+	>=dev-libs/glib-2.50.0:2
+	dev-libs/libpcre2
+	>=net-dns/c-ares-1.13.0:=
+	>=dev-libs/libgcrypt-1.8.0:=
+	media-libs/speexdsp
+	bcg729? ( media-libs/bcg729 )
+	brotli? ( app-arch/brotli:= )
+	ciscodump? ( >=net-libs/libssh-0.6:= )
+	filecaps? ( sys-libs/libcap )
+	http2? ( >=net-libs/nghttp2-1.11.0:= )
+	http3? ( net-libs/nghttp3 )
+	ilbc? ( media-libs/libilbc:= )
+	kerberos? ( virtual/krb5 )
+	libxml2? ( dev-libs/libxml2 )
+	lua? ( ${LUA_DEPS} )
+	lz4? ( app-arch/lz4:= )
+	maxminddb? ( dev-libs/libmaxminddb:= )
+	minizip? ( sys-libs/zlib[minizip] )
+	netlink? ( dev-libs/libnl:3 )
+	opus? ( media-libs/opus )
+	pcap? ( net-libs/libpcap )
+	gui? (
+		dev-qt/qtbase:6[concurrent,dbus,gui,widgets]
+		dev-qt/qt5compat:6
+		dev-qt/qtdeclarative:6
+		dev-qt/qtmultimedia:6
+		x11-misc/xdg-utils
+	)
+	sbc? ( media-libs/sbc )
+	sdjournal? ( sys-apps/systemd:= )
+	smi? ( net-libs/libsmi )
+	snappy? ( app-arch/snappy:= )
+	spandsp? ( media-libs/spandsp:= )
+	sshdump? ( >=net-libs/libssh-0.6:= )
+	ssl? ( >=net-libs/gnutls-3.5.8:= )
+	wifi? ( >=net-libs/libssh-0.6:= )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="
+	${RDEPEND}
+"
+# TODO: 4.0.0_rc1 release notes say:
+# "Perl is no longer required to build Wireshark, but may be required to build some source code files and run code analysis checks."
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-lang/perl
+	app-alternatives/lex
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+		dev-ruby/asciidoctor
+		dev-libs/libxslt
+	)
+	gui? (
+		dev-qt/qttools:6[linguist]
+	)
+	test? (
+		$(python_gen_any_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="
+	${RDEPEND}
+	gui? ( virtual/freedesktop-icon-theme )
+	selinux? ( sec-policy/selinux-wireshark )
+"
+
+if [[ ${PV} != *9999* ]] ; then
+	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-wireshark )"
+fi
+
+python_check_deps() {
+	use test || return 0
+
+	python_has_version -b "dev-python/pytest[${PYTHON_USEDEP}]" &&
+		 python_has_version -b "dev-python/pytest-xdist[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+
+	python-any-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]] ; then
+		git-r3_src_unpack
+	else
+		if use verify-sig ; then
+			cd "${DISTDIR}" || die
+			verify-sig_verify_signed_checksums \
+				${P}-signatures.txt \
+				openssl-dgst \
+				${P}.tar.xz
+			cd "${WORKDIR}" || die
+		fi
+
+		default
+	fi
+}
+
+src_configure() {
+	local mycmakeargs
+
+	python_setup
+
+	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
+	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
+	if use kerberos ; then
+		case $(krb5-config --libs) in
+			*-lcrypto*)
+				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
+				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
+				ewarn "license and the GPL, so do your check before distributing such package."
+				mycmakeargs+=( -DENABLE_GNUTLS=$(usex ssl) )
+				;;
+		esac
+	fi
+
+	if use gui ; then
+		append-cxxflags -fPIC -DPIC
+	fi
+
+	# crashes at runtime
+	# https://bugs.gentoo.org/754021
+	filter-lto
+
+	mycmakeargs+=(
+		-DPython3_EXECUTABLE="${PYTHON}"
+		-DCMAKE_DISABLE_FIND_PACKAGE_{Asciidoctor,DOXYGEN}=$(usex !doc)
+
+		# Force bundled lemon (bug 933119)
+		-DLEMON_EXECUTABLE=
+
+		-DRPMBUILD_EXECUTABLE=
+		-DGIT_EXECUTABLE=
+		-DENABLE_CCACHE=OFF
+
+		$(use androiddump && use pcap && echo -DEXTCAP_ANDROIDDUMP_LIBPCAP=yes)
+		$(usex gui LRELEASE=$(qt6_get_bindir)/lrelease '')
+		$(usex gui MOC=$(qt6_get_bindir)/moc '')
+		$(usex gui RCC=$(qt6_get_bindir)/rcc '')
+		$(usex gui UIC=$(qt6_get_bindir)/uic '')
+
+		-DBUILD_androiddump=$(usex androiddump)
+		-DBUILD_capinfos=$(usex capinfos)
+		-DBUILD_captype=$(usex captype)
+		-DBUILD_ciscodump=$(usex ciscodump)
+		-DBUILD_dftest=$(usex dftest)
+		-DBUILD_dpauxmon=$(usex dpauxmon)
+		-DBUILD_dumpcap=$(usex dumpcap)
+		-DBUILD_editcap=$(usex editcap)
+		-DBUILD_mergecap=$(usex mergecap)
+		-DBUILD_mmdbresolve=$(usex maxminddb)
+		-DBUILD_randpkt=$(usex randpkt)
+		-DBUILD_randpktdump=$(usex randpktdump)
+		-DBUILD_reordercap=$(usex reordercap)
+		-DBUILD_sdjournal=$(usex sdjournal)
+		-DBUILD_sharkd=$(usex sharkd)
+		-DBUILD_sshdump=$(usex sshdump)
+		-DBUILD_text2pcap=$(usex text2pcap)
+		-DBUILD_tfshark=$(usex tfshark)
+		-DBUILD_tshark=$(usex tshark)
+		-DBUILD_udpdump=$(usex udpdump)
+
+		-DBUILD_wireshark=$(usex gui)
+		-DUSE_qt6=$(usex gui)
+
+		-DENABLE_WERROR=OFF
+		-DENABLE_BCG729=$(usex bcg729)
+		-DENABLE_BROTLI=$(usex brotli)
+		-DENABLE_CAP=$(usex filecaps caps)
+		-DENABLE_GNUTLS=$(usex ssl)
+		-DENABLE_ILBC=$(usex ilbc)
+		-DENABLE_KERBEROS=$(usex kerberos)
+		-DENABLE_LIBXML2=$(usex libxml2)
+		# only appends -flto
+		-DENABLE_LTO=OFF
+		-DENABLE_LUA=$(usex lua)
+		-DLUA_FIND_VERSIONS="${ELUA#lua}"
+		-DENABLE_LZ4=$(usex lz4)
+		-DENABLE_MINIZIP=$(usex minizip)
+		-DENABLE_NETLINK=$(usex netlink)
+		-DENABLE_NGHTTP2=$(usex http2)
+		-DENABLE_NGHTTP3=$(usex http3)
+		-DENABLE_OPUS=$(usex opus)
+		-DENABLE_PCAP=$(usex pcap)
+		-DENABLE_PLUGINS=$(usex plugins)
+		-DENABLE_PLUGIN_IFDEMO=OFF
+		-DENABLE_SBC=$(usex sbc)
+		-DENABLE_SMI=$(usex smi)
+		-DENABLE_SNAPPY=$(usex snappy)
+		-DENABLE_SPANDSP=$(usex spandsp)
+		-DBUILD_wifidump=$(usex wifi)
+		-DENABLE_ZLIB=$(usex zlib)
+		-DENABLE_ZSTD=$(usex zstd)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cmake_build test-programs
+
+	# https://www.wireshark.org/docs/wsdg_html_chunked/ChTestsRunPytest.html
+	epytest \
+		--disable-capture \
+		--skip-missing-programs=all \
+		--program-path "${BUILD_DIR}"/run
+}
+
+src_install() {
+	# bug #928577
+	# https://gitlab.com/wireshark/wireshark/-/commit/fe7bfdf6caac9204ab5f34eeba7b0f4a0314d3cd
+	cmake_src_install install-headers
+
+	if ! use doc; then
+		# prepare Relase Notes redirector (bug #939195)
+		local relnotes="doc/release-notes.html"
+
+		# by default create a link for our specific version
+		local relversion="wireshark-${PV}.html"
+
+		# for 9999 we link to the release notes index page
+		if [[ ${PV} == *9999* ]] ; then
+			relversion=""
+		fi
+
+		# patch version into redirector & install it
+		sed -e "s/#VERSION#/${relversion}/g" < "${FILESDIR}/release-notes.html" > ${relnotes} || die
+		dodoc ${relnotes}
+	fi
+
+	# FAQ is not required as is installed from help/faq.txt
+	dodoc AUTHORS ChangeLog README* doc/randpkt.txt doc/README*
+
+	# install headers
+	insinto /usr/include/wireshark
+	doins "${BUILD_DIR}"/config.h
+
+	# If trying to remove this, try build e.g. libvirt first!
+	# At last check, Fedora is still doing this too.
+	local dir dirs=(
+		epan
+		epan/crypt
+		epan/dfilter
+		epan/dissectors
+		epan/ftypes
+		wiretap
+		wsutil
+		wsutil/wmem
+	)
+
+	for dir in "${dirs[@]}" ; do
+		insinto /usr/include/wireshark/${dir}
+		doins ${dir}/*.h
+	done
+
+	if use gui ; then
+		local s
+
+		for s in 16 32 48 64 128 256 512 1024 ; do
+			insinto /usr/share/icons/hicolor/${s}x${s}/apps
+			newins resources/icons/wsicon${s}.png wireshark.png
+		done
+
+		for s in 16 24 32 48 64 128 256 ; do
+			insinto /usr/share/icons/hicolor/${s}x${s}/mimetypes
+			newins resources/icons//WiresharkDoc-${s}.png application-vnd.tcpdump.pcap.png
+		done
+	fi
+
+	if [[ -d "${ED}"/usr/share/appdata ]] ; then
+		rm -r "${ED}"/usr/share/appdata || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	# Add group for users allowed to sniff.
+	chgrp pcap "${EROOT}"/usr/bin/dumpcap
+
+	if use dumpcap && use pcap ; then
+		fcaps -o 0 -g pcap -m 4710 -M 0710 \
+			cap_dac_read_search,cap_net_raw,cap_net_admin \
+			"${EROOT}"/usr/bin/dumpcap
+	fi
+
+	ewarn "NOTE: To capture traffic with wireshark as normal user you have to"
+	ewarn "add yourself to the pcap group. This security measure ensures"
+	ewarn "that only trusted users are allowed to sniff your traffic."
+}

From 3c14628ca5047e41ce4b4ed806bcf77c79ca35e5 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Wed, 27 Nov 2024 06:43:12 +0000
Subject: [PATCH 4/8] net-analyzer/wireshark: add 4.2.9

Signed-off-by: Sam James <sam@gentoo.org>
---
 net-analyzer/wireshark/Manifest               |   2 +
 net-analyzer/wireshark/wireshark-4.2.9.ebuild | 346 ++++++++++++++++++
 2 files changed, 348 insertions(+)
 create mode 100644 net-analyzer/wireshark/wireshark-4.2.9.ebuild

diff --git a/net-analyzer/wireshark/Manifest b/net-analyzer/wireshark/Manifest
index 5d82171eec08e..188cd783da19c 100644
--- a/net-analyzer/wireshark/Manifest
+++ b/net-analyzer/wireshark/Manifest
@@ -10,6 +10,8 @@ DIST wireshark-4.2.7-signatures.txt 2706 BLAKE2B e209123e0785f7cdda0083c142575a8
 DIST wireshark-4.2.7.tar.xz 45017312 BLAKE2B ab82c4ff9afa0fecb3cddbabc7441c3f457c2ccfc39f8a1e65f5d4df752bbdf7cb3d892db5a3de86ec055b12c512f4d067f6d98626ecd2f58f31052e10415be8 SHA512 22ef36bb18610c36d848277c95df17734ac266ea301e636fd19900da0ac49c3d5ce8b59c3fce3a2ef1e919c70fa4003647cbd417c06248dabe498f5772f62c15
 DIST wireshark-4.2.8-signatures.txt 2706 BLAKE2B 10128023609008d18a502e09ec8f77898db557fe08340bd242c07f0b9802da6c326f7391b363764800debf5e0ef8aa5df73771bad5881f875a32e0faba5907a6 SHA512 031ab84ab1232a74108ad37ae03f8fe1eb3728fc04b20887e89343ebff985a27b7b04653599a4ba03a3e98dfff33a38adbc1671d0519fc73c2677d82702f4542
 DIST wireshark-4.2.8.tar.xz 45032832 BLAKE2B 315926efc0b53b5ca2a35dc2dedf66f14150a6f06eac18816d12defcba2ba9e136abc63fe1042a9d3a93820f5854f8375638bef86c7a95d0315494edda290470 SHA512 4c132d8760ca7bc4976ee5f5b3f4904610d7e2129e10653d3d3fc6ca371b1891c8de2981324bd3113e5bf9302add0370f97b041314b3f6c508da46815a40a562
+DIST wireshark-4.2.9-signatures.txt 2706 BLAKE2B 5f1f30a8fce3c967cab165667a4f27bc1a8e425d41d6df42f91a1249bc3934e8fbae29f0e13e53f7f821e1b1b4420564b482e882cfaef66d5f05c5a54bdaa0b8 SHA512 9a259c8e1a9f7308348bf8c45023d9c6d3a6e51f05c89c500c4232267b4d13f8fd18803e78ed45646c73c66769f13bdaf7f071df98e92d2d63c432d176a946eb
+DIST wireshark-4.2.9.tar.xz 45045592 BLAKE2B 3e39f6c9e606b818abaab8339906c17c50c1a675583725bd4cdd4530f95054cb5d7679f4e022ac5dd2eedb84d08b528be75b5d0f715f1f710393254840b7bb58 SHA512 6ad9318549ab60794c967a071a267e9642e97bb52289570e36c8221e6e160bafb346f789ad879ae1a87c0789ce3352b6a795a5a2ccf723891615a0b8c62eb668
 DIST wireshark-4.4.0-signatures.txt 2706 BLAKE2B 46337f24dfe32b1ff39f8a0b1f30c29a43d7a02a4e8e787833dde47a98206f36501b3e7fe449cc874f81733f8a7b2a16b4e5b07a2fae20d7ddae0121adbc8f98 SHA512 1725790d0671d31814b92508079a135d328df58bd94305e2406a3edf9e08bc5e2bb4ac487045b99684acb8cc8343422cececa32319bbcb36712bb3b2c860cb0c
 DIST wireshark-4.4.0.tar.xz 46786568 BLAKE2B 679b774e780201d1d188f5ce2ec1eb21d98250d2dd45b37b741a3cd5d6dc59d983e473a3f87e3ae1b8eef0b0f9b0c02227eecee644697ec19b6c3b2a21a5ad31 SHA512 a00275ffcc7c5bdf546e3e1c95a2fa77b86232d008f77b1b2f3de8e63f1862321d7a439cba2d136be4407131e07e20071d972a4efb7db2bc55388a347f47ce9e
 DIST wireshark-4.4.1-signatures.txt 2706 BLAKE2B 04458da4aedbefa57f03711781215b999bbf1e8d5f34aefa7d853b18991cb08da29ec9b922fd1b9d8f1092cd9b1a080df8aa41bf0e5981639cc9820c39302b12 SHA512 145c6739d092f0068666c4317b58efdfd34690511ff30797c0fa153abc847f96fb84ea8bde4e09c681ca28b32ddb7dc25683c8e40ccb55b83c23328f2e732f62
diff --git a/net-analyzer/wireshark/wireshark-4.2.9.ebuild b/net-analyzer/wireshark/wireshark-4.2.9.ebuild
new file mode 100644
index 0000000000000..e6493d6e836c5
--- /dev/null
+++ b/net-analyzer/wireshark/wireshark-4.2.9.ebuild
@@ -0,0 +1,346 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..2} )
+# TODO: check cmake/modules/UseAsn2Wrs.cmake for 3.12
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit fcaps flag-o-matic lua-single python-any-r1 qmake-utils xdg cmake
+
+DESCRIPTION="Network protocol analyzer (sniffer)"
+HOMEPAGE="https://www.wireshark.org/"
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://gitlab.com/wireshark/wireshark"
+	inherit git-r3
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/wireshark.asc
+	inherit verify-sig
+
+	SRC_URI="https://www.wireshark.org/download/src/all-versions/${P/_/}.tar.xz"
+	SRC_URI+=" verify-sig? ( https://www.wireshark.org/download/SIGNATURES-${PV}.txt -> ${P}-signatures.txt )"
+	S="${WORKDIR}/${P/_/}"
+
+	if [[ ${PV} != *_rc* ]] ; then
+		KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc64 ~riscv ~x86"
+	fi
+fi
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+IUSE="androiddump bcg729 brotli +capinfos +captype ciscodump +dftest doc dpauxmon"
+IUSE+=" +dumpcap +editcap +gui http2 http3 ilbc kerberos libxml2 lua lz4 maxminddb"
+IUSE+=" +mergecap +minizip +netlink opus +plugins +pcap qt6 +randpkt"
+IUSE+=" +randpktdump +reordercap sbc selinux +sharkd smi snappy spandsp sshdump ssl"
+IUSE+=" sdjournal test +text2pcap tfshark +tshark +udpdump wifi zlib +zstd"
+
+REQUIRED_USE="
+	lua? ( ${LUA_REQUIRED_USE} )
+"
+
+RESTRICT="!test? ( test )"
+
+# bug #753062 for speexdsp
+RDEPEND="
+	acct-group/pcap
+	>=dev-libs/glib-2.50.0:2
+	dev-libs/libpcre2
+	>=net-dns/c-ares-1.13.0:=
+	>=dev-libs/libgcrypt-1.8.0:=
+	media-libs/speexdsp
+	bcg729? ( media-libs/bcg729 )
+	brotli? ( app-arch/brotli:= )
+	ciscodump? ( >=net-libs/libssh-0.6:= )
+	filecaps? ( sys-libs/libcap )
+	http2? ( >=net-libs/nghttp2-1.11.0:= )
+	http3? ( net-libs/nghttp3 )
+	ilbc? ( media-libs/libilbc:= )
+	kerberos? ( virtual/krb5 )
+	libxml2? ( dev-libs/libxml2 )
+	lua? ( ${LUA_DEPS} )
+	lz4? ( app-arch/lz4:= )
+	maxminddb? ( dev-libs/libmaxminddb:= )
+	minizip? ( sys-libs/zlib[minizip] )
+	netlink? ( dev-libs/libnl:3 )
+	opus? ( media-libs/opus )
+	pcap? ( net-libs/libpcap )
+	gui? (
+		x11-misc/xdg-utils
+		qt6? (
+			dev-qt/qtbase:6[concurrent,dbus,gui,widgets]
+			dev-qt/qt5compat:6
+			dev-qt/qtmultimedia:6
+		)
+		!qt6? (
+			dev-qt/qtcore:5
+			dev-qt/qtconcurrent:5
+			dev-qt/qtgui:5
+			dev-qt/qtmultimedia:5
+			dev-qt/qtprintsupport:5
+			dev-qt/qtwidgets:5
+		)
+	)
+	sbc? ( media-libs/sbc )
+	sdjournal? ( sys-apps/systemd:= )
+	smi? ( net-libs/libsmi )
+	snappy? ( app-arch/snappy:= )
+	spandsp? ( media-libs/spandsp:= )
+	sshdump? ( >=net-libs/libssh-0.6:= )
+	ssl? ( >=net-libs/gnutls-3.5.8:= )
+	wifi? ( >=net-libs/libssh-0.6:= )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="
+	${RDEPEND}
+	gui? (
+		!qt6? (
+			dev-qt/qtdeclarative:5
+		)
+	)
+"
+# TODO: 4.0.0_rc1 release notes say:
+# "Perl is no longer required to build Wireshark, but may be required to build some source code files and run code analysis checks."
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-lang/perl
+	app-alternatives/lex
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen
+		dev-ruby/asciidoctor
+		dev-libs/libxslt
+	)
+	gui? (
+		qt6? (
+			dev-qt/qttools:6[linguist]
+		)
+		!qt6? (
+			dev-qt/linguist-tools:5
+		)
+	)
+	test? (
+		$(python_gen_any_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		')
+	)
+"
+RDEPEND="
+	${RDEPEND}
+	gui? ( virtual/freedesktop-icon-theme )
+	selinux? ( sec-policy/selinux-wireshark )
+"
+
+if [[ ${PV} != *9999* ]] ; then
+	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-wireshark )"
+fi
+
+python_check_deps() {
+	use test || return 0
+
+	python_has_version -b "dev-python/pytest[${PYTHON_USEDEP}]" &&
+		 python_has_version -b "dev-python/pytest-xdist[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+
+	python-any-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]] ; then
+		git-r3_src_unpack
+	else
+		if use verify-sig ; then
+			cd "${DISTDIR}" || die
+			verify-sig_verify_signed_checksums \
+				${P}-signatures.txt \
+				openssl-dgst \
+				${P}.tar.xz
+			cd "${WORKDIR}" || die
+		fi
+
+		default
+	fi
+}
+
+src_configure() {
+	local mycmakeargs
+
+	python_setup
+
+	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
+	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
+	if use kerberos ; then
+		case $(krb5-config --libs) in
+			*-lcrypto*)
+				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
+				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
+				ewarn "license and the GPL, so do your check before distributing such package."
+				mycmakeargs+=( -DENABLE_GNUTLS=$(usex ssl) )
+				;;
+		esac
+	fi
+
+	if use gui ; then
+		append-cxxflags -fPIC -DPIC
+	fi
+
+	# crashes at runtime
+	# https://bugs.gentoo.org/754021
+	filter-lto
+
+	mycmakeargs+=(
+		-DPython3_EXECUTABLE="${PYTHON}"
+		-DCMAKE_DISABLE_FIND_PACKAGE_{Asciidoctor,DOXYGEN}=$(usex !doc)
+
+		# Force bundled lemon (bug 933119)
+		-DLEMON_EXECUTABLE=
+
+		-DRPMBUILD_EXECUTABLE=
+		-DGIT_EXECUTABLE=
+		-DENABLE_CCACHE=OFF
+
+		$(use androiddump && use pcap && echo -DEXTCAP_ANDROIDDUMP_LIBPCAP=yes)
+		$(usex gui LRELEASE=$(qt5_get_bindir)/lrelease '')
+		$(usex gui MOC=$(qt5_get_bindir)/moc '')
+		$(usex gui RCC=$(qt5_get_bindir)/rcc '')
+		$(usex gui UIC=$(qt5_get_bindir)/uic '')
+
+		-DBUILD_androiddump=$(usex androiddump)
+		-DBUILD_capinfos=$(usex capinfos)
+		-DBUILD_captype=$(usex captype)
+		-DBUILD_ciscodump=$(usex ciscodump)
+		-DBUILD_dftest=$(usex dftest)
+		-DBUILD_dpauxmon=$(usex dpauxmon)
+		-DBUILD_dumpcap=$(usex dumpcap)
+		-DBUILD_editcap=$(usex editcap)
+		-DBUILD_mergecap=$(usex mergecap)
+		-DBUILD_mmdbresolve=$(usex maxminddb)
+		-DBUILD_randpkt=$(usex randpkt)
+		-DBUILD_randpktdump=$(usex randpktdump)
+		-DBUILD_reordercap=$(usex reordercap)
+		-DBUILD_sdjournal=$(usex sdjournal)
+		-DBUILD_sharkd=$(usex sharkd)
+		-DBUILD_sshdump=$(usex sshdump)
+		-DBUILD_text2pcap=$(usex text2pcap)
+		-DBUILD_tfshark=$(usex tfshark)
+		-DBUILD_tshark=$(usex tshark)
+		-DBUILD_udpdump=$(usex udpdump)
+
+		-DBUILD_wireshark=$(usex gui)
+		-DUSE_qt6=$(usex qt6)
+
+		-DENABLE_WERROR=OFF
+		-DENABLE_BCG729=$(usex bcg729)
+		-DENABLE_BROTLI=$(usex brotli)
+		-DENABLE_CAP=$(usex filecaps caps)
+		-DENABLE_GNUTLS=$(usex ssl)
+		-DENABLE_ILBC=$(usex ilbc)
+		-DENABLE_KERBEROS=$(usex kerberos)
+		-DENABLE_LIBXML2=$(usex libxml2)
+		# only appends -flto
+		-DENABLE_LTO=OFF
+		-DENABLE_LUA=$(usex lua)
+		-DLUA_FIND_VERSIONS="${ELUA#lua}"
+		-DENABLE_LZ4=$(usex lz4)
+		-DENABLE_MINIZIP=$(usex minizip)
+		-DENABLE_NETLINK=$(usex netlink)
+		-DENABLE_NGHTTP2=$(usex http2)
+		-DENABLE_NGHTTP3=$(usex http3)
+		-DENABLE_OPUS=$(usex opus)
+		-DENABLE_PCAP=$(usex pcap)
+		-DENABLE_PLUGINS=$(usex plugins)
+		-DENABLE_PLUGIN_IFDEMO=OFF
+		-DENABLE_SBC=$(usex sbc)
+		-DENABLE_SMI=$(usex smi)
+		-DENABLE_SNAPPY=$(usex snappy)
+		-DENABLE_SPANDSP=$(usex spandsp)
+		-DBUILD_wifidump=$(usex wifi)
+		-DENABLE_ZLIB=$(usex zlib)
+		-DENABLE_ZSTD=$(usex zstd)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	cmake_build test-programs
+
+	# https://www.wireshark.org/docs/wsdg_html_chunked/ChTestsRunPytest.html
+	epytest \
+		--disable-capture \
+		--skip-missing-programs=all \
+		--program-path "${BUILD_DIR}"/run
+}
+
+src_install() {
+	# bug #928577
+	# https://gitlab.com/wireshark/wireshark/-/commit/fe7bfdf6caac9204ab5f34eeba7b0f4a0314d3cd
+	cmake_src_install install-headers
+
+	# FAQ is not required as is installed from help/faq.txt
+	dodoc AUTHORS ChangeLog NEWS README* doc/randpkt.txt doc/README*
+
+	# install headers
+	insinto /usr/include/wireshark
+	doins "${BUILD_DIR}"/config.h
+
+	# If trying to remove this, try build e.g. libvirt first!
+	# At last check, Fedora is still doing this too.
+	local dir dirs=(
+		epan
+		epan/crypt
+		epan/dfilter
+		epan/dissectors
+		epan/ftypes
+		wiretap
+		wsutil
+		wsutil/wmem
+	)
+
+	for dir in "${dirs[@]}" ; do
+		insinto /usr/include/wireshark/${dir}
+		doins ${dir}/*.h
+	done
+
+	if use gui ; then
+		local s
+
+		for s in 16 32 48 64 128 256 512 1024 ; do
+			insinto /usr/share/icons/hicolor/${s}x${s}/apps
+			newins resources/icons/wsicon${s}.png wireshark.png
+		done
+
+		for s in 16 24 32 48 64 128 256 ; do
+			insinto /usr/share/icons/hicolor/${s}x${s}/mimetypes
+			newins resources/icons//WiresharkDoc-${s}.png application-vnd.tcpdump.pcap.png
+		done
+	fi
+
+	if [[ -d "${ED}"/usr/share/appdata ]] ; then
+		rm -r "${ED}"/usr/share/appdata || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	# Add group for users allowed to sniff.
+	chgrp pcap "${EROOT}"/usr/bin/dumpcap
+
+	if use dumpcap && use pcap ; then
+		fcaps -o 0 -g pcap -m 4710 -M 0710 \
+			cap_dac_read_search,cap_net_raw,cap_net_admin \
+			"${EROOT}"/usr/bin/dumpcap
+	fi
+
+	ewarn "NOTE: To capture traffic with wireshark as normal user you have to"
+	ewarn "add yourself to the pcap group. This security measure ensures"
+	ewarn "that only trusted users are allowed to sniff your traffic."
+}

From 457dc24d8a366c79c33ce37ae5d13504b8fc81e7 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Wed, 27 Nov 2024 06:44:10 +0000
Subject: [PATCH 5/8] net-libs/c-client: Stabilize 2007f_p7-r1 sparc, #945080

Signed-off-by: Sam James <sam@gentoo.org>
---
 net-libs/c-client/c-client-2007f_p7-r1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/net-libs/c-client/c-client-2007f_p7-r1.ebuild b/net-libs/c-client/c-client-2007f_p7-r1.ebuild
index df2ceb0544516..f97bfd6a05526 100644
--- a/net-libs/c-client/c-client-2007f_p7-r1.ebuild
+++ b/net-libs/c-client/c-client-2007f_p7-r1.ebuild
@@ -18,7 +18,7 @@ S="${WORKDIR}"/${MY_PN}-$(ver_cut 1-2)
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ppc ~ppc64 ~riscv ~s390 sparc ~x86"
 IUSE="doc +ipv6 kerberos pam ssl static-libs topal"
 
 RDEPEND="

From 9a86032692dad814f8f231c064790b1fb5a55a02 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Wed, 27 Nov 2024 06:44:11 +0000
Subject: [PATCH 6/8] net-libs/c-client: Stabilize 2007f_p7-r1 arm64, #945080

Signed-off-by: Sam James <sam@gentoo.org>
---
 net-libs/c-client/c-client-2007f_p7-r1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/net-libs/c-client/c-client-2007f_p7-r1.ebuild b/net-libs/c-client/c-client-2007f_p7-r1.ebuild
index f97bfd6a05526..fd3da41bd8b84 100644
--- a/net-libs/c-client/c-client-2007f_p7-r1.ebuild
+++ b/net-libs/c-client/c-client-2007f_p7-r1.ebuild
@@ -18,7 +18,7 @@ S="${WORKDIR}"/${MY_PN}-$(ver_cut 1-2)
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ppc ~ppc64 ~riscv ~s390 sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~loong ~mips ppc ~ppc64 ~riscv ~s390 sparc ~x86"
 IUSE="doc +ipv6 kerberos pam ssl static-libs topal"
 
 RDEPEND="

From d881b65c425e8c6fd5b8718cd24e626e3444e3b5 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Wed, 27 Nov 2024 06:44:12 +0000
Subject: [PATCH 7/8] net-libs/c-client: Stabilize 2007f_p7-r1 ppc64, #945080

Signed-off-by: Sam James <sam@gentoo.org>
---
 net-libs/c-client/c-client-2007f_p7-r1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/net-libs/c-client/c-client-2007f_p7-r1.ebuild b/net-libs/c-client/c-client-2007f_p7-r1.ebuild
index fd3da41bd8b84..3cc4b0f7b997b 100644
--- a/net-libs/c-client/c-client-2007f_p7-r1.ebuild
+++ b/net-libs/c-client/c-client-2007f_p7-r1.ebuild
@@ -18,7 +18,7 @@ S="${WORKDIR}"/${MY_PN}-$(ver_cut 1-2)
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~loong ~mips ppc ~ppc64 ~riscv ~s390 sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 sparc ~x86"
 IUSE="doc +ipv6 kerberos pam ssl static-libs topal"
 
 RDEPEND="

From 25b82d9c03d4b0b0a0151af9c6ea13fb1d7e656d Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Wed, 27 Nov 2024 06:44:13 +0000
Subject: [PATCH 8/8] net-libs/c-client: Stabilize 2007f_p7-r1 arm, #945080

Signed-off-by: Sam James <sam@gentoo.org>
---
 net-libs/c-client/c-client-2007f_p7-r1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/net-libs/c-client/c-client-2007f_p7-r1.ebuild b/net-libs/c-client/c-client-2007f_p7-r1.ebuild
index 3cc4b0f7b997b..e60bc0ac41c88 100644
--- a/net-libs/c-client/c-client-2007f_p7-r1.ebuild
+++ b/net-libs/c-client/c-client-2007f_p7-r1.ebuild
@@ -18,7 +18,7 @@ S="${WORKDIR}"/${MY_PN}-$(ver_cut 1-2)
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 sparc ~x86"
+KEYWORDS="~alpha ~amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 sparc ~x86"
 IUSE="doc +ipv6 kerberos pam ssl static-libs topal"
 
 RDEPEND="