games-fps/gzdoom: Drop old 4.12.2

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

games-fps/gzdoom/Manifest

@@ -1,2 +1 @@
-DIST gzdoom-4.12.2.tar.gz 25910359 BLAKE2B 3f456136cfc161d67451d8bf1f359d748d6f30f4461a3bff4ab6b02fd949e4057dcbee79eae9ebc0566e33d2f1f3f42add18417b1932e3bccf8b4d5cae9b9a38 SHA512 1e9f34af0d5bf9f3797e0cfef01f993c0b8a742ba0af53b4b13cbce9ecefa15f22949bdbbba5a09e890a01dc32af81806fcb6fc632e0dc9261494580782a5007
 DIST gzdoom-4.14.1.tar.gz 25970736 BLAKE2B 49012b47288d6d4ad0806abb6b33ed2a9dbb3fffbf65135b4c37f6c7d48bf7943a81a718ab91b787b07e4d0a42853e2a21c8a3c05693e7979d42bf812a46d864 SHA512 43589366d3311ca55e595852c526eeaf24a89decb7a029ddc4363019a61459a8da7d5ca43f1edffe9bfd44189af40fec40351857956d78b57d8db920a1a84a92

games-fps/gzdoom/gzdoom-4.12.2.ebuild

@@ -1,99 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake desktop xdg flag-o-matic
-
-DESCRIPTION="A modder-friendly OpenGL source port based on the DOOM engine"
-HOMEPAGE="https://zdoom.org"
-SRC_URI="https://github.com/coelckers/${PN}/archive/g${PV}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}/${PN}-g${PV}"
-
-LICENSE="Apache-2.0 BSD BZIP2 GPL-3 LGPL-2.1+ LGPL-3 MIT
-	non-free? ( Activision ChexQuest3 DOOM-COLLECTORS-EDITION freedist WidePix )"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~ppc64"
-IUSE="debug gles2 gtk +non-free openmp +swr telemetry vulkan"
-
-DEPEND="
-	app-arch/bzip2
-	media-libs/libjpeg-turbo:0=
-	media-libs/libsdl2[gles2?,opengl,vulkan?]
-	media-libs/libvpx:=
-	media-libs/libwebp
-	media-libs/openal
-	media-libs/zmusic
-	virtual/zlib:=
-	gtk? ( x11-libs/gtk+:3 )"
-RDEPEND="${DEPEND}"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-4.7.1-Introduce-the-BUILD_NONFREE-option.patch
-)
-
-src_prepare() {
-	rm -rf docs/licenses || die
-	rm -rf libraries/{bzip2,jpeg,zlib} || die
-	if ! use non-free ; then
-		rm -rf wadsrc_bm wadsrc_extra wadsrc_widepix || die
-	fi
-
-	{
-		echo "// 0"
-		echo "// The above line prevents UpdateRevision.cmake from replacing this file."
-		echo "// This file was generated by the Gentoo ebuild."
-		echo
-		echo "#define GIT_DESCRIPTION \"g${PV}\""
-		echo "#define GIT_HASH \"0\""
-		echo "#define GIT_TIME \"\""
-	} > "${S}/src/gitinfo.h" || die
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	# https://bugs.gentoo.org/858749
-	filter-lto
-	append-flags -fno-strict-aliasing
-
-	local mycmakeargs=(
-		-DBUILD_SHARED_LIBS=OFF
-		-DINSTALL_DOCS_PATH="${EPREFIX}/usr/share/doc/${PF}"
-		-DINSTALL_PK3_PATH="${EPREFIX}/usr/share/doom"
-		-DINSTALL_SOUNDFONT_PATH="${EPREFIX}/usr/share/doom"
-		-DDYN_OPENAL=OFF
-		-DNO_GTK="$(usex !gtk)"
-		-DNO_OPENAL=OFF
-		-DHAVE_VULKAN="$(usex vulkan)"
-		-DHAVE_GLES2="$(usex gles2)"
-		-DNO_OPENMP="$(usex !openmp)"
-		-DZDOOM_ENABLE_SWR="$(usex swr)"
-		-DBUILD_NONFREE="$(usex non-free)"
-	)
-
-	use debug || append-cppflags -DNDEBUG
-	use telemetry || append-cppflags -DNO_SEND_STATS
-
-	cmake_src_configure
-}
-
-src_install() {
-	newicon src/posix/zdoom.xpm "${PN}.xpm"
-	make_desktop_entry "${PN}" "GZDoom" "${PN}" "Game;ActionGame"
-	cmake_src_install
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if ! use non-free ; then
-		ewarn
-		ewarn "GZDoom installed without non-free components."
-		ewarn "Note: The non-free game_support.pk3 file is needed to play"
-		ewarn "      games natively supported by GZDoom."
-		ewarn "A list of games natively supported by GZDoom is available"
-		ewarn "on the ZDoom wiki: https://zdoom.org/wiki/IWAD"
-		ewarn
-	fi
-}