dev-python/enable: Version bump

Package-Manager: Portage-2.3.31, Repoman-2.3.9

dev-python/enable/Manifest

@@ -1,2 +1,3 @@
 DIST enable-4.4.1.tar.gz 2507048 BLAKE2B e3414a0505acafece3242a40400aab9ea00062bb605baa500f604df875b1caacd446c30189a23bac856c6cb39067f120be6e89ac9c95a05e92dc882d839a7e4b SHA512 72c879f19e26a4311b900cb4665969b9f806ce47b23c214a25e3ec308cc5300b6d71084a793215b05302fbeba09e13a4561e661c3bddb700d529bd31cfeb4dff
 DIST enable-4.5.1.tar.gz 2571975 BLAKE2B dfd294f80e22fa89243057f405fe83ecadeb3768cae5a103e62219cfc62ecb5bd3acf1bd2d575da3276e8111c5c5330fa88e1ed06c6eb67a04974a57dd0cbd98 SHA512 1095a4490f4918756dd33864aaba2636c294c3b177d3f500d98a355ec86ef86ab211d33cdec95c2d37e7e1df41622acf2c8ecf524a1d93cc39797804c49e6971
+DIST enable-4.7.1.tar.gz 2728889 BLAKE2B 2952c1772ea902b2a040a5dbc1ade4fcb41f38da41cb9cfd3a574d16397fcceedb5d2216e19bd14ca9881ff27efa93ec0fe4b94db8f3baedf174fe062c825f1e SHA512 49ca414d1273fb5ddcb1732e621f91a5ac49ff02d63b5b36b8d9e28dd737eb4a312f35345fc29db555db1c6e0e8c9bf2204f8662b43a2761db6c2d656c6b2140

dev-python/enable/enable-4.7.1.ebuild

@@ -0,0 +1,75 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 virtualx flag-o-matic
+
+DESCRIPTION="Enthought Tool Suite: Drawing and interaction packages"
+HOMEPAGE="http://docs.enthought.com/enable/
+	https://pypi.org/project/enable
+	https://github.com/enthought/enable"
+SRC_URI="https://github.com/enthought/enable/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="
+	dev-python/apptools[${PYTHON_USEDEP}]
+	dev-python/kiwisolver[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/reportlab[${PYTHON_USEDEP}]
+	>=dev-python/traitsui-4[${PYTHON_USEDEP}]
+	media-libs/freetype:2
+	virtual/opengl
+	virtual/glu
+	x11-libs/libX11
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-lang/swig:0
+	dev-python/cython[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/fonttools[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pyface[${PYTHON_USEDEP}]
+		media-fonts/font-cursor-misc
+		media-fonts/font-misc-misc
+	)
+"
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	append-cflags -fno-strict-aliasing
+
+	sed -e 's:html_favicon = "et.ico":html_favicon = "_static/et.ico":' \
+		-i docs/source/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	pushd "${BUILD_DIR}"/lib > /dev/null
+	# https://github.com/enthought/enable/issues/158
+	PYTHONPATH=.:kiva \
+		virtx nosetests --verbose
+	popd > /dev/null
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}