From 69c4a9951c74c18964da45b62ddfb18e59341d73 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Mon, 11 Jul 2022 08:30:54 +0200
Subject: [PATCH] dev-python/cherrypy: Bump to 18.7.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/cherrypy/Manifest               |  1 +
 dev-python/cherrypy/cherrypy-18.7.0.ebuild | 66 ++++++++++++++++++++++
 2 files changed, 67 insertions(+)
 create mode 100644 dev-python/cherrypy/cherrypy-18.7.0.ebuild

diff --git a/dev-python/cherrypy/Manifest b/dev-python/cherrypy/Manifest
index 910f688327a5b..8c0d50144fb18 100644
--- a/dev-python/cherrypy/Manifest
+++ b/dev-python/cherrypy/Manifest
@@ -1 +1,2 @@
 DIST CherryPy-18.6.1.tar.gz 692730 BLAKE2B 44cef7ed54a090df396691001b794bf13be2c61003bf80b63223e3a42914ce50fcfe43c06626fb881105e3ed6fbf587df7024bbf7cfde00a8263c432f4cc7ae4 SHA512 186a0992a443e1ffc1a2924b3351dcb0e6cc6c88b39ac32330d6365fe1b0a35c2008a3a18e1a57f61ffd1901ea6134333bb6288024d8ffbb1fd8e8dcd3145007
+DIST CherryPy-18.7.0.tar.gz 621794 BLAKE2B d60cd21d0b0bacbb18bcaeb525be143c3639f462978e9835e5c77ba8ce732a3af4662e4c37e2d20e1ad19760900775dee4a3cd98db53e70a19611d30c8329bce SHA512 321771a3e3cda16090bfb7a79c297defd67655ba5453e440e09e85fec41cba850544bebac7203206c95e38d79b3bce22368ea19c0fb1fbedbb00d76a4ab59c8b
diff --git a/dev-python/cherrypy/cherrypy-18.7.0.ebuild b/dev-python/cherrypy/cherrypy-18.7.0.ebuild
new file mode 100644
index 0000000000000..829fc9cccf096
--- /dev/null
+++ b/dev-python/cherrypy/cherrypy-18.7.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="CherryPy"
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="CherryPy is a pythonic, object-oriented HTTP framework"
+HOMEPAGE="
+	https://cherrypy.dev/
+	https://github.com/cherrypy/cherrypy/
+	https://pypi.org/project/CherryPy/
+"
+SRC_URI="mirror://pypi/${MY_PN::1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="ssl test"
+
+RDEPEND="
+	>=dev-python/cheroot-8.2.1[${PYTHON_USEDEP}]
+	>=dev-python/portend-2.1.1[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/zc-lockfile[${PYTHON_USEDEP}]
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	ssl? (
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/routes[${PYTHON_USEDEP}]
+		dev-python/simplejson[${PYTHON_USEDEP}]
+		dev-python/objgraph[${PYTHON_USEDEP}]
+		dev-python/path-py[${PYTHON_USEDEP}]
+		dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+		dev-python/pytest-services[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# flaky test that's now problematic due to xfail_strict
+	cherrypy/test/test_caching.py::CacheTest::test_antistampede
+)
+
+python_prepare_all() {
+	sed -r -e '/(pytest-sugar|pytest-cov)/ d' \
+		-i setup.py || die
+
+	sed -r -e 's:--cov-report[[:space:]]+[[:graph:]]+::g' \
+		-e 's:--cov[[:graph:]]+::g' \
+		-e 's:--doctest[[:graph:]]+::g' \
+		-i pytest.ini || die
+
+	distutils-r1_python_prepare_all
+}