dev-python/django-debug-toolbar: 2.1 bump

Signed-off-by: William Hubbs <williamh@gentoo.org>

dev-python/django-debug-toolbar/Manifest

@@ -1 +1,2 @@
 DIST django-debug-toolbar-2.0.tar.gz 321249 BLAKE2B cd4f9e7d55deaf404369ba89eaffe0c730a058450c8368e39bfe3f5562019f5978ff33b93dc0463dc0fa6e6ba1047335d45997929dc3d2b576a78ff7cd5f75f0 SHA512 8440705a2e38f2c035a1dde4eb14ec829ead502cbbebcae46889e26877c0843389107bf14249afe9742638c4880b362fd699aed935e271bc1ade8f0a54bfea46
+DIST django-debug-toolbar-2.1.tar.gz 321132 BLAKE2B 4765a25bd7aa2578c65cd0918bf47de047e131deb896cdd7b80111e9628e4f7c39ad6dc84fc4114310fb1a8195fea263810b279e8b19b6e621879b8eb2961f82 SHA512 3cfd11b28ec6573977a0476388e8f4d63441c5b390fe974294bc059a83fc95a44c3c8df18a549403756f7929181750aec51d70b38cfe3bce1d40ba24e6b72e9d

dev-python/django-debug-toolbar/django-debug-toolbar-2.1.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_6 python3_7 )
+
+inherit distutils-r1
+
+DESCRIPTION="A configurable set of panels that display debug information"
+HOMEPAGE="
+	https://pypi.org/project/django-debug-toolbar/
+	https://github.com/django-debug-toolbar/django-debug-toolbar/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples"
+
+RDEPEND="
+	>=dev-python/django-1.11[${PYTHON_USEDEP}]
+	>=dev-python/python-sqlparse-0.2.0[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	# Prevent non essential d'loading by intersphinx
+	sed -e 's:intersphinx_mapping:_&:' -i docs/conf.py || die
+
+	# This prevents distutils from installing 'tests' package, rm magic no more needed
+	sed -e "/find_packages/s:'tests':'tests.\*', 'tests':" -i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	emake test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	use examples && local EXAMPLES=( example/. )
+	distutils-r1_python_install_all
+}