From 6c07a10fd3b060da64bfa0b399b344fee4c03177 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Holger=20Hoffst=C3=A4tte?= <holger@applied-asynchrony.com>
Date: Fri, 13 Feb 2026 22:47:34 +0100
Subject: [PATCH] dev-libs/libverto: revbump to remove USE=threads
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Upstream enables threads by default, so as described in bug #868336
enable (p)thread support unconditionally and remove "threads" from IUSE.

Closes: https://bugs.gentoo.org/869728
Signed-off-by: Holger Hoffstätte <holger@applied-asynchrony.com>
Part-of: https://github.com/gentoo/gentoo/pull/45801
Closes: https://github.com/gentoo/gentoo/pull/45801
Signed-off-by: Eray Aslan <eras@gentoo.org>
---
 dev-libs/libverto/libverto-0.3.2-r1.ebuild | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 dev-libs/libverto/libverto-0.3.2-r1.ebuild

diff --git a/dev-libs/libverto/libverto-0.3.2-r1.ebuild b/dev-libs/libverto/libverto-0.3.2-r1.ebuild
new file mode 100644
index 0000000000000..ff101ad147cfb
--- /dev/null
+++ b/dev-libs/libverto/libverto-0.3.2-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="Main event loop abstraction library"
+HOMEPAGE="https://github.com/latchset/libverto/"
+SRC_URI="https://github.com/latchset/libverto/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="glib +libev libevent"
+REQUIRED_USE="|| ( glib libev libevent )"
+
+DEPEND="glib? ( >=dev-libs/glib-2.34.3[${MULTILIB_USEDEP}] )
+	libev? ( >=dev-libs/libev-4.15[${MULTILIB_USEDEP}] )
+	libevent? ( >=dev-libs/libevent-2.0.21[${MULTILIB_USEDEP}] )"
+
+RDEPEND="${DEPEND}"
+
+DOCS=( AUTHORS ChangeLog NEWS INSTALL README )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-non-bash.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" \
+	econf \
+		$(use_with glib) \
+		$(use_with libev) \
+		$(use_with libevent) \
+		--with-pthread \
+		--disable-static
+}
+
+multilib_src_install_all() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}