gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-07-25 08:58:27 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/dbus-python: Bump to 1.2.12, needs setuptools

Browse Source 
Closes: https://bugs.gentoo.org/678942
Closes: https://bugs.gentoo.org/695426
Package-Manager: Portage-2.3.77, Repoman-2.3.17
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
This commit is contained in:
Pacho Ramos
2019-10-20 16:38:34 +02:00
parent 1763a812b5
commit 6a0f465dad
2 changed files with 79 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/dbus-python/Manifest
View File

@@ -1,4 +1,5 @@
DIST dbus-python-1.2.0.tar.gz 602426 BLAKE2B 86f5ba9283256b83d268ff7c27368e587896d58f87b15aefe9d29a90530ced591a2c6814dd37b91274910ed131fe031846071311bc6cc07c11d1f9cdda9e4602 SHA512 013b23e08fa1ed43f53a756587fefbc9770f7c51e93510e555acbd77230b7200693419bba9a69680d790bbaf123f4a195afa38b3eee1143da950fee0b5130bce
DIST dbus-python-1.2.12.tar.gz 574727 BLAKE2B e5516e7109fad089af51d3e5db3921d056f327c27f9b74a870b1b31b04ba952ad3c9ba5916a18d674ab1179b94cf516b24e046feded8f2e542b196d162038944 SHA512 6f90eaeeb74ea71a026a331d4c611911eda6dfb6c9086a0a80352f9963a9ae126db6f3e32d183916b8517f177fc947f1ddb15df83ff0b5c886532116868383b4
DIST dbus-python-1.2.4.tar.gz 612112 BLAKE2B cccd3e2f5d700c0d228e7d21fd85e2307357778371742a7fe26a0e419af41886efebb27a73f642d2ecd4603c79f4afe6e7002af95c831180e0e7844c079b2c8c SHA512 efdd9d96a8b56e813c93208d34777f1ca2db96c076d31f13afbcaec3c7770a16a623d5531fe23443130c555240949802503f171f2064d45eee97546d6251304b
DIST dbus-python-1.2.6.tar.gz 778893 BLAKE2B 1587bc9b1795e5c416397468b2061c869d923aea0983e604862342b27d37b946b1fcdd3bf07a612dba30087bdc6a5fa734906188c55756edf38d50eb67b7eef6 SHA512 6f2aec81defd2528d9876ec9a83843f8767275a5d6cf1b2b7b7a094f892f552f9a7b3d7b5006465254d410e503108e10138d7dd4cb3f1a4035d7f8d58c4d0684
DIST dbus-python-1.2.8.tar.gz 787426 BLAKE2B 186cb8b1b25b2d2d12ab24ed304819ef18f953232d321bd425e7fda632c79a5a94f7b4118cc09f1bb13a0621980af67b4b55599fbbbcaf0e95f7912f4afd0a2e SHA512 6e486fd560944fc1461a27e6798e2c348c7fdf351602c082a0614c0a6822ff147875212bdcb1f818c0ab12470cffc613c0ffbd292cd9d445d3429bee65765905

78
dev-python/dbus-python/dbus-python-1.2.12.ebuild Normal file
View File

@@ -0,0 +1,78 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
PYTHON_REQ_USE="threads(+)"
inherit autotools python-r1
DESCRIPTION="Python bindings for the D-Bus messagebus"
HOMEPAGE="https://www.freedesktop.org/wiki/Software/DBusBindings https://dbus.freedesktop.org/doc/dbus-python/"
SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="doc examples test"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RESTRICT="!test? ( test )"
RDEPEND="${PYTHON_DEPS}
>=sys-apps/dbus-1.8:=
>=dev-libs/glib-2.40
"
DEPEND="${RDEPEND}"
BDEPEND="
dev-python/setuptools[${PYTHON_USEDEP}]
virtual/pkgconfig
doc? ( $(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]') )
test? ( dev-python/pygobject:3[${PYTHON_USEDEP}]
dev-python/tappy[${PYTHON_USEDEP}] )
"
python_check_deps() {
has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
}
src_prepare() {
default
# Update py-compile, bug 529502.
eautoreconf
python_copy_sources
}
src_configure() {
use doc && python_setup
local SPHINX_IMPL=${EPYTHON}
configuring() {
local myconf=(
--disable-documentation
)
[[ ${EPYTHON} == ${SPHINX_IMPL} ]] &&
myconf+=( --enable-documentation )
econf "${myconf[@]}"
}
python_foreach_impl run_in_build_dir configuring
}
src_compile() {
python_foreach_impl run_in_build_dir default
}
src_test() {
unset DBUS_SESSION_BUS_ADDRESS
python_foreach_impl run_in_build_dir default
}
src_install() {
python_foreach_impl run_in_build_dir default
find "${D}" -name '*.la' -type f -delete || die
use examples && dodoc -r examples
}