diff --git a/kde-frameworks/breeze-icons/Manifest b/kde-frameworks/breeze-icons/Manifest
index 9abcc302a9736..be068c070219a 100644
--- a/kde-frameworks/breeze-icons/Manifest
+++ b/kde-frameworks/breeze-icons/Manifest
@@ -1 +1,2 @@
 DIST breeze-icons-6.27.0.tar.xz 2107164 BLAKE2B 1c696538210e121e462968c07b293d9a42d528de0b9411fe9ded228e043176facf749ec1b88ce4979276dd19fa3ed98985722f8e2f5d3d1e42445770eab541a4 SHA512 6e811fd0f415f7a50e94c5953ba314fe1e672e4cd54e652e89c056f4fa39cc340293cfa499891792dda81902fdb5a68edf3277aa6bec6f3287175bc83f75df6f
+DIST breeze-icons-6.28.0.tar.xz 2107072 BLAKE2B 4e4f8efb7fb8a92cfe2de65204fdf85ceae2101250287c1f59dd403f20bacfd2a39b99daf59f14e570dc2b36ef87f679bf098fa215a44f5667de342f4bc28a1a SHA512 82e8c324903284c7eb9c14a4a3985532292e6125535c586433b8e8dbaeccea945fdea7a00355e50e791342614a510e17c461f710b5d4f13ef0a32c68e1d26891
diff --git a/kde-frameworks/breeze-icons/breeze-icons-6.28.0.ebuild b/kde-frameworks/breeze-icons/breeze-icons-6.28.0.ebuild
new file mode 100644
index 0000000000000..b39aecf7e7c12
--- /dev/null
+++ b/kde-frameworks/breeze-icons/breeze-icons-6.28.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+QTMIN=6.9.0
+inherit cmake frameworks.kde.org python-any-r1 xdg
+
+DESCRIPTION="Breeze SVG icon theme"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!kde-frameworks/${PN}:5
+	!kde-frameworks/${PN}-rcc:5
+	!kde-frameworks/${PN}-rcc:6
+"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	>=dev-qt/qtbase-${QTMIN}:6[gui]
+	>=kde-frameworks/extra-cmake-modules-${KDE_CATV}:*
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	python_has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=ON # TODO: remove when kexi was ported away
+		-DSKIP_INSTALL_ICONS=OFF
+		-DBUILD_TESTING="$(usex test)"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	# bug 770988
+	find "${ED}"/usr/share/icons/ -type d -empty -delete || die
+	find "${ED}"/usr/share/icons/ -xtype l -delete || die
+}