dev-python/django-appconf: Version Bump

Package-Manager: portage-2.2.20.1
Signed-off-by: Justin Lecher <jlec@gentoo.org>

dev-python/django-appconf/Manifest

@@ -1 +1,2 @@
 DIST django-appconf-0.6.tar.gz 14072 SHA256 d3f4bcabcb3a9559775c5f4e94cef47f936b1df63703542bc8d912637452e75c SHA512 d2a4aea07eeabdc32ed85cf0625702f3e7861b82d1e47660f3761dedff42a3bd3bfcc54dc3d46072758bea1a34af160f7a908bf0925c05b7409f1224f4a7245d WHIRLPOOL f357a26a28476048ce97a1b85309c87382e750bb1ff9ea8552e194423e815b8945da5367200872096ede6177133094314e9a4a4ca4c5a058b273ab46aacb5091
+DIST django-appconf-1.0.1.tar.gz 16743 SHA256 ba1375fb1024e8e91547504d4392321795c989fde500b96ebc7c93884f786e60 SHA512 b6075bed0372f7f9da7c7af49124a08a2d119533ea15b284529166bcc09e61a541ce179a696dd426a9323ea1874c219880869ef7934345f4d40b1b3201eb2c6d WHIRLPOOL db6d03024b25442a3db71163f6c130c504756a52cf8454f38e4f0c4667c3e4a147b65f0b679a8300f83fd9aecdf1d5f35cb1b1879c988dd5536ab5976ddcb1c0

dev-python/django-appconf/django-appconf-1.0.1.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="A helper class for handling configuration defaults of packaged apps gracefully"
+HOMEPAGE="https://github.com/jezdez/django-appconf http://django-appconf.readthedocs.org/ https://pypi.python.org/pypi/django-appconf"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/django-1.4.1[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/django-discover-runner[${PYTHON_USEDEP}]
+		dev-python/flake8[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/docs.patch )
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	cd appconf/tests || die
+	set -- django-admin.py test appconf --settings=appconf.test_settings
+	echo "$@"
+	"$@" || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}