kde-apps/dolphin-plugins-mercurial: 25.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/dolphin-plugins-mercurial/Manifest

@@ -1 +1,2 @@
 DIST dolphin-plugins-25.04.3.tar.xz 329648 BLAKE2B 58d412c61476696bd0b885539405e21b17be1d7b07a86175989060eebdb266e6201909944a70b2be3b4a9c3f00131f24590fadf7a586289d7dd55e5b878aac0a SHA512 2e8756fb7789ee479477a67392dcebde5bd178bec8589053a4f4c7fa5659ea8a67c76ebe10e56d9e56f58dbab837f276620bbe50d0efee1f142369f5df317989
+DIST dolphin-plugins-25.08.0.tar.xz 330584 BLAKE2B f887724361e2ae4d081b1795386e17f584cafdc5b892a0acfd04e9780eb35c9469c3ba5e34d930ea2f25f2832353f12d27251a97becaa066190fff60540eb3ca SHA512 65283810e73338dd77fcb9d9932f6c4acd9ce9c18572eef1c6dc0179fd1204ee9bae491764869a6aad91600872a9f3a44d07c8a0ad15278787f42626bdcf7249

kde-apps/dolphin-plugins-mercurial/dolphin-plugins-mercurial-25.08.0.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="hg"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.16.0
+QTMIN=6.9.1
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for Mercurial integration"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui,widgets]
+	>=kde-apps/dolphin-${PVCUT}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ktexteditor-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	dev-vcs/mercurial
+	>=kde-apps/dolphin-plugins-common-${PV}
+"
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_po_install
+	# qtconcurrent only required by git
+	ecm_punt_qt_module Concurrent
+	# solid, qtdbus only required by mountiso
+	ecm_punt_qt_module DBus
+	ecm_punt_kf_module Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_makefileactions=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}